Macaulay2 » Documentation
Packages » RationalMaps :: baseLocusOfMap
next | previous | forward | backward | up | index | toc

# baseLocusOfMap -- the base locus of a map from a projective variety to projective space

- Usage:
    `I = baseLocusOfMap(h)`
    `I = baseLocusOfMap(phi)`
- Inputs:
  - h, a ring map, a ring map corresponding to a rational map of projective varieties
  - phi, an instance of the type RationalMapping, a rational map between projective varieties
- Optional inputs:
  - SaturateOutput => a Boolean value, default value true, if set to true then the output will be saturated
  - Verbosity => an integer, default value 0, if 0 then silence the function, if 1 then generate informative output which can be used to adjust strategies, if > 1 then generate a detailed description of the execution
- Outputs:
  - I, an ideal, the saturated defining ideal of the base locus of the corresponding maps

## Description

This defines the locus where a given map of projective varieties is not defined. If the option SaturateOutput is set to false, the output will not be saturated. The default value is true. Consider the following rational map from $P^2$ to $P^1$.

    i1 : R = QQ[x,y,z];

    i2 : S = QQ[a,b];

    i3 : f = map(R, S, {x,y});

    o3 : RingMap R <-- S

    i4 : baseLocusOfMap(f)

    o4 = ideal (y, x)

    o4 : Ideal of R

Observe it is not defined at the point [0:0:1], which is exactly what one expects. However, we can restrict the map to a curve in $P^2$ and then it will be defined everywhere.

    i5 : R=QQ[x,y,z]/(y^2*z-x*(x-z)*(x+z));

    i6 : S=QQ[a,b];

    i7 : f=rationalMapping(R,S,{x,y});

    i8 : baseLocusOfMap(f)

    o8 = ideal 1

    o8 : Ideal of R

Let us next consider the quadratic Cremona transformation.

    i9 : R=QQ[x,y,z];

    i10 : S=QQ[a,b,c];

    i11 : f=map(R,S,{y*z,x*z,x*y});

    o11 : RingMap R <-- S

    i12 : J=baseLocusOfMap(f)

    o12 = ideal (y*z, x*z, x*y)

    o12 : Ideal of R

    i13 : minimalPrimes J

    o13 = {ideal (y, x), ideal (z, x), ideal (z, y)}

    o13 : List

The base locus is exactly the three points one expects.

## Ways to use baseLocusOfMap:

- `baseLocusOfMap(RationalMapping)`
- `baseLocusOfMap(RingMap)`

## For the programmer

The object baseLocusOfMap is a method function with options.

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/RationalMaps.m2:2075:0.