Macaulay2 » Documentation
Packages » HyperplaneArrangements :: euler(CentralArrangement)
next | previous | forward | backward | up | index | toc

# euler(CentralArrangement) -- compute the Euler characteristic of the projective complement

- Function: euler
- Usage:
    `euler A`
- Inputs:
  - A, a central hyperplane arrangement, or a Flat
- Outputs:
  - an integer, equal to the Euler characteristic

## Description

For any topological space, the Euler characteristic is the alternating sum of its Betti numbers (a.k.a. the ranks of its homology groups). For a central hyperplane arrangement, the associated topological space is the projectivization of its complement.

The Euler characteristic for the hyperplane arrangements defined by root systems are described by simple formulas.

    i1 : A2 = typeA 2

    o1 = {x  - x , x  - x , x  - x }
           1    2   1    3   2    3

    o1 : Hyperplane Arrangement

    i2 : euler A2

    o2 = -1

    i3 : assert all(5, n -> euler typeA (n+1) === (-1)^(n) * n!)

    i4 : B2 = typeB 2

    o4 = {x , x  - x , x  + x , x }
           1   1    2   1    2   2

    o4 : Hyperplane Arrangement

    i5 : euler B2

    o5 = -2

    i6 : assert all(4, n -> euler typeB (n+1) === (-1)^(n) * 2^n * n!)

Given a flat, this method computes the Euler characteristic of the subarrangement indexed by the flat.

    i7 : A4 = typeA 4

    o7 = {x  - x , x  - x , x  - x , x  - x , x  - x , x  - x , x  - x , x  - x , x  - x , x  - x }
           1    2   1    3   1    4   1    5   2    3   2    4   2    5   3    4   3    5   4    5

    o7 : Hyperplane Arrangement

    i8 : F = flat(A4, {0,7})

    o8 = {0, 7}

    o8 : Flat of {x  - x , x  - x , x  - x , x  - x , x  - x , x  - x , x  - x , x  - x , x  - x , x  - x }
                   1    2   1    3   1    4   1    5   2    3   2    4   2    5   3    4   3    5   4    5

    i9 : euler F

    o9 = 0

    i10 : assert(euler A4_F === euler F)

    i11 : euler flat(A4, {2,3,9})

    o11 = -1

    i12 : euler flat(A4, {0,1,2,4,5,7})

    o12 = 2

    i13 : euler flat(A4, {2,4,6,8})

    o13 = 0

The Euler characteristic of the empty arrangement is just the Euler characteristic of the ambient projective space. For instance, the Euler characteristic of the complex projective plane is $3$.

    i14 : assert (euler arrangement({}, ring A2) === 3)

## See also

- typeA -- make the hyperplane arrangement defined by a type $A_n$ root system
- typeB -- make the hyperplane arrangement defined by a type $B_n$ root system
- subArrangement -- create the hyperplane arrangement containing a flat
- flat -- make a flat from a list of indices

## Ways to use this method:

- euler(CentralArrangement) -- compute the Euler characteristic of the projective complement
- `euler(Flat)`

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/HyperplaneArrangements.m2:2670:0.