Appendix E. Handling Common Tasks
Prev |  |

## Appendix E. Handling Common Tasks

There is a common set of simple tasks that many build configurations rely on as they become more complex. Most build tools have special purpose constructs for performing these tasks, but since `SConscript` files are Python scripts, you can use more flexible built-in Python services to perform these tasks. This appendix lists a number of these tasks and how to implement them in Python and SCons.

Example E.1. Wildcard globbing to create a list of filenames

    files = Glob(wildcard)

Example E.2. Filename extension substitution

    import os.path
    filename = os.path.splitext(filename)[0]+extension

Example E.3. Appending a path prefix to a list of filenames

    import os.path
    filenames = [os.path.join(prefix, x) for x in filenames]

Example E.4. Substituting a path prefix with another one

    if filename.find(old_prefix) == 0:
        filename = filename.replace(old_prefix, new_prefix)

Example E.5. Filtering a filename list to exclude/retain only a specific set of extensions

    import os.path
    filenames = [x for x in filenames if os.path.splitext(x)[1] in extensions]

Example E.6. The "backtick function": run a shell command and capture the output

    import subprocess
    output = subprocess.check_output(command)

Example E.7. Generating source code: how code can be generated and used by SCons

The Copy builders here could be any arbitrary shell or python function that produces one or more files. This example shows how to create those files and use them in SCons.

    #### SConstruct
    env = Environment()
    env.Append(CPPPATH = "#")

    ## Header example
    env.Append(BUILDERS =
       {'Copy1' : Builder(action = 'cat < $SOURCE > $TARGET',
                          suffix='.h', src_suffix='.bar')})
    env.Copy1('test.bar') # produces test.h from test.bar.
    env.Program('app','main.cpp') # indirectly depends on test.bar

    ## Source file example
    env.Append(BUILDERS =
      {'Copy2' : Builder(action = 'cat < $SOURCE > $TARGET',
                         suffix='.cpp', src_suffix='.bar2')})
    foo = env.Copy2('foo.bar2') # produces foo.cpp from foo.bar2.
    env.Program('app2',['main2.cpp'] + foo) # compiles main2.cpp and foo.cpp into app2.

Where main.cpp looks like this:

    #include "test.h"

produces this:

    % scons -Q
    cat < test.bar > test.h
    cc -o app main.cpp
    cat < foo.bar2 > foo.cpp
    cc -o app2 main2.cpp foo.cpp

Prev |  |
Appendix D. Functions and Environment Methods | Home |