Macaulay2 » Documentation
Packages » BettiCharacters » BettiCharacters Example 4
next | previous | forward | backward | up | index | toc

# BettiCharacters Example 4 -- a multigraded example

Consider the polynomial ring $\mathbb{Q} [x_1,x_2,y_1,y_2,y_3]$ with the variables $x_i$ of bidegree {1,0} and the variables $y_j$ of bidegree {0,1}. We consider the action of a product of two symmetric groups, the first permuting the $x_i$ variables and the second permuting the $y_j$ variables. We compute the Betti characters of this group on the resolution of the bigraded irrelevant ideal $\langle x_1,x_2\rangle \cap \langle y_1,y_2,y_3\rangle$. This is also the edge ideal of the complete bipartite graph $K_{2,3}$.

    i1 : R = QQ[x_1,x_2,y_1,y_2,y_3,Degrees=>{2:{1,0},3:{0,1}}]

    o1 = R

    o1 : PolynomialRing

    i2 : I = intersect(ideal(x_1,x_2),ideal(y_1,y_2,y_3))

    o2 = ideal (x y , x y , x y , x y , x y , x y )
                 2 3   1 3   2 2   1 2   2 1   1 1

    o2 : Ideal of R

    i3 : RI = freeResolution I

          1      6      9      5      1
    o3 = R  <-- R  <-- R  <-- R  <-- R

         0      1      2      3      4

    o3 : Complex

    i4 : G = {
             matrix{{x_1,x_2,y_2,y_3,y_1}},
             matrix{{x_1,x_2,y_2,y_1,y_3}},
             matrix{{x_1,x_2,y_1,y_2,y_3}},
             matrix{{x_2,x_1,y_2,y_3,y_1}},
             matrix{{x_2,x_1,y_2,y_1,y_3}},
             matrix{{x_2,x_1,y_1,y_2,y_3}}
             }

    o4 = {| x_1 x_2 y_2 y_3 y_1 |, | x_1 x_2 y_2 y_1 y_3 |, | x_1 x_2 y_1 y_2 y_3
         ------------------------------------------------------------------------
         |, | x_2 x_1 y_2 y_3 y_1 |, | x_2 x_1 y_2 y_1 y_3 |, | x_2 x_1 y_1 y_2
         ------------------------------------------------------------------------
         y_3 |}

    o4 : List

    i5 : A = action(RI,G)

    o5 = Complex with 6 actors

    o5 : ActionOnComplex

    i6 : character A

    o6 = Character over R

         (0, {0, 0}) => | 1 1 1 1 1 1 |
         (1, {1, 1}) => | 0 2 6 0 0 0 |
         (2, {1, 2}) => | 0 -2 6 0 0 0 |
         (2, {2, 1}) => | 0 1 3 0 -1 -3 |
         (3, {1, 3}) => | 2 -2 2 0 0 0 |
         (3, {2, 2}) => | 0 -1 3 0 1 -3 |
         (4, {2, 3}) => | 1 -1 1 -1 1 -1 |

    o6 : Character

We can also compute the characters of some graded components of the quotient by this ideal.

    i7 : Q = R/I

    o7 = Q

    o7 : QuotientRing

    i8 : B = action(Q,G)

    o8 = QuotientRing with 6 actors

    o8 : ActionOnGradedModule

    i9 : character(B,{1,0})

    o9 = Character over R

         (0, {1, 0}) => | 2 2 2 0 0 0 |

    o9 : Character

    i10 : character(B,{0,1})

    o10 = Character over R

          (0, {0, 1}) => | 0 1 3 0 1 3 |

    o10 : Character

    i11 : character(B,{4,0})

    o11 = Character over R

          (0, {4, 0}) => | 5 5 5 1 1 1 |

    o11 : Character

    i12 : character(B,{0,5})

    o12 = Character over R

          (0, {0, 5}) => | 0 3 21 0 3 21 |

    o12 : Character

Note that all mixed degree components are zero.

    i13 : character(B,{1,1})

    o13 = Character over R

    o13 : Character

    i14 : character(B,{2,1})

    o14 = Character over R

    o14 : Character

    i15 : character(B,{1,2})

    o15 = Character over R

    o15 : Character

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/BettiCharacters.m2:2859:0.