Macaulay2 » Documentation
Packages » QuaternaryQuartics :: Type [210], CY of degree 18 via linkage
next | previous | forward | backward | up | index | toc

# Type [210], CY of degree 18 via linkage -- lifting to a 3-fold with components of degrees 11, 6, 1

We construct via linkage an arithmetically Gorenstein 3-fold $X = X_{11} \cup X_1 \cup X_6 \subset \bf{P}^7$, of degree 17, having Betti table of type [210]: For an artinian reduction $A_F$, the quadratic part of the ideal $F^\perp$ is the ideal of a plane and a line, and $F^\perp$ contains pencils of ideals of five points on a conic in the plane and three points on the line, and a 3-dimensional family of ideals of six points in the plane and two points on the line. In particular, $F^\perp$ contains the ideal of the intersection point of the line and the plane in addition to five points in the plane and two points on the line.

We construct $X_{11}$ in a quadric in a P6, $X_{6}$ in a quadric in a P5 and $X_{1}$ in the P4 of intersection of P5 and P6. In the construction the intersection $X\cup X'$ of a component $X$ with the other is an anticanonical divisor on $X$.

$\phantom{WWWW} \begin{matrix} &0&1&2&3&4\\\text{total:}&1&11&20&11&1\\ \text{0:}&1&\text{.}&\text{.}&\text{.}&\text{.}\\ \text{1:}&\text{.}&2&1&\text{.}&\text{.}\\ \text{2:}&\text{.}&9&18&9&\text{.}\\ \text{3:}&\text{.}&\text{.}&1&2&\text{.}\\ \text{4:}&\text{.}&\text{.}&\text{.}&\text{.}&1\\ \end{matrix} $

    i1 : kk = QQ;

    i2 : U=kk[y0,y1,y2,y3,y4,y5,y6,y7];

    i3 : X1 = ideal(y0,y5,y6,y7); -- the component X1, a P3

    o3 : Ideal of U

    i4 : P3a = ideal(y0,y1,y2,y3); --another  P3

    o4 : Ideal of U

    i5 : P4 = ideal(y0,y6,y7); --a P4

    o5 : Ideal of U

    i6 : P5 = ideal(y6,y7); --a P5

    o6 : Ideal of U

    i7 : P6 = ideal(y0); -- a P6

    o7 : Ideal of U

Construct a $(2,2)$ complete intersection in $X_1$:

    i8 : CI22 = X1 + ideal(random(2,P3a),random(2,P3a));

    o8 : Ideal of U

Compute the ideal of the union of $CI_{22}$ and the other $\PP^3$. Then compute a complete intersection of type $(1,2,2,2)$ which contains $\PP^3_a$ and $CI_{22}$.

    i9 : CIP3 = intersect(CI22,P3a);  --the union of CI22 and P3a

    o9 : Ideal of U

    i10 : CI1222 = trim(
              ideal(y0) +
              ideal(random(2,CIP3),random(2,CIP3),random(2,CIP3)));

    o10 : Ideal of U

We take the residual in this complete intersection of the $\PP^3_a$.

    i11 : X7 = CI1222:P3a;   -- the 3-fold X7 linked (1,2,2,2) to PL

    o11 : Ideal of U

    i12 : (dim X7, degree X7)

    o12 = (4, 7)

    o12 : Sequence

    i13 : QX7 = ideal random(2,X7);--a quadric hypersurface that contains X7

    o13 : Ideal of U

    i14 : Z2a = X1 + QX7;-- quadric that contain X7 intersected with X1

    o14 : Ideal of U

    i15 : X7Z2 = intersect(Z2a,X7);-- the union of  Z2 and X7

    o15 : Ideal of U

    i16 : Z6 = P4 + QX7 + ideal(random(3,X7Z2));--a complete intersection 2,3 in P4

    o16 : Ideal of U

    i17 : X7Z6 = intersect(X7,Z6);  --the union of X7 and the complete intersection 2,3 in P4

    o17 : Ideal of U

    i18 : CI1233 = P6 + QX7 + ideal(random(3,X7Z6),random(3,X7Z6));--complete intersection 1233 containing  Z2a and a hyperplane section of X7

    o18 : Ideal of U

    i19 : X11 = CI1233:X7;  --a 3-fold of degree 11.

    o19 : Ideal of U

    i20 : Z4 = Z6:Z2a;--a Del Pezzo surface in P4

    o20 : Ideal of U

    i21 : Y2 = P5+ideal(random(2,Z4));--a quadric 4-fold in P5 that contain Z4

    o21 : Ideal of U

    i22 : Z2b = X1+Y2;-- another quadric surface in X1

    o22 : Ideal of U

    i23 : Z6b = intersect(Z4,Z2b);-- a complete intersection 2,3 different from Z6a, the union of Z4 and Z2b

    o23 : Ideal of U

    i24 : Y3 = P5 + ideal(random(3,Z6b));--a cubic 4-fold in P5 that contain Z6b

    o24 : Ideal of U

    i25 : X6 = Y2 + Y3;

    o25 : Ideal of U

    i26 : X18 = intersect(X11,X6,X1);--a AG 3-fold of degree 18, with betti table of type 210.

    o26 : Ideal of U

    i27 : (dim X18, degree X18)

    o27 = (4, 18)

    o27 : Sequence

    i28 : betti res X18

                 0  1  2  3 4
    o28 = total: 1 11 20 11 1
              0: 1  .  .  . .
              1: .  2  1  . .
              2: .  9 18  9 .
              3: .  .  1  2 .
              4: .  .  .  . 1

    o28 : BettiTally

## See also

- [QQ] -- Quaternary Quartic Forms and Gorenstein rings (Kapustka, Kapustka, Ranestad, Schenck, Stillman, Yuan, 2021)

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/QuaternaryQuartics/Section9Doc.m2:79:0.