Macaulay2 » Documentation
Packages » QuaternaryQuartics :: Singularities of lifting of type [300b]
next | previous | forward | backward | up | index | toc

# Singularities of lifting of type [300b] -- The lifting of [300b] defined by biliaison acquires singularities in dimension 3

We describe a way of lifting case [300b] by performing a biliaison construction. Let $X$ be a degree 7 residual component of an intersection of three quadrics containing a linear space of codimension 3.

    i1 : loadPackage "RandomIdeals"

    o1 = RandomIdeals

    o1 : Package

    i2 : kk = ZZ/101;

    i3 : R = kk[x_0..x_7];

    i4 : T = random(R^1,R^{-1,-1,-1});

                 1      3
    o4 : Matrix R  <-- R

    i5 : I = ideal(T);

    o5 : Ideal of R

    i6 : J = randomElementsFromIdeal({2,2,2},I);

    o6 : Ideal of R

    i7 : X=J:I;

    o7 : Ideal of R

Consider $SS$ the intersection of the two components of the complete intersection

    i8 : SS=X+I;

    o8 : Ideal of R

    i9 : SingSS= radical ideal singularLocus saturate SS;

    o9 : Ideal of R

    i10 : degree SingSS

    o10 = 6

    i11 : dim SingSS

    o11 = 1

Perform a biliaison uo by degree 2 of $SS$ in $X$ and get $BT$ an AG variety of degree 17 and type [300b]

    i12 : JJ = randomElementsFromIdeal({3},SS);

    o12 : Ideal of R

    i13 : IDD=X+JJ;

    o13 : Ideal of R

    i14 : PP=IDD:SS;

    o14 : Ideal of R

    i15 : BB= randomElementsFromIdeal({5},PP);

    o15 : Ideal of R

    i16 : BU=BB+X;

    o16 : Ideal of R

    i17 : BT=BU:PP;

    o17 : Ideal of R

    i18 : degree BT

    o18 = 17

We look for singularities of $BT$. Since the computation of singular locus is too long, we just check the rank of the jacobian matrix in one of the components of $SingSS$ and get that $BT$ is singular in that locus.

    i19 : minors(4,(map(R/(decompose SingSS)_0,R)) (jacobian BT))

    o19 = ideal ()

                                                        R
    o19 : Ideal of ---------------------------------------------------------------------------
                   (x  + 4x , x  + 24x , x  + 10x , x  + 5x , x  + 44x , x  - 37x , x  + 38x )
                     6     7   5      7   4      7   3     7   2      7   1      7   0      7

## See also

- [QQ] -- Quaternary Quartic Forms and Gorenstein rings (Kapustka, Kapustka, Ranestad, Schenck, Stillman, Yuan, 2021)

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/QuaternaryQuartics/Section8Doc.m2:137:0.