Macaulay2 » Documentation
Packages » Permutations :: Group actions
next | previous | forward | backward | up | index | toc

# Group actions -- an overview of permutations acting on objects in Macaulay2

A permutation on $n$ symbols acts on lists of size $n$ by permuting its contents according to the permutation.

    i1 : p = permutation {3,1,2,5,4};

    i2 : L = {1,2,3,4,5};

    i3 : p*L

    o3 = {3, 1, 2, 5, 4}

    o3 : List

A permutation $p$ on $n$ symbols can also be regarded as a permutation on $N$ symbols for any $N \geq n$ by regarding all of the indices $n+1, n+2, \dots$ as fixed by $p$, i.e., $p(i)=i$ for all $i > n$. This is also reflected in the group action.

    i4 : p = permutation {3,1,2,5,4};

    i5 : L = {1,2,3,4,5,6,7,8};

    i6 : p*L

    o6 = {3, 1, 2, 5, 4, 6, 7, 8}

    o6 : List

In a similar manner, permutations on $n$ symbols also act on the space of $m \times n$ matrices by permuting the rows (or columns). Another way to view this action is via the multiplication on the left by the matrix representation of the permutation (if acting on the rows).

    i7 : p = permutation {3,1,2};

    i8 : M = id_(ZZ^3);

                  3       3
    o8 : Matrix ZZ  <-- ZZ

    i9 : p*M

    o9 = | 0 1 0 |
         | 0 0 1 |
         | 1 0 0 |

                  3       3
    o9 : Matrix ZZ  <-- ZZ

Just as in the case of lists, the size of the matrix can be larger than $n$. Example p = permutation {3,1,2}; M = id_(ZZ^5); p*M

The matrix does not need to be square. As long as the number of rows is greater than or equal largest non-fixed point of the permutation, the action is valid.

    i10 : p = permutation {3,1,2};

    i11 : M = id_(ZZ^3) || id_(ZZ^3);

                   6       3
    o11 : Matrix ZZ  <-- ZZ

    i12 : N = matrix {{1,0},{0,1},{1,1}};

                   3       2
    o12 : Matrix ZZ  <-- ZZ

    i13 : p*M

    o13 = | 0 1 0 |
          | 0 0 1 |
          | 1 0 0 |
          | 1 0 0 |
          | 0 1 0 |
          | 0 0 1 |

                   6       3
    o13 : Matrix ZZ  <-- ZZ

    i14 : p*N

    o14 = | 0 1 |
          | 1 1 |
          | 1 0 |

                   3       2
    o14 : Matrix ZZ  <-- ZZ

We can also act on the columns of the matrix in a similar way.

    i15 : p = permutation {3,1,2};

    i16 : M = id_(ZZ^3) || id_(ZZ^3);

                   6       3
    o16 : Matrix ZZ  <-- ZZ

    i17 : N = matrix {{1,0,0,0},{0,1,0,0},{0,0,1,0}};

                   3       4
    o17 : Matrix ZZ  <-- ZZ

    i18 : M*p

    o18 = | 0 0 1 |
          | 1 0 0 |
          | 0 1 0 |
          | 0 0 1 |
          | 1 0 0 |
          | 0 1 0 |

                   6       3
    o18 : Matrix ZZ  <-- ZZ

    i19 : N*p

    o19 = | 0 0 1 0 |
          | 1 0 0 0 |
          | 0 1 0 0 |

                   3       4
    o19 : Matrix ZZ  <-- ZZ

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/Permutations/Documentation/packageDocs.m2:153:0.