Macaulay2 » Documentation
Packages » BettiCharacters » character » Character » dual(Character,RingMap)
next | previous | forward | backward | up | index | toc

# dual(Character,RingMap) -- dual character

- Function: dual

## Description

Returns the dual of a character, i.e., the character of the dual or contragredient representation.

The first argument is the original character. The second argument has two possibilities, listed below. The page characterTable contains some motivation for using conjugation or permutations of conjugacy classes when dealing with characters.

## dual character with respect to a conjugation in coefficient field

- Usage:
    `dual(c,conj)`
- Inputs:
  - c, an instance of the type Character, of a finite group action
  - conj, a ring map, conjugation in coefficient field
- Outputs:
  - an instance of the type Character,

Assuming the polynomial ring over which the character is defined has a coefficient field F which is a subfield of the complex numbers, then the second argument is the restriction of complex conjugation to F.

As an example, we construct a character of the alternating group $A_4$ considered as a subgroup of the symmetric group $S_4$. The conjugacy classes are represented by the identity, and the permutations $(12)(34)$, $(123)$, and $(132)$, in cycle notation. The character is constructed over the field $\mathbb{Q}[w]$, where $w$ is a primitive third root of unity. Complex conjugation restricts to $\mathbb{Q}[w]$ by sending $w$ to $w^2$. The character is concentrated in homological degree 1, and internal degree 2.

    i1 : F = toField(QQ[w]/ideal(1+w+w^2))

    o1 = F

    o1 : PolynomialRing

    i2 : R = F[x_1..x_4]

    o2 = R

    o2 : PolynomialRing

    i3 : conj = map(F,F,{w^2})

    o3 = map (F, F, {- w - 1})

    o3 : RingMap F <-- F

    i4 : X = character(R,4,hashTable {(1,{2}) => matrix{{1,1,w,w^2}}})

    o4 = Character over R

         (1, {2}) => | 1 1 w -w-1 |

    o4 : Character

    i5 : X' = dual(X,conj)

    o5 = Character over R

         (-1, {-2}) => | 1 1 -w-1 w |

    o5 : Character

## dual character with respect to a permutation of conjugacy classes

- Usage:
    `dual(c,perm)`
- Inputs:
  - c, an instance of the type Character, of a finite group action
  - perm, a list, permutation of conjugacy classes
- Outputs:
  - an instance of the type Character,

If working over coefficient fields of positive characteristic or if one wishes to avoid defining conjugation, one may replace the second argument by a list containing a permutation $\pi$ of the integers $1,\dots,r$, where $r$ is the number of conjugacy classes of the group. The permutation $\pi$ is defined as follows: if $g$ is an element of the $j$-th conjugacy class, then $g^{-1}$ is an element of the $\pi (j)$-th class.

In the case of $A_4$, the identity and $(12)(34)$ are their own inverses, while $(123)^{-1} = (132)$. Therefore the permutation $\pi$ is the transposition exchanging 3 and 4. Hence the dual of the character in the example above may also be constructed as follows, with $\pi$ represented in one-line notation by a list passed as the second argument.

    i6 : perm = {1,2,4,3}

    o6 = {1, 2, 4, 3}

    o6 : List

    i7 : dual(X,perm) === X'

    o7 = true

## See also

- characterTable -- construct a character table

## Ways to use this method:

- `dual(Character,List)`
- dual(Character,RingMap) -- dual character

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/BettiCharacters.m2:2859:0.