Macaulay2 » Documentation
Packages » Schubert2 » Examples from Schubert, translated » Example from Schubert: Conics on a quintic threefold
next | previous | forward | backward | up | index | toc

# Example from Schubert: Conics on a quintic threefold

    # Conics on a quintic threefold. This is the top Chern class of the
    # quotient of the 5th symmetric power of the universal quotient on the
    # Grassmannian of 2 planes in P^5 by the subbundle of quintic containing the
    # tautological conic over the moduli space of conics.
    >
    > grass(3,5,c):         # 2-planes in P^4.

    i1 : Gc = flagBundle({2,3}, VariableNames => {,c})

    o1 = Gc

    o1 : a flag bundle with subquotient ranks {2..3}

    i2 : (Sc,Qc) = bundles Gc

    o2 = (Sc, Qc)

    o2 : Sequence

    > B:=Symm(2,Qc):        # The bundle of conics in the 2-plane.

    i3 : B = symmetricPower(2,Qc)

    o3 = B

    o3 : an abstract sheaf of rank 6 on Gc

    > Proj(X,dual(B),z):    # X is the projective bundle of all conics.

    i4 : X = projectiveBundle'(dual B, VariableNames => {,{z}})

    o4 = X

    o4 : a flag bundle with subquotient ranks {5, 1}

    > A:=Symm(5,Qc)-Symm(3,Qc)&*o(-z):  # The rank 11 bundle of quintics
    >                                   # restricted to the universal conic.

    i5 : A = symmetricPower_5 Qc - symmetricPower_3 Qc ** OO(-z)

    o5 = A

    o5 : an abstract sheaf of rank 11 on X

    > c11:=chern(rank(A),A):# its top Chern class.

    i6 : c11 = chern(rank A, A)

                2 5
    o6 = 609250c z
                3

                                                             QQ[][H   ..H   , c ..c ]
                                                                   1,1   1,2   1   3
                             ---------------------------------------------------------------------------------------[H   ..H   , z]
                             (- H    - c , - H    - H   c  - c , - H   c  - H   c  - c , - H   c  - H   c , -H   c )  1,1   1,5
                                 1,1    1     1,2    1,1 1    2     1,2 1    1,1 2    3     1,2 2    1,1 3    1,2 3
    o6 : ----------------------------------------------------------------------------------------------------------------------------------------------
                                               2                                                           2
         (- H    - z - 4c , - H    - H   z + 5c  + 5c , - H    - H   z - 15c c  - 5c , - H    - H   z + 10c  + 20c c , - H    - H   z - 20c c , -H   z)
             1,1         1     1,2    1,1      1     2     1,3    1,2       1 2     3     1,4    1,3       2      1 3     1,5    1,4       2 3    1,5

    > lowerstar(X,c11):     # push down to G(3,5).

    i7 : X.StructureMap_* c11

                2
    o7 = 609250c
                3

                                         QQ[][H   ..H   , c ..c ]
                                               1,1   1,2   1   3
    o7 : ---------------------------------------------------------------------------------------
         (- H    - c , - H    - H   c  - c , - H   c  - H   c  - c , - H   c  - H   c , -H   c )
             1,1    1     1,2    1,1 1    2     1,2 1    1,1 2    3     1,2 2    1,1 3    1,2 3

    > integral(Gc,");       # and integrate there.
                                         609250

    i8 : integral oo

    o8 = 609250

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/Schubert2.m2:1857:0.