Macaulay2 » Documentation
Packages » ReflexivePolytopesDB :: kreuzerSkarkeDim3
next | previous | forward | backward | up | index | toc

# kreuzerSkarkeDim3 -- the list of 4319 dimension 3 reflexive polytopes in the Kreuzer-Skarke database

- Usage:
    `kreuzerSkarkeDim3()`
- Outputs:
  - a list, A list of KSEntry's, each one representing one of the 4319 polytopes (including description header information). Use matrix(KSEntry) to make any element in this list into something usable from Macaulay2.

## Description

As a an example, let's take the 101th example on this list.

    i1 : topes = kreuzerSkarkeDim3();

    i2 : #topes

    o2 = 4319

    i3 : tope = topes_100

    o3 = 3 5  M:12 5 N:15 5 Pic:13 Cor:4 id:100
             1    0    0   -3    1
             0    1    0    0   -2
             0    0    1   -2    2

    o3 : KSEntry

    i4 : header = description tope

    o4 = 3 5  M:12 5 N:15 5 Pic:13 Cor:4 id:100

    i5 : A = matrix tope

    o5 = | 1 0 0 -3 1  |
         | 0 1 0 0  -2 |
         | 0 0 1 -2 2  |

                  3       5
    o5 : Matrix ZZ  <-- ZZ

The first line gives some information about the example, see Kreuzer-Skarke description headers for more details. The polytope is the convex hull of the columns of the matrix $A$.

One can use the packages Polyhedra and NormalToricVarieties to investigate these polyhedra, and the associated toric varieties.

    i6 : needsPackage "Polyhedra"

    o6 = Polyhedra

    o6 : Package

    i7 : P = convexHull A

    o7 = P

    o7 : Polyhedron

    i8 : P2 = polar P

    o8 = P2

    o8 : Polyhedron

    i9 : # latticePoints P

    o9 = 12

    i10 : # latticePoints P2

    o10 = 15

    i11 : # vertices P

    o11 = 5

    i12 : # vertices P2

    o12 = 5

    i13 : isReflexive P

    o13 = true

    i14 : needsPackage "NormalToricVarieties"

    o14 = NormalToricVarieties

    o14 : Package

    i15 : V0 = normalToricVariety normalFan P

    o15 = V0

    o15 : NormalToricVariety

    i16 : dim V0

    o16 = 3

    i17 : max V0

    o17 = {{0, 1, 2}, {0, 1, 4}, {0, 2, 3, 4}, {1, 2, 3}, {1, 3, 4}}

    o17 : List

    i18 : rays V0

    o18 = {{1, 0, -1}, {-1, -1, -1}, {1, -1, -1}, {-1, -1, 2}, {-1, 2, 2}}

    o18 : List

    i19 : V = makeSimplicial V0

    o19 = V

    o19 : NormalToricVariety

    i20 : isSimplicial V

    o20 = true

    i21 : isProjective V

    o21 = true

    i22 : isSmooth V

    o22 = false

    i23 : dim V

    o23 = 3

## See also

- kreuzerSkarke -- access Kreuzer-Skarke dimension 4 reflexive polytopes database
- matrix(KSEntry) -- convert a Kreuzer-Skarke entry to a matrix of integers
- description(KSEntry) -- the description header
- Kreuzer-Skarke description headers -- information contained in the description line

## For the programmer

The object kreuzerSkarkeDim3 is a function closure.

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/ReflexivePolytopesDB.m2:676:0.