9.2. Controlling How SCons Prints Build Commands: the `$*COMSTR` Variables
Prev | Chapter 9. Controlling Build Output | Next

## 9.2. Controlling How SCons Prints Build Commands: the `$*COMSTR` Variables

Sometimes the commands executed to compile object files or link programs (or build other targets) can get very long, long enough to make it difficult for users to distinguish error messages or other important build output from the commands themselves. All of the default `$*COM` variables that specify the command lines used to build various types of target files have a corresponding `$*COMSTR` variable that can be set to an alternative string that will be displayed when the target is built.

For example, suppose you want to have SCons display a `"Compiling"` message whenever it's compiling an object file, and a `"Linking"` when it's linking an executable. You could write a `SConstruct` file that looks like:

    env = Environment(CCCOMSTR = "Compiling $TARGET",
                      LINKCOMSTR = "Linking $TARGET")
    env.Program('foo.c')

Which would then yield the output:

    % scons -Q
    Compiling foo.o
    Linking foo

SCons performs complete variable substitution on `$*COMSTR` variables, so they have access to all of the standard variables like `$TARGET` `$SOURCES`, etc., as well as any construction variables that happen to be configured in the construction environment used to build a specific target.

Of course, sometimes it's still important to be able to see the exact command that SCons will execute to build a target. For example, you may simply need to verify that SCons is configured to supply the right options to the compiler, or a developer may want to cut-and-paste a compile command to add a few options for a custom test.

One common way to give users control over whether or not SCons should print the actual command line or a short, configured summary is to add support for a `VERBOSE` command-line variable to your `SConstruct` file. A simple configuration for this might look like:

    env = Environment()
    if ARGUMENTS.get('VERBOSE') != '1':
        env['CCCOMSTR'] = "Compiling $TARGET"
        env['LINKCOMSTR'] = "Linking $TARGET"
    env.Program('foo.c')

By only setting the appropriate `$*COMSTR` variables if the user specifies `VERBOSE=1` on the command line, the user has control over how SCons displays these particular command lines:

    % scons -Q
    Compiling foo.o
    Linking foo
    % scons -Q -c
    Removed foo.o
    Removed foo
    % scons -Q VERBOSE=1
    cc -o foo.o -c foo.c
    cc -o foo foo.o

A gentle reminder here: many of the commands for building come in pairs, depending on whether the intent is to build an object for use in a shared library or not. The command strings mirror this, so it may be necessary to set, for example, both `CCCOMSTR` and `SHCCCOMSTR` to get the desired results.

Prev | Up | Next
Chapter 9. Controlling Build Output | Home | 9.3. Providing Build Progress Output: the `Progress` Function