Macaulay2 » Documentation
Packages » Macaulay2Doc » commutative algebra » hilbertPolynomial » ProjectiveHilbertPolynomial » hilbertSeries(ProjectiveHilbertPolynomial)
next | previous | forward | backward | up | index | toc

# hilbertSeries(ProjectiveHilbertPolynomial) -- compute the Hilbert series of a projective Hilbert polynomial

- Function: hilbertSeries
- Usage:
    `hilbertSeries P`
- Inputs:
  - P, a projective Hilbert polynomial
- Optional inputs:
  - Order => ..., default value infinity, display the truncated power series expansion
  - Reduce => ..., default value false, reduce the Hilbert series
- Outputs:
  - a divide expression, the Hilbert series

## Description

We compute the Hilbert series of a projective Hilbert polynomial.

    i1 : P = projectiveHilbertPolynomial 3

    o1 = P
          3

    o1 : ProjectiveHilbertPolynomial

    i2 : s = hilbertSeries P

             1
    o2 = --------
                4
         (1 - T)

    o2 : Expression of class Divide

    i3 : numerator s

    o3 = 1

    o3 : ZZ[T]

Computing the Hilbert series of a projective variety can be useful for finding the h-vector of a simplicial complex from its f-vector. For example, consider the octahedron. The ideal below is its Stanley-Reisner ideal. We can see its f-vector (1, 6, 12, 8) in the Hilbert polynomial, and then we get the h-vector (1,3,3,1) from the coefficients of the Hilbert series projective Hilbert polynomial.

    i4 : R = QQ[a..h];

    i5 : I = ideal (a*b, c*d, e*f);

    o5 : Ideal of R

    i6 : P=hilbertPolynomial(I)

    o6 = - P  + 6*P  - 12*P  + 8*P
            1      2       3      4

    o6 : ProjectiveHilbertPolynomial

    i7 : s = hilbertSeries P

                    2    3
         1 + 3T + 3T  + T
    o7 = -----------------
                     5
              (1 - T)

    o7 : Expression of class Divide

    i8 : numerator s

                    2    3
    o8 = 1 + 3T + 3T  + T

    o8 : ZZ[T]

## Ways to use this method:

- hilbertSeries(ProjectiveHilbertPolynomial) -- compute the Hilbert series of a projective Hilbert polynomial

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/Macaulay2Doc/functions/hilbertSeries-doc.m2:146:0.