Macaulay2 » Documentation
Packages » Schubert2 » Examples from Schubert, translated » Example from Schubert: Lines on a quintic threefold
next | previous | forward | backward | up | index | toc

# Example from Schubert: Lines on a quintic threefold

    # Lines on a quintic threefold.  This is the top Chern class of the
    # 5th symmetric power of the universal quotient bundle on the Grassmannian
    # of lines.
    >
    > grass(2,5,c):        # Lines in P^4.

    i1 : Gc = flagBundle({3,2}, VariableNames => {,c})

    o1 = Gc

    o1 : a flag bundle with subquotient ranks {3, 2}

    i2 : (Sc,Qc) = bundles Gc

    o2 = (Sc, Qc)

    o2 : Sequence

    > B:=symm(5,Qc):       # Qc is the rank 2 quotient bundle, B its 5th
    >                      # symmetric power.

    i3 : B = symmetricPower(5,Qc)

    o3 = B

    o3 : an abstract sheaf of rank 6 on Gc

    > c6:=chern(rank(B),B):# the 6th Chern class of this rank 6 bundle.

    i4 : c6 = chern(rank B,B)

              3
    o4 = 2875c
              2

                                          QQ[][H   ..H   , c ..c ]
                                                1,1   1,3   1   2
    o4 : -----------------------------------------------------------------------------------------
         (- H    - c , - H    - H   c  - c , - H    - H   c  - H   c , - H   c  - H   c , -H   c )
             1,1    1     1,2    1,1 1    2     1,3    1,2 1    1,1 2     1,3 1    1,2 2    1,3 2

    > integral(c6);
                                          2875

    i5 : integral c6

    o5 = 2875

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/Schubert2.m2:1857:0.