title:: More chaos
summary:: some notes on 2D chaos ugens (BhobUGens)
categories:: UGens>Generators>Stochastic


2D chaos ugens similar to sc chaos ugens, but x is mapped to freq, y to amplitude. arguments are minfreq, maxfreq, parameters. where applicable, the parameters arguments are in the same order as sc chaos ugens

code::
{ Henon2DC.ar(440, 1880, LFNoise2.kr(1, 0.1, 1.3), 0.3).dup }.play
{ Gbman2DL.ar(200, 800).dup }.play

// each also has a corresponding trigger
{ Ringz.ar(StandardTrig.ar(10, 20), 2205, 0.02).fold2(0.5).dup }.play

// can be k-rate
{ SinOsc.ar(Latoocarfian2DN.kr(4, 16, mul:220, add:440)).cubed.fold2(0.6).dup }.play

// trig & oscillator
(
{
var trig, sig;
trig=LatoocarfianTrig.kr(4, 12, [1.1, 1.5]);
sig=Latoocarfian2DC.ar(420, 8200, Lag.kr(TRand.kr(0.4, 0.8, trig), 0.1), Lag.kr(TRand.kr(2.0, 3.0, trig), 0.1), d:[1.0, 1.05], mul:Latch.kr(trig, trig));
(sig.cubed * 2).tanh
}.play
)
::

and there are a few chaos patterns as well.  Phenon, etc. (see class file).  these output arrays where applicable and are normalized from 0-1 by default (you can remove normalization by setting the n argument to false).

code::
p=Pstandard.new;
x=p.asStream;

20.do({ x.next.postln });
::
