Macaulay2 » Documentation
Packages » GradedLieAlgebras :: koszulDual
next | previous | forward | backward | up | index | toc

# koszulDual -- compute the Lie algebra whose enveloping algebra is the Koszul dual of a quadratic algebra

- Usage:
    `L = koszulDual(Q)`
- Inputs:
  - Q, a quotient ring, the input type may also be PolynomialRing
- Outputs:
  - L, an instance of the type LieAlgebra,

## Description

The input $Q$ is a quotient of a polynomial algebra by a quadratic ideal (which might be 0). Some of the variables may be declared as SkewCommutative. Moreover, the variables may have multi-degrees where the first degree is equal to $1$. The quadratic ideal must be homogeneous with respect to the multi-degree and the "skew-degree". The output is the Lie algebra whose enveloping algebra is the Koszul dual of $Q$.

    i1 : R1=QQ[x,y,z, SkewCommutative=>{y,z}]

    o1 = R1

    o1 : PolynomialRing, 2 skew commutative variable(s)

    i2 : I1={x^2,y*z}

           2
    o2 = {x , y*z}

    o2 : List

    i3 : L1=koszulDual(R1/ideal I1)

    o3 = L1

    o3 : LieAlgebra

    i4 : describe L1

    o4 = generators => {ko , ko , ko }
                          0    1    2
         Weights => {{1, 0}, {1, 0}, {1, 0}}
         Signs => {1, 0, 0}
         ideal => { - (ko_1 ko_0),  - (ko_2 ko_0)}
         ambient => LieAlgebra{...10...}
         diff => {}
         Field => QQ
         computedDegree => 0

    i5 : E1=extAlgebra(3,L1)

    o5 = E1

    o5 : ExtAlgebra

    i6 : dims(3,E1)

    o6 = | 3 0 0 |
         | 0 2 0 |
         | 0 0 0 |

                  3       3
    o6 : Matrix ZZ  <-- ZZ

Here is an example of a non-Koszul algebra. The table for the Ext-algebra has a non-zero occurrence off the diagonal.

    i7 : R2=QQ[x,y,z, SkewCommutative=>{},Degrees=>{{1,1},{1,2},{1,3}}]

    o7 = R2

    o7 : PolynomialRing

    i8 : I2=ideal{y^2+x*z,x*y,z^2}

                 2              2
    o8 = ideal (y  + x*z, x*y, z )

    o8 : Ideal of R2

    i9 : L2=koszulDual(R2/I2)

    o9 = L2

    o9 : LieAlgebra

    i10 : describe L2

    o10 = generators => {ko , ko , ko }
                           0    1    2
          Weights => {{1, 1, 0}, {1, 2, 0}, {1, 3, 0}}
          Signs => {1, 1, 1}
          ideal => { - (1/2)(ko_0 ko_0), (1/2)(ko_1 ko_1) - (ko_2 ko_0),  - (ko_2 ko_1)}
          ambient => LieAlgebra{...10...}
          diff => {}
          Field => QQ
          computedDegree => 0

    i11 : E2=extAlgebra(4,L2)

    o11 = E2

    o11 : ExtAlgebra

    i12 : dims(4,E2)

    o12 = | 3 0 0 0 |
          | 0 3 0 0 |
          | 0 0 1 1 |
          | 0 0 0 1 |

                   4       4
    o12 : Matrix ZZ  <-- ZZ

## See also

- minimalModel -- compute the minimal model
- extAlgebra -- compute the Ext-algebra of a Lie algebra

## Ways to use koszulDual:

- `koszulDual(PolynomialRing)`
- `koszulDual(QuotientRing)`

## For the programmer

The object koszulDual is a method function.

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/GradedLieAlgebras/doc2.m2:2090:0.