Macaulay2 » Documentation
Packages » Jets » Example 4
next | previous | forward | backward | up | index | toc

# Example 4 -- invariants of principal jets of monomial ideals

This follows Examples 7.5 and 7.7 in F. Galetto, N. Iammarino, and T. Yu, Jets and principal components of monomial ideals, and very well-covered graphs.

Consider the following squarefree monomial ideal in a standard graded polynomial ring.

    i1 : R = QQ[v..z]

    o1 = R

    o1 : PolynomialRing

    i2 : I = ideal(v*w*x,x*y,y*z)

    o2 = ideal (v*w*x, x*y, y*z)

    o2 : Ideal of R

This is the Stanley-Reisner ideal of a simplicial complex $\Delta$ whose $f$-vector we compute below.

    i3 : needsPackage "SimplicialComplexes"

    o3 = SimplicialComplexes

    o3 : Package

    i4 : Δ = simplicialComplex I

    o4 = simplicialComplex | wxz vxz vwz vwy |

    o4 : SimplicialComplex

    i5 : f = matrix{fVector(Δ)}

    o5 = | 1 5 8 4 |

                  1       4
    o5 : Matrix ZZ  <-- ZZ

Next, we construct the ideal $\mathcal{P}_1 (I)$ of principal 1-jets of $I$ (see principalComponent for details). This is also the Stanley-Reisner ideal of a simplicial complex $\Gamma_1$ and we can compute its $f$-vector.

    i6 : P1 = principalComponent(1,I)

    o6 = ideal (y0*z0, x0*y0, y0*z1, z0*y1, x0*y1, y0*x1, y1*z1, x1*y1, v0*w0*x0,
         ------------------------------------------------------------------------
         v0*w0*x1, v0*x0*w1, w0*x0*v1, v0*w1*x1, w0*v1*x1, x0*v1*w1, v1*w1*x1)

    o6 : Ideal of QQ[v0, w0, x0, y0, z0][v1, w1, x1, y1, z1]

    i7 : phi = last flattenRing ring P1;

    o7 : RingMap QQ[v1, w1, x1, y1, z1, v0, w0, x0, y0, z0] <-- QQ[v0, w0, x0, y0, z0][v1, w1, x1, y1, z1]

    i8 : Γ1 = simplicialComplex phi P1

    o8 = simplicialComplex | w1x1z1w0x0z0 v1x1z1v0x0z0 v1w1z1v0w0z0 v1w1y1v0w0y0 |

    o8 : SimplicialComplex

    i9 : F = matrix{fVector Γ1}

    o9 = | 1 10 37 64 56 24 4 |

                  1       7
    o9 : Matrix ZZ  <-- ZZ

The $f$-vector of $\Gamma_1$ can be obtained by multiplying the $f$-vector of $\Delta$ with a liftingMatrix of the appropriate size.

    i10 : L = liftingMatrix(1,4,7)

    o10 = | 1 0 0 0 0  0 0 |
          | 0 2 1 0 0  0 0 |
          | 0 0 4 4 1  0 0 |
          | 0 0 0 8 12 6 1 |

                   4       7
    o10 : Matrix ZZ  <-- ZZ

    i11 : F == f*L

    o11 = true

There is a similar relation between the Betti numbers of the Stanley-Reisner rings $\Bbbk [\Delta]$ and $\Bbbk [\Gamma_1]$. First, we compute the Betti diagram of $\Bbbk [\Delta]$ and turn it into a matrix by sliding the $i$-th row $i$ units to the right.

    i12 : betti res I

                 0 1 2
    o12 = total: 1 3 2
              0: 1 . .
              1: . 2 1
              2: . 1 1

    o12 : BettiTally

    i13 : b = mutableMatrix(ZZ,3,5);

    i14 : scanPairs(betti res I, (k,v) -> b_(k_2-k_0,k_2) = v);

    i15 : b = matrix b

    o15 = | 1 0 0 0 0 |
          | 0 0 2 1 0 |
          | 0 0 0 1 1 |

                   3       5
    o15 : Matrix ZZ  <-- ZZ

Next, we do the same with the Betti diagram of $\Bbbk [\Gamma_1]$.

    i16 : betti res P1

                 0  1  2  3  4 5 6
    o16 = total: 1 16 44 52 31 9 1
              0: 1  .  .  .  . . .
              1: .  8 16 14  6 1 .
              2: .  8 28 38 25 8 1

    o16 : BettiTally

    i17 : B = mutableMatrix(ZZ,3,9);

    i18 : scanPairs(betti res P1, (k,v) -> B_(k_2-k_0,k_2) = v);

    i19 : B = matrix B

    o19 = | 1 0 0 0  0  0  0  0 0 |
          | 0 0 8 16 14 6  1  0 0 |
          | 0 0 0 8  28 38 25 8 1 |

                   3       9
    o19 : Matrix ZZ  <-- ZZ

The matrix containing the Betti numbers of $\Bbbk [\Gamma_1]$ can be obtained by multiplying the matrix containing the Betti numbers of $\Bbbk [\Delta]$ with a liftingMatrix of the appropriate size.

    i20 : L = liftingMatrix(1,5,9)

    o20 = | 1 0 0 0 0  0  0  0 0 |
          | 0 2 1 0 0  0  0  0 0 |
          | 0 0 4 4 1  0  0  0 0 |
          | 0 0 0 8 12 6  1  0 0 |
          | 0 0 0 0 16 32 24 8 1 |

                   5       9
    o20 : Matrix ZZ  <-- ZZ

    i21 : B == b*L

    o21 = true

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/Jets.m2:1666:0.