Macaulay2 » Documentation
Packages » NormalToricVarieties :: pullback(ToricMap,ToricDivisor)
next | previous | forward | backward | up | index | toc

# pullback(ToricMap,ToricDivisor) -- make the pullback of a Cartier divisor under a toric map

- Function: pullback
- Usage:
    `pullback(f, D)`
- Inputs:
  - f, a toric map,
  - D, a toric divisor, on the target of f that is Cartier
- Outputs:
  - a toric divisor, the pullback of the divisor D under the map f

## Description

Torus-invariant Cartier divisors pullback under a toric map by composing the toric map with the support function of the divisor. For more information, see Proposition 6.2.7 in Cox-Little-Schenck's Toric Varieties.

As a first example, we consider the projection from a product of two projective lines onto the first factor. The pullback of a point is just a fibre in the product.

    i1 : P = toricProjectiveSpace 1;

    i2 : X = P ** P;

    i3 : f = X^[0]

    o3 = | 1 0 |

    o3 : ToricMap P <--- X

    i4 : pullback(f, P_0)

    o4 = X
          0

    o4 : ToricDivisor on X

    i5 : pullback(f, 2*P_0 - 6*P_1)

    o5 = 2*X  - 6*X
            0      1

    o5 : ToricDivisor on X

    i6 : assert (isWellDefined f and f == map(P, X, matrix {{1,0}}))

The next example illustrates that the pullback of a line through the origin in affine plane under the blowup map is a line together with the exceptional divisor.

    i7 : A = affineSpace 2, max A

    o7 = (A, {{0, 1}})

    o7 : Sequence

    i8 : B = toricBlowup({0,1}, A);

    i9 : g = B^[]

    o9 = | 1 0 |
         | 0 1 |

    o9 : ToricMap A <--- B

    i10 : pullback(g, A_0)

    o10 = B  + B
           0    2

    o10 : ToricDivisor on B

    i11 : pullback(g, -3*A_0 + 7*A_1)

    o11 = - 3*B  + 7*B  + 4*B
               0      1      2

    o11 : ToricDivisor on B

## See also

- working with toric maps -- information about toric maps and the induced operations
- isCartier(ToricDivisor) -- whether a torus-invariant Weil divisor is Cartier
- pullback(ToricMap,CoherentSheaf) -- make the pullback of a coherent sheaf under a toric map

## Ways to use this method:

- pullback(ToricMap,ToricDivisor) -- make the pullback of a Cartier divisor under a toric map

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/NormalToricVarieties/ToricMapsDocumentation.m2:1446:0.