Macaulay2 » Documentation
Packages » Macaulay2Doc » commutative algebra » hilbertSeries » hilbertSeries(...,Order=>...)
next | previous | forward | backward | up | index | toc

# hilbertSeries(...,Order=>...) -- display the truncated power series expansion

- Usage:
    `hilbertSeries(..., Order => n)`
- Inputs:
  - n, an integer
- Consequences:
  - The output is no longer of type Divide. It is a polynomial in the degrees ring.

## Description

We compute the Hilbert series both without and with the optional argument. In the second case notice the terms of power series expansion up to, but not including, degree 5 are displayed rather than expressing the series as a rational function. The polynomial expression is an element of a Laurent polynomial ring that is the degrees ring of the ambient ring.

    i1 : R = ZZ/101[x,y];

    i2 : hilbertSeries(R/x^3)

               3
          1 - T
    o2 = --------
                2
         (1 - T)

    o2 : Expression of class Divide

    i3 : hilbertSeries(R/x^3, Order =>5)

                    2     3     4
    o3 = 1 + 2T + 3T  + 3T  + 3T

    o3 : ZZ[T]

If the ambient ring is multigraded, then the degrees ring has multiple variables.

    i4 : R = ZZ/101[x,y, Degrees=>{{1,2},{2,3}}];

    i5 : hilbertSeries(R/x^3, Order =>5)

                2    2 4    2 3    3 5    4 7    4 6
    o5 = 1 + T T  + T T  + T T  + T T  + T T  + T T
              0 1    0 1    0 1    0 1    0 1    0 1

    o5 : ZZ[T ..T ]
             0   1

The heft vector provides a suitable monomial ordering and degrees in the ring of the Hilbert series.

    i6 : R = QQ[a..d,Degrees=>{{-2,-1},{-1,0},{0,1},{1,2}}]

    o6 = R

    o6 : PolynomialRing

    i7 : hilbertSeries(R, Order =>3)

                2         -1    -2 -1    2 4      3     2     -1       -2
    o7 = 1 + T T  + T  + T   + T  T   + T T  + T T  + 2T  + 2T  T  + 2T   +
              0 1    1    0     0  1     0 1    0 1     1     0  1     0
         ------------------------------------------------------------------------
          -3 -1    -4 -2
         T  T   + T  T
          0  1     0  1

    o7 : ZZ[T ..T ]
             0   1

    i8 : degrees ring oo

    o8 = {{-1}, {1}}

    o8 : List

    i9 : heft R

    o9 = {-1, 1}

    o9 : List

## Functions with optional argument named Order:

- hilbertSeries(...,Order=>...) -- display the truncated power series expansion

## Further information

- Default value: infinity
- Function: hilbertSeries -- compute the Hilbert series
- Option key: Order -- an optional argument

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/Macaulay2Doc/functions/hilbertSeries-doc.m2:182:0.