Macaulay2 » Documentation
Packages » Saturation :: module quotients, saturation, and annihilator
next | previous | forward | backward | up | index | toc

# module quotients, saturation, and annihilator

## Module Quotients

There are two notions associated to the colon construction for modules.

Similar to the case of ideals, the quotient of two $R$-modules $M, N$ contained in the same ambient module is an ideal $M:N$ of elements $f\in R$ such that $f N \subset M$. This is equivalent to the annihilator of the quotient module $(M+N)/M$.

The quotient of an $R$-module $M\subset F$ with respect to an ideal $J\subset R$ is the module $M:_F J$ of elements $f\in F$ such that $J f\subset M$.

## Saturation of Modules

The saturation of an $R$-module $M\subset F$ with respect to an ideal $J\subset R$ is an $R$-module $M:_F J^\infty$ of elements $f\in F$ such that $J^N f\subset M$ for some $N$ large enough. If the ideal $J$ is not given, the ideal generated by the variables of the ring $R$ is used.

If $M=M:_F J^\infty$ (or, equivalently, $M=M:_F J$), we say that $M$ is saturated with respect to $J$. We can use this command to remove graded submodules of finite length.

    i1 : R = ZZ/32003[a..d];

    i2 : m = ideal vars R

    o2 = ideal (a, b, c, d)

    o2 : Ideal of R

    i3 : M = R^1 / (a * m^2)

    o3 = cokernel | a3 a2b a2c a2d ab2 abc abd ac2 acd ad2 |

                                1
    o3 : R-module, quotient of R

    i4 : M / saturate 0_M

    o4 = cokernel | a a3 a2b a2c a2d ab2 abc abd ac2 acd ad2 |

                                1
    o4 : R-module, quotient of R

## Module Annihilators

The annihilator of an $R$-module $M$ is the ideal $\mathrm{ann}(M) = \{ f \in R | f M = 0 \}$.

    i5 : R = QQ[a..i];

    i6 : M = cokernel genericMatrix(R,a,3,3)

    o6 = cokernel | a d g |
                  | b e h |
                  | c f i |

                                3
    o6 : R-module, quotient of R

    i7 : annihilator M

    o7 = ideal(c*e*g - b*f*g - c*d*h + a*f*h + b*d*i - a*e*i)

    o7 : Ideal of R

You may also use the abbreviation ann:

    i8 : ann (M/(a*M))

    o8 = ideal (a, c*e*g - b*f*g - c*d*h + b*d*i)

    o8 : Ideal of R

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/Saturation/doc.m2:100:0.