Macaulay2 » Documentation
Packages » BettiCharacters » characterTable » Labels
next | previous | forward | backward | up | index | toc

# Labels -- custom labels for irreducible characters

## Description

This optional input is used with the method characterTable provided by the package BettiCharacters.

By default, irreducible characters in a character table are labeled as X0, X1, ..., etc. The user may pass custom labels in a list using this option.

The next example sets up the character table of the dihedral group $D_4$, generated by an order 4 rotation $r$ and an order 2 reflection $s$ with the relation $srs=r^3$. The representatives of the conjugacy classes are, in order: the identity, $r^2$, $r$, $s$, and $rs$. Besides the trivial representation, $D_4$ has three irreducible one-dimensional representations, corresponding to the three normal subgroups of index two: $\langle r\rangle$, $\langle r^,,s\rangle$, and $\langle r^2,rs\rangle$. The characters of these representations send the elements of the corresponding subgroup to 1, and the other elements to -1. We denote those characters rho1,rho2,rho3. Finally, there is a unique irreducible representation of dimension 2.

    i1 : R = QQ[x,y]

    o1 = R

    o1 : PolynomialRing

    i2 : D8 = { matrix{{x,y}},
                matrix{{-x,-y}},
                matrix{{-y,x}},
                matrix{{x,-y}},
                matrix{{y,x}} }

    o2 = {| x y |, | -x -y |, | -y x |, | x -y |, | y x |}

    o2 : List

    i3 : M = matrix {{1,1,1,1,1},
             {1,1,1,-1,-1},
             {1,1,-1,1,-1},
             {1,1,-1,-1,1},
             {2,-2,0,0,0}};

                  5       5
    o3 : Matrix ZZ  <-- ZZ

    i4 : T = characterTable({1,1,2,2,2},M,R,{1,2,3,4,5},
             Labels=>{"triv","rho1","rho2","rho3","dim2"})

    o4 = Character table over R

               |  1   1   2   2   2
         ------+-------------------
         triv  |  1   1   1   1   1
         rho1  |  1   1   1  -1  -1
         rho2  |  1   1  -1   1  -1
         rho3  |  1   1  -1  -1   1
         dim2  |  2  -2   0   0   0

    o4 : CharacterTable

The same labels are automatically used when decomposing characters against a labeled character table.

    i5 : A = action(R,D8)

    o5 = PolynomialRing with 5 actors

    o5 : ActionOnGradedModule

    i6 : c = character(A,0,8)

    o6 = Character over R

         (0, {0}) => | 1 1 1 1 1 |
         (0, {1}) => | 2 -2 0 0 0 |
         (0, {2}) => | 3 3 -1 1 1 |
         (0, {3}) => | 4 -4 0 0 0 |
         (0, {4}) => | 5 5 1 1 1 |
         (0, {5}) => | 6 -6 0 0 0 |
         (0, {6}) => | 7 7 -1 1 1 |
         (0, {7}) => | 8 -8 0 0 0 |
         (0, {8}) => | 9 9 1 1 1 |

    o6 : Character

    i7 : decomposeCharacter(c,T)

    o7 = Decomposition table

                   |  triv  rho1  rho2  rho3  dim2
         ----------+------------------------------
         (0, {0})  |     1     0     0     0     0
         (0, {1})  |     0     0     0     0     1
         (0, {2})  |     1     0     1     1     0
         (0, {3})  |     0     0     0     0     2
         (0, {4})  |     2     1     1     1     0
         (0, {5})  |     0     0     0     0     3
         (0, {6})  |     2     1     2     2     0
         (0, {7})  |     0     0     0     0     4
         (0, {8})  |     3     2     2     2     0

    o7 : CharacterDecomposition

The labels are stored in the character table under the key Labels.

## See also

- characterTable -- construct a character table
- decomposeCharacter -- decompose a character into irreducible characters

## Functions with optional argument named Labels:

- `characterTable(...,Labels=>...)`

## For the programmer

The object Labels is a symbol.

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/BettiCharacters.m2:2859:0.