Macaulay2 » Documentation
Packages » Resultants :: Grass
next | previous | forward | backward | up | index | toc

# Grass -- coordinate ring of a Grassmannian

- Usage:
    `Grass(k,n)`
    `Grass(k,n,K)`
- Inputs:
  - k, an integer
  - n, an integer
  - K, a ring, optional with default value QQ, the coefficient ring to be used
- Optional inputs:
  - Variable => ..., default value "p", specify a name for a variable
- Outputs:
  - a quotient ring, the coordinate ring of the Grassmannian variety of all projective $k$-planes in $\mathbb{P}^n$

## Description

This method calls the method Grassmannian, and Grass(k,n,K,Variable=>p) can be considered equivalent to quotient Grassmannian(k,n,Variable=>p,CoefficientRing=>K). However, the method Grass creates no more than an instance of ring for a given tuple (k,n,K,p).

    i1 : R = Grass(2,4,ZZ/11)

    o1 = R

    o1 : QuotientRing

    i2 : R === Grass(2,4,ZZ/11)

    o2 = true

In order to facilitate comparisons, the outputs of the methods chowForm, hurwitzForm, tangentialChowForm, chowEquations, and dualize always lie in these rings.

    i3 : L = trim ideal(random(1,Grass(0,3,ZZ/11,Variable=>x)),random(1,Grass(0,3,ZZ/11,Variable=>x)))

    o3 = ideal (x  + 2x , x  - x  + 2x )
                 1     3   0    2     3

                  ZZ
    o3 : Ideal of --[x ..x ]
                  11  0   3

    i4 : w = chowForm L

    o4 = x    + x    + 2x    - 2x    - 2x
          0,1    1,2     0,3     1,3     2,3

         ZZ
         --[x   ..x   , x   , x   , x   , x   ]
         11  0,1   0,2   1,2   0,3   1,3   2,3
    o4 : --------------------------------------
             x   x    - x   x    + x   x
              1,2 0,3    0,2 1,3    0,1 2,3

    i5 : ring w === Grass(1,3,ZZ/11,Variable=>x)

    o5 = true

    i6 : L' = chowEquations w

    o6 = ideal (x  + 2x , x  - x  + 2x )
                 1     3   0    2     3

                  ZZ
    o6 : Ideal of --[x ..x ]
                  11  0   3

    i7 : ring L' === Grass(0,3,ZZ/11,Variable=>x)

    o7 = true

    i8 : L''= chowEquations(w,Variable=>y)

    o8 = ideal (y  + 2y , y  - y  + 2y )
                 1     3   0    2     3

                  ZZ
    o8 : Ideal of --[y ..y ]
                  11  0   3

    i9 : ring L'' === Grass(0,3,ZZ/11,Variable=>y)

    o9 = true

## Ways to use Grass:

- `Grass(ZZ,ZZ)`
- `Grass(ZZ,ZZ,Ring)`

## For the programmer

The object Grass is a method function with options.

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/Resultants.m2:1187:0.