Macaulay2 » Documentation
Packages » MatrixFactorizations :: isShortExactSequence(ZZdFactorizationMap,ZZdFactorizationMap)
next | previous | forward | backward | up | index | toc

# isShortExactSequence(ZZdFactorizationMap,ZZdFactorizationMap) -- whether a pair of ZZ/d-graded factorization maps forms a short exact sequence

- Function: isShortExactSequence
- Usage:
    `isShortExactSequence(g, f)`
- Inputs:
  - f, a map of ZZ/d-graded factorizations,
  - g, a map of ZZ/d-graded factorizations,
- Outputs:
  - a Boolean value, that is true if these form a short exact sequence

## Description

A short exact sequence of ZZ/d-graded factorizations \[ 0 \to B \xrightarrow{f} C \xrightarrow{g} D \to 0\] consists of two morphisms of factorizations $f \colon B \to C$ and $g \colon C \to D$ such that $g f = 0$, $\operatorname{image} f = \operatorname{ker} g$, $\operatorname{ker} f = 0$, and $\operatorname{coker} g = 0$.

From a factorization morphism $h \colon B \to C$, one obtains a short exact sequence \[ 0 \to \operatorname{image} h \to C \to \operatorname{coker} h \to 0. \]

    i1 : S = ZZ/101[a,b];

    i2 : R = S/(a^3+b^3);

    i3 : m = ideal vars R

    o3 = ideal (a, b)

    o3 : Ideal of R

    i4 : C = tailMF m

          2      2      2
    o4 = S  <-- S  <-- S

         0      1      0

    o4 : ZZdFactorization

    i5 : D = tailMF (m^2)

          3      3      3
    o5 = S  <-- S  <-- S

         0      1      0

    o5 : ZZdFactorization

    i6 : h = randomFactorizationMap(C, D, Cycle => true)

              2                                         3
    o6 = 0 : S  <------------------------------------- S  : 0
                   {2} | 47a+17b -36a-48b -29a+24b |
                   {3} | 19      -30      19       |

              2                                        3
         1 : S  <------------------------------------ S  : 1
                   {4} | 47a-19b 36a+19b -29a-30b |
                   {4} | 19a+24b 30a-17b 19a+48b  |

    o6 : ZZdFactorizationMap

    i7 : f = inducedMap(C, image h)

              2
    o7 = 0 : S  <------------------------------------- image {2} | 47a+17b -36a-48b -29a+24b | : 0
                   {2} | 47a+17b -36a-48b -29a+24b |         {3} | 19      -30      19       |
                   {3} | 19      -30      19       |

              2
         1 : S  <------------------------------------ image {4} | 47a-19b 36a+19b -29a-30b | : 1
                   {4} | 47a-19b 36a+19b -29a-30b |         {4} | 19a+24b 30a-17b 19a+48b  |
                   {4} | 19a+24b 30a-17b 19a+48b  |

    o7 : ZZdFactorizationMap

    i8 : g = inducedMap(coker h, C)

                                                                          2
    o8 = 0 : cokernel {2} | 47a+17b -36a-48b -29a+24b | <--------------- S  : 0
                      {3} | 19      -30      19       |    {2} | 1 0 |
                                                           {3} | 0 0 |

                                                                         2
         1 : cokernel {4} | 47a-19b 36a+19b -29a-30b | <--------------- S  : 1
                      {4} | 19a+24b 30a-17b 19a+48b  |    {4} | 1 0 |
                                                          {4} | 0 1 |

    o8 : ZZdFactorizationMap

    i9 : assert isShortExactSequence(g,f)

## See also

- Basic invariants and properties -- information about accessing basic features
- cone(ZZdFactorizationMap) -- make the mapping cone of a morphism of ZZ/d-graded factorizations

## Ways to use this method:

- isShortExactSequence(ZZdFactorizationMap,ZZdFactorizationMap) -- whether a pair of ZZ/d-graded factorization maps forms a short exact sequence

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/MatrixFactorizations/MatrixFactorizationsDOC.m2:4885:0.