Macaulay2 » Documentation
Packages » CorrespondenceScrolls :: correspondenceScroll
next | previous | forward | backward | up | index | toc

# correspondenceScroll -- Union of planes joining points of rational normal curves according to a given correspondence

- Usage:
    `G = correspondenceScroll(I,scroll)`
- Inputs:
  - I, an ideal, ideal of a correspondence; an arbitrary subscheme of (P^1)^{#scroll}
  - VariableName, a string, name of the variable to use in the output
  - scroll, a list, list of positive integers, the degrees of disjoint rational normal curves
- Optional inputs:
  - VariableName => ..., default value "x"
- Outputs:
  - G, an ideal, ideal of the generalized scroll

## Description

Let L = {a_0,..a_{(m-1)}}, and let P = P^N with N = (#L-1+ sum L). Just as the ordinary scroll S(L) is the union of planes joining rational normal curves C_i of degree a_i according to some chosen isomorphism among them (a (1,1,..,1) correspondence), the generalized Scroll is the union of planes joining the points that correspond under an arbitrary correspondence, specified by I.

Thus if I is the ideal of the small diagonal of (P^1)^m, then generalized Scroll(I,L) is equal to S(L). If #L = 2, and I is the square of the ideal of the diagonal, we get a K3 carpet:

    i1 : L = {3,4}

    o1 = {3, 4}

    o1 : List

    i2 : S = productOfProjectiveSpaces(#L) --creates the multi-graded ring of (P^1)^(#L)

    o2 = S

    o2 : PolynomialRing

    i3 : Delta = smallDiagonal S -- the ideal of the small diagonal of (P^1)^(#L)

    o3 = ideal(- x   x    + x   x   )
                  0,1 1,0    0,0 1,1

    o3 : Ideal of S

    i4 : G = correspondenceScroll(Delta, L)

                 2
    o4 = ideal (x    - x   x   , x   x    - x   x   , x   x    - x   x   ,
                 1,3    1,2 1,4   1,2 1,3    1,1 1,4   1,1 1,3    1,0 1,4
         ------------------------------------------------------------------------
                                                                         2
         x   x    - x   x   , x   x    - x   x   , x   x    - x   x   , x    -
          0,3 1,3    0,2 1,4   0,2 1,3    0,1 1,4   0,1 1,3    0,0 1,4   1,2
         ------------------------------------------------------------------------

         x   x   , x   x    - x   x   , x   x    - x   x   , x   x    - x   x   ,
          1,0 1,4   1,1 1,2    1,0 1,3   0,3 1,2    0,1 1,4   0,2 1,2    0,0 1,4
         ------------------------------------------------------------------------
                               2
         x   x    - x   x   , x    - x   x   , x   x    - x   x   , x   x    -
          0,1 1,2    0,0 1,3   1,1    1,0 1,2   0,3 1,1    0,0 1,4   0,2 1,1
         ------------------------------------------------------------------------

         x   x   , x   x    - x   x   , x   x    - x   x   , x   x    - x   x   ,
          0,0 1,3   0,1 1,1    0,0 1,2   0,3 1,0    0,0 1,3   0,2 1,0    0,0 1,2
         ------------------------------------------------------------------------
                               2                                     2
         x   x    - x   x   , x    - x   x   , x   x    - x   x   , x    -
          0,1 1,0    0,0 1,1   0,2    0,1 0,3   0,1 0,2    0,0 0,3   0,1
         ------------------------------------------------------------------------
         x   x   )
          0,0 0,2

                    ZZ
    o4 : Ideal of -----[x   ..x   , x   ..x   ]
                  32003  0,0   0,3   1,0   1,4

    i5 : minimalBetti G

                0  1  2   3  4  5 6
    o5 = total: 1 21 70 105 84 35 6
             0: 1  .  .   .  .  . .
             1: . 21 70 105 84 35 6

    o5 : BettiTally

    i6 : G = correspondenceScroll(Delta^2, L)

                 2                                                          2
    o6 = ideal (x    - x   x   , x   x    - x   x   , x   x    - x   x   , x    -
                 1,3    1,2 1,4   1,2 1,3    1,1 1,4   1,1 1,3    1,0 1,4   1,2
         ------------------------------------------------------------------------

         x   x   , x   x    - x   x   , x   x    - 2x   x    + x   x   , x   x
          1,0 1,4   1,1 1,2    1,0 1,3   0,3 1,2     0,2 1,3    0,1 1,4   0,2 1,2
         ------------------------------------------------------------------------
                                  2
         - 2x   x    + x   x   , x    - x   x   , x   x    - 3x   x    +
             0,1 1,3    0,0 1,4   1,1    1,0 1,2   0,3 1,1     0,1 1,3
         ------------------------------------------------------------------------

         2x   x   , x   x    - 2x   x    + x   x   , x   x    - 3x   x    +
           0,0 1,4   0,2 1,1     0,1 1,2    0,0 1,3   0,3 1,0     0,1 1,2
         ------------------------------------------------------------------------
                                                      2
         2x   x   , x   x    - 2x   x    + x   x   , x    - x   x   , x   x    -
           0,0 1,3   0,2 1,0     0,1 1,1    0,0 1,2   0,2    0,1 0,3   0,1 0,2
         ------------------------------------------------------------------------
                    2
         x   x   , x    - x   x   )
          0,0 0,3   0,1    0,0 0,2

                    ZZ
    o6 : Ideal of -----[x   ..x   , x   ..x   ]
                  32003  0,0   0,3   1,0   1,4

    i7 : minimalBetti G

                0  1  2  3  4  5 6
    o7 = total: 1 15 35 42 35 15 1
             0: 1  .  .  .  .  . .
             1: . 15 35 21  .  . .
             2: .  .  . 21 35 15 .
             3: .  .  .  .  .  . 1

    o7 : BettiTally

Here is how to make the generalized scroll corresponding to a general elliptic curve in (P^1)^3. First, the general elliptic curve, as a plane cubic through three given points:

    i8 : T = ZZ/32003[y_0,y_1,y_2]

    o8 = T

    o8 : PolynomialRing

    i9 : threepoints = gens intersect(ideal(y_0,y_1),ideal(y_0,y_2),ideal(y_1,y_2))

    o9 = | y_1y_2 y_0y_2 y_0y_1 |

                 1      3
    o9 : Matrix T  <-- T

    i10 : f = threepoints*random(source threepoints, T^{-3}); -- general cubic through the three points

                  1      1
    o10 : Matrix T  <-- T

    i11 : L = {2,2,2}

    o11 = {2, 2, 2}

    o11 : List

    i12 : x = symbol x;

    i13 : S = productOfProjectiveSpaces(#L,VariableName =>"x") --creates the multi-graded ring of (P^1)^(#L)

    o13 = S

    o13 : PolynomialRing

    i14 : ST = (flattenRing(T**S))_0

    o14 = ST

    o14 : PolynomialRing

    i15 : irrel = irrelevantIdeal ST;

    o15 : Ideal of ST

Here the irrelevant ideal is the intersection of the 4 ideals of coordinates (P^2 and the three copies of P^1). Next, define the pairs of sections on the curve giving the three projections:

    i16 : ff =  {{y_0,y_1},{y_0,y_2},{y_1,y_2}} -- projections from the three points

    o16 = {{y , y }, {y , y }, {y , y }}
             0   1     0   2     1   2

    o16 : List

    i17 : ff =  apply(ff, f-> apply(f, p-> sub(p, ST)))

    o17 = {{y , y }, {y , y }, {y , y }}
             0   1     0   2     1   2

    o17 : List

And create the equations of the incidence variety

    i18 : D1 = det matrix{{x_(0,0),ff_0_1},{x_(0,1),ff_0_0}}

    o18 = y x    - y x
           0 0,0    1 0,1

    o18 : ST

    i19 : D2 = det matrix{{x_(1,0),ff_1_1},{x_(1,1),ff_1_0}}

    o19 = y x    - y x
           0 1,0    2 1,1

    o19 : ST

    i20 : D3 = det matrix{{x_(2,0),ff_2_1},{x_(2,1),ff_2_1}}

    o20 = y x    - y x
           2 2,0    2 2,1

    o20 : ST

    i21 : J = sub(ideal f, ST)+ideal(D1,D2,D3)

                      2             2        2                        2
    o21 = ideal (8570y y  - 15344y y  + 3187y y  + 12334y y y  + 4376y y  -
                      0 1         0 1        0 2         0 1 2        1 2
          -----------------------------------------------------------------------
                 2          2
          5307y y  - 5570y y , y x    - y x   , y x    - y x   , y x    - y x   )
               0 2        1 2   0 0,0    1 0,1   0 1,0    2 1,1   2 2,0    2 2,1

    o21 : Ideal of ST

This must be saturated with respect to the irrelevant ideal, and then the y variables are eliminated, to get the curve in (P^1)^3.

    i22 : Js = saturate(J, irrel);

    o22 : Ideal of ST

    i23 : I = eliminate({y_0,y_1,y_2}, Js);

    o23 : Ideal of ST

    i24 : IS = (map(S,ST))I;

    o24 : Ideal of S

    i25 : codim I

    o25 = 1

Finally, we compute the ideal of the generalized Scroll:

    i26 : g = correspondenceScroll(IS, L);

                     ZZ
    o26 : Ideal of -----[x   ..x   ]
                   32003  0,0   2,2

    i27 : minimalBetti g

                 0  1  2  3  4 5
    o27 = total: 1 19 59 72 39 8
              0: 1  .  .  .  . .
              1: .  3  .  .  . .
              2: . 12 43 48 23 4
              3: .  4 16 24 16 4

    o27 : BettiTally

## Caveat

The script currently uses an elimination method, but could be speeded up by replacing that with the easy direct description of the equations that come from the correspondence I.

## See also

- irrelevantIdeal -- returns the irrelevant ideal of a multi-graded ring
- productOfProjectiveSpaces -- Constructs the multi-graded ring of a product of copies of P^1 (pp is a synonym)
- smallDiagonal -- Ideal of the small diagonal in (P^1)^n

## Ways to use correspondenceScroll:

- `correspondenceScroll(Ideal,List)`

## For the programmer

The object correspondenceScroll is a method function with options.

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/CorrespondenceScrolls.m2:489:0.