Macaulay2 » Documentation
Packages » ConnectionMatrices » Gauss' hypergeometric function
next | previous | forward | backward | up | index | toc

# Gauss' hypergeometric function

Consider the GKZ system representing the Gauss hypergeometric function as in [SST, Example 1.2.9].

    i1 : D = makeWeylAlgebra(frac(QQ[a,b,c])[x_1..x_4]);

    i2 : I = ideal(dx_2*dx_3 - dx_1*dx_4,x_1*dx_1 - x_4*dx_4 + 1 - c,x_2*dx_2 + x_4*dx_4 + a,x_3*dx_3 + x_4*dx_4 + b);

    o2 : Ideal of D

    i3 : assert(2 == holonomicRank I)

    i4 : standardMonomials I

    o4 = {1, dx }
               4

    o4 : List

[SST, Example 1.4.23] computes the connection matrices for this system with constants $a=1/2,b=1/2,c=1$. Using the connectionMatrices function, we can find the system for arbitrary constants.

    i5 : A = connectionMatrices I;

    i6 : isIntegrable A

    o6 = true

    i7 : netList(Boxes => false, VerticalSpace => 1, apply(4, i -> i+1 => A#i))

    o7 = 1 => | (c-1)/x_1          x_4/x_1                              |
              | ab/(x_2x_3-x_1x_4) (x_4a+x_4b-x_4c+x_4)/(x_2x_3-x_1x_4) |

         2 => | -a/x_2                      -x_4/x_2                                               |
              | -x_1ab/(x_2^2x_3-x_1x_2x_4) (-x_2x_3a-x_1x_4b+x_2x_3c-x_2x_3)/(x_2^2x_3-x_1x_2x_4) |

         3 => | -b/x_3                      -x_4/x_3                                               |
              | -x_1ab/(x_2x_3^2-x_1x_3x_4) (-x_1x_4a-x_2x_3b+x_2x_3c-x_2x_3)/(x_2x_3^2-x_1x_3x_4) |

         4 => | 0                          1                                                     |
              | x_1ab/(x_2x_3x_4-x_1x_4^2) (x_1x_4a+x_1x_4b-x_2x_3c+x_1x_4)/(x_2x_3x_4-x_1x_4^2) |

Substituting the constants, we note that example in [SST] contains a small misprint.

- $A_1=\left(\!\begin{array}{cc} 0&\frac{x_{4}}{x_{1}}\\ \frac{1}{4\,x_{2}x_{3}-4\,x_{1}x_{4}}&\frac{x_{4}}{x_{2}x_{3}-x_{1}x_{4}} \end{array}\!\right)$
- $A_2=\left(\!\begin{array}{cc} -\frac{1}{2\,x_{2}}&-\frac{x_{4}}{x_{2}}\\ -\frac{x_{1}}{4\,x_{2}^{2}x_{3}-4\,x_{1}x_{2}x_{4}}&\frac{-x_{2}x_{3}-x_{1}x_{4}}{2\,x_{2}^{2}x_{3}-2\,x_{1}x_{2}x_{4}} \end{array}\!\right)$
- $A_3=\left(\!\begin{array}{cc} -\frac{1}{2\,x_{3}}&-\frac{x_{4}}{x_{3}}\\ -\frac{x_{1}}{4\,x_{2}x_{3}^{2}-4\,x_{1}x_{3}x_{4}}&\frac{-x_{2}x_{3}-x_{1}x_{4}}{2\,x_{2}x_{3}^{2}-2\,x_{1}x_{3}x_{4}} \end{array}\!\right)$
- $A_4=\left(\!\begin{array}{cc} 0&1\\ \frac{x_{1}}{4\,x_{2}x_{3}x_{4}-4\,x_{1}x_{4}^{2}}&\frac{-x_{2}x_{3}+2\,x_{1}x_{4}}{x_{2}x_{3}x_{4}-x_{1}x_{4}^{2}} \end{array}\!\right)$

## References

[SST] M. Saito, B. Sturmfels, and N. Takayama. Gröbner Deformations of Hypergeometric Differential Equations. Volume 6 of Algorithms and Computation in Mathematics. Springer, 2000.

## See also

- Cosmological correlator for the 2-site chain
- Massless one-loop triangle Feynman diagram

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/ConnectionMatrices/examples.m2:141:0.