Macaulay2 » Documentation
Packages » QuaternaryQuartics :: Type [562] with lifting of type I, a CY of degree 15 via linkage
next | previous | forward | backward | up | index | toc

# Type [562] with lifting of type I, a CY of degree 15 via linkage -- lifting to a 3-fold with components of degree 8, 7

We construct via linkage an arithmetically Gorenstein 3-fold $X = X_{8} \cup X_{7} \subset \bf{P}^7$, of degree 15, with two components of degrees 7 and 8, having Betti table of type [562]. For an artinian reduction $A_F$, the ideal $F^\perp$ contains a pencil of ideals $I_\Gamma$, where $\Gamma=\Gamma_3\cup\Gamma_2$, the union of a three points in a line $L$ and two fixed points on a line $L'$ skew to $L$ . So we construct $X_8$ in the complete intersection of two cubics in a P5 and $X_7$ in a complete intersection $(2,4)$ in another P5. In the construction the intersection $X\cup X'$ of a component $X$ with the other is an anticanonical divisor on $X$.

The betti table is $\phantom{WWWW} \begin{matrix} &0&1&2&3&4\\ \text{total:}&1&9&16&9&1\\ \text{0:}&1&\text{.}&\text{.}&\text{.}&\text{.}\\ \text{1:}&\text{.}&5&6&2&\text{.}\\ \text{2:}&\text{.}&2&4&2&\text{.}\\ \text{3:}&\text{.}&2&6&5&\text{.}\\ \text{4:}&\text{.}&\text{.}&\text{.}&\text{.}&1\\ \end{matrix} $

$X_{7}$ is a 3-fold of degree 7 linked via a $(2,4)$ complete intersection to a $\PP^3$ in a $\PP^5$. The other component $X_8$ of $X$ is a 3-fold of degree 8 linked via a $(3,3)$ complete intersection to another $\PP^3$ in another $\PP^5$. These are constructed do that $X_7$ and $X_8$ intersect in a quartic surface $Z_4$ in the $\PP^3$ which is the intersection of the span of $X_7$ and $X_8$.

    i1 : kk=QQ;

    i2 : U=kk[y0,y1,y2,y3,y4,y5,y6,y7];

    i3 : P5c=ideal(y0,y1);  -- a P5

    o3 : Ideal of U

    i4 : P5a=ideal(y2,y3);  --P5 of S8

    o4 : Ideal of U

    i5 : P5b=ideal(y4,y5);   --P5 of S7

    o5 : Ideal of U

    i6 : P3ac=P5a+P5c;-- P3 intersection of P5a and P5c

    o6 : Ideal of U

    i7 : P3bc=P5b+P5c;

    o7 : Ideal of U

    i8 : P1=P5a+P5b+P5c; --a line L, the intersection of all three P5s

    o8 : Ideal of U

    i9 : F=matrix{{y0,random(2,U),random(2,P1)},{y1,random(2,U),random(2,P1)}};

                 2      3
    o9 : Matrix U  <-- U

    i10 : X8=P5a+minors(2,F);-- a 3-fold of degree 8 in P5a

    o10 : Ideal of U

    i11 : Z4=P5c+X8; -- a quartic surface in P3ac that contains L

    o11 : Ideal of U

    i12 : XY=P5c+ideal(random(2,intersect(P5a,P5b)),random(4,intersect(Z4,P5b)));

    o12 : Ideal of U

    i13 : X7=XY:P3bc;--a 3-fold of degree 7 in P5b

    o13 : Ideal of U

    i14 : (dim X7, degree X7)

    o14 = (4, 7)

    o14 : Sequence

    i15 : betti res X7

                 0 1 2 3 4
    o15 = total: 1 5 9 7 2
              0: 1 2 1 . .
              1: . 1 2 1 .
              2: . . . . .
              3: . 2 6 6 2

    o15 : BettiTally

    i16 : X15=intersect(X7,X8);--a 3-fold of degree 15 in P7 with betti table of type [562],  the union of X7 and X8.

    o16 : Ideal of U

    i17 : (dim X15, degree X15)

    o17 = (4, 15)

    o17 : Sequence

    i18 : betti res X15

                 0 1  2 3 4
    o18 = total: 1 9 16 9 1
              0: 1 .  . . .
              1: . 5  6 2 .
              2: . 2  4 2 .
              3: . 2  6 5 .
              4: . .  . . 1

    o18 : BettiTally

## See also

- [QQ] -- Quaternary Quartic Forms and Gorenstein rings (Kapustka, Kapustka, Ranestad, Schenck, Stillman, Yuan, 2021)

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/QuaternaryQuartics/Section9Doc.m2:521:0.