Macaulay2 » Documentation
Packages » Macaulay2Doc » map » Hom » homomorphism'
next | previous | forward | backward | up | index | toc

# homomorphism' -- get the element of Hom from a homomorphism

- Usage:
    `homomorphism' f`
- Inputs:
  - f, a matrix, of the form $M \to N$
- Optional inputs:
  - DegreeLimit => an integer or a list, default value null, see Hom(...,DegreeLimit=>...)
  - MinimalGenerators => a Boolean value, default value true, see Hom(...,MinimalGenerators=>...)
  - Strategy => a thing, default value null, see Hom(...,Strategy=>...)
- Outputs:
  - a matrix, the map $R^1 \to \mathrm{Hom}(M,N)$, corresponding to the map $f \in \mathrm{Hom}(M,N)$

## Description

    i1 : R = QQ[x,y,z]

    o1 = R

    o1 : PolynomialRing

    i2 : f = vars R ++ vars R

    o2 = | x y z 0 0 0 |
         | 0 0 0 x y z |

                 2      6
    o2 : Matrix R  <-- R

    i3 : g = homomorphism' f

    o3 = {-1} | x |
         {-1} | 0 |
         {-1} | y |
         {-1} | 0 |
         {-1} | z |
         {-1} | 0 |
         {-1} | 0 |
         {-1} | x |
         {-1} | 0 |
         {-1} | y |
         {-1} | 0 |
         {-1} | z |

                 12      1
    o3 : Matrix R   <-- R

    i4 : target g === Hom(source f, target f)

    o4 = true

We can undo the process with homomorphism.

    i5 : f' = homomorphism g

    o5 = | x y z 0 0 0 |
         | 0 0 0 x y z |

                 2      6
    o5 : Matrix R  <-- R

    i6 : f === f'

    o6 = true

## Code

    ../../m2/Hom.m2:100:34-102:46: --source code:
    homomorphism' Matrix := Matrix => opts -> f -> (
        -- from a map M --> N produce a map R^1 -> Hom(M, N)
        adjoint(f, module ring f, source f, opts))

## See also

- Hom -- module of homomorphisms
- homomorphism -- get the homomorphism from element of Hom
- adjoint -- the tensor-Hom adjunction maps

## Ways to use homomorphism':

- `homomorphism'(Matrix)`

## For the programmer

The object homomorphism' is a method function with options.

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/Macaulay2Doc/functions/Hom-doc.m2:379:0.