Macaulay2 » Documentation
Packages » MultiprojectiveVarieties :: graph(MultirationalMap)
next | previous | forward | backward | up | index | toc

# graph(MultirationalMap) -- the graph of a multi-rational map

- Function: graph
- Usage:
    `graph Phi`
- Inputs:
  - Phi, a multi-rational map
- Optional inputs:
  - BlowUpStrategy => ..., default value "Eliminate",
- Outputs:
  - a multi-rational map, the first projection from the graph of Phi
  - a multi-rational map, the second projection from the graph of Phi

## Description

The equalities (first graph Phi) * Phi == last graph Phi and (first graph Phi)^-1 * (last graph Phi) == Phi are always satisfied.

    i1 : Phi = rationalMap(PP_(ZZ/333331)^(1,4),Dominant=>true)

    o1 = Phi

    o1 : MultirationalMap (dominant rational map from PP^4 to hypersurface in PP^5)

    i2 : time (Phi1,Phi2) = graph Phi
     -- used 0.0231869s (cpu); 0.0221667s (thread); 0s (gc)

    o2 = (Phi1, Phi2)

    o2 : Sequence

    i3 : Phi1;

    o3 : MultirationalMap (birational map from 4-dimensional subvariety of PP^4 x PP^5 to PP^4)

    i4 : Phi2;

    o4 : MultirationalMap (dominant rational map from 4-dimensional subvariety of PP^4 x PP^5 to hypersurface in PP^5)

    i5 : time (Phi21,Phi22) = graph Phi2
     -- used 0.0340831s (cpu); 0.0336471s (thread); 0s (gc)

    o5 = (Phi21, Phi22)

    o5 : Sequence

    i6 : Phi21;

    o6 : MultirationalMap (birational map from 4-dimensional subvariety of PP^4 x PP^5 x PP^5 to 4-dimensional subvariety of PP^4 x PP^5)

    i7 : Phi22;

    o7 : MultirationalMap (dominant rational map from 4-dimensional subvariety of PP^4 x PP^5 x PP^5 to hypersurface in PP^5)

    i8 : time (Phi211,Phi212) = graph Phi21
     -- used 0.178363s (cpu); 0.137673s (thread); 0s (gc)

    o8 = (Phi211, Phi212)

    o8 : Sequence

    i9 : Phi211;

    o9 : MultirationalMap (birational map from 4-dimensional subvariety of PP^4 x PP^5 x PP^5 x PP^4 x PP^5 to 4-dimensional subvariety of PP^4 x PP^5 x PP^5)

    i10 : Phi212;

    o10 : MultirationalMap (birational map from 4-dimensional subvariety of PP^4 x PP^5 x PP^5 x PP^4 x PP^5 to 4-dimensional subvariety of PP^4 x PP^5)

    i11 : assert(
          source Phi1 == source Phi2 and target Phi1 == source Phi and target Phi2 == target Phi and
          source Phi21 == source Phi22 and target Phi21 == source Phi2 and target Phi22 == target Phi2 and
          source Phi211 == source Phi212 and target Phi211 == source Phi21 and target Phi212 == target Phi21)

    i12 : assert(Phi1 * Phi == Phi2 and Phi21 * Phi2 == Phi22 and Phi211 * Phi21 == Phi212)

## See also

- graph(RationalMap) -- closure of the graph of a rational map
- MultirationalMap * MultirationalMap -- composition of multi-rational maps
- MultirationalMap == MultirationalMap -- equality of multi-rational maps
- inverse(MultirationalMap) -- inverse of a birational map

## Ways to use this method:

- graph(MultirationalMap) -- the graph of a multi-rational map

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/MultiprojectiveVarieties.m2:3147:0.