Macaulay2 » Documentation
Packages » MultiplierIdeals :: multiplierIdeal(MonomialIdeal,QQ)
next | previous | forward | backward | up | index | toc

# multiplierIdeal(MonomialIdeal,QQ) -- multiplier ideal

- Function: multiplierIdeal

## Description

## multiplier ideal of a monomial ideal

- Usage:
    `multiplierIdeal(I,t)`
- Inputs:
  - I, a monomial ideal, a monomial ideal in a polynomial ring
  - t, a rational number, a coefficient
- Outputs:
  - an ideal,

Computes the multiplier ideal of $I$ with coefficient $t$ using Howald's Theorem and the package Normaliz.

    i1 : R = QQ[x,y];

    i2 : I = monomialIdeal(y^2,x^3);

    o2 : MonomialIdeal of R

    i3 : multiplierIdeal(I,5/6)

    o3 = monomialIdeal (x, y)

    o3 : MonomialIdeal of R

    i4 : J = monomialIdeal(x^8,y^6); -- Example 2 of [Howald 2000]

    o4 : MonomialIdeal of R

    i5 : multiplierIdeal(J,1)

                         6   5    4 2   2 3     4   5
    o5 = monomialIdeal (x , x y, x y , x y , x*y , y )

    o5 : MonomialIdeal of R

## multiplier ideal of a hyperplane arrangement

- Usage:
    `multiplierIdeal(A,m,s)`
- Inputs:
  - A, a central hyperplane arrangement, a central hyperplane arrangement
  - m, a list, a list of weights for the hyperplanes in $A$ (optional)
  - s, a number, a coefficient
- Outputs:
  - an ideal,

Computes the multiplier ideal of the ideal of $A$ with coefficient $s$ using the package HyperplaneArrangements.

    i6 : R = QQ[x,y,z];

    i7 : f = toList factor((x^2 - y^2)*(x^2 - z^2)*(y^2 - z^2)*z) / first;

    i8 : A = arrangement f;

    i9 : multiplierIdeal(A,3/7)

    o9 = ideal (z, y, x)

    o9 : Ideal of R

## multiplier ideal of monomial space curve

- Usage:
    `I = multiplierIdeal(R,n,t)`
- Inputs:
  - R, a ring
  - n, a list, a list of three integers
  - t, a rational number
- Outputs:
  - I, an ideal

Computes the multiplier ideal of the space curve $C$ parametrized by $(t^a,t^b,t^c)$ given by $n=(a,b,c)$.

    i10 : R = QQ[x,y,z];

    i11 : n = {2,3,4};

    i12 : t = 5/2;

    i13 : I = multiplierIdeal(R,n,t)

                  2         2
    o13 = ideal (y  - x*z, x  - z)

    o13 : Ideal of R

## multiplier ideal of a generic determinantal ideal

- Usage:
    `multiplierIdeal(R,L,r,t)`
- Inputs:
  - R, a ring, a ring
  - L, a list, dimensions $\{m,n\}$ of a matrix
  - r, an integer, the size of minors generating the determinantal ideal
  - t, a rational number, a coefficient
- Outputs:
  - an ideal,

Computes the multiplier ideal of the ideal of $r \times r$ minors in a $m \times n$ matrix whose entries are independent variables in the ring $R$ (a generic matrix).

    i14 : x = symbol x;

    i15 : R = QQ[x_1..x_20];

    i16 : X = genericMatrix(R,4,5);

                  4      5
    o16 : Matrix R  <-- R

    i17 : multiplierIdeal(X,2,5/7)

    o17 = ideal 1

    o17 : Ideal of R

## See also

- MonomialIdeal -- the class of all monomial ideals handled by the engine

## Ways to use this method:

- `multiplierIdeal(CentralArrangement,List,Number)`
- `multiplierIdeal(CentralArrangement,Number)`
- `multiplierIdeal(Matrix,ZZ,QQ)`
- `multiplierIdeal(Matrix,ZZ,ZZ)`
- multiplierIdeal(MonomialIdeal,QQ) -- multiplier ideal
- `multiplierIdeal(MonomialIdeal,ZZ)`
- `multiplierIdeal(Ring,List,QQ)`
- `multiplierIdeal(Ring,List,ZZ)`

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/MultiplierIdeals.m2:1892:0.