Macaulay2 » Documentation
Packages » RationalMaps :: RationalMapping * RationalMapping
next | previous | forward | backward | up | index | toc

# RationalMapping * RationalMapping -- compose rational maps between projective varieties

- Operator: *

## Description

This allows one to compose two rational maps between projective varieties.

    i1 : R = QQ[x,y,z]

    o1 = R

    o1 : PolynomialRing

    i2 : P2 = Proj(R)

    o2 = P2

    o2 : ProjectiveVariety

    i3 : phi = rationalMapping (P2, P2, {y*z,x*z,x*y})

    o3 = P2 - - - > P2   {y*z, x*z, x*y}

    o3 : RationalMapping

    i4 : ident = rationalMapping (P2, P2, {x,y,z})

    o4 = P2 - - - > P2   {x, y, z}

    o4 : RationalMapping

    i5 : phi*phi == ident

    o5 = true

Raising a map to the negative first power means computing the inverse birational map. Raising a map to the first power simply returns the map itself. In the next example we compute the blowup of a point on $P^2$ and its inverse.

    i6 : P5ring = ZZ/103[a..f];

    i7 : R = ZZ/103[x,y,z];

    i8 : P2 = Proj R;

    i9 : identP2 = rationalMapping(P2, P2, {x,y,z});

    i10 : M = matrix{{a,b,c},{d,e,f}};

                       2           3
    o10 : Matrix P5ring  <-- P5ring

    i11 : blowUp = Proj(P5ring/(minors(2, M)+ideal(b - d)));

    i12 : identBlowUp = rationalMapping(blowUp, blowUp, {a,b,c,d,e,f});

    i13 : tau = rationalMapping(P2, blowUp,{a, b, c});

    i14 : tauInverse = tau^-1;

    i15 : tau*tauInverse == identP2 --a map composed with its inverse is the identity

    o15 = true

    i16 : tauInverse*tau == identBlowUp

    o16 = true

Note that one can only raise maps to powers (with the exception of 1 and -1) if the source and target are the same. In that case, raising a map to a negative power means compose the inverse of a map with itself. We illustrate this with the quadratic transformation on $P^2$ that we started with (an transformation of order 2 in the Cremona group).

    i17 : phi^3 == phi^-1

    o17 = true

    i18 : phi^-2 == ident

    o18 = true

    i19 : phi^1 == ident

    o19 = false

## See also

- isSameMap -- whether two rational maps to between projective varieties are really the same

## Ways to use this method:

- RationalMapping * RationalMapping -- compose rational maps between projective varieties

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/RationalMaps.m2:1632:0.