Macaulay2 » Documentation
Packages » LocalRings :: replacements for functions from version 1.0
next | previous | forward | backward | up | index | toc

# replacements for functions from version 1.0

This page describes the replacements for functions implemented in version 1.0 of this package by Mike Stillman and David Eisenbud. That version implemented functionality for finding minimal generators, syzygies and resolutions for polynomial rings localized at a maximal ideal.

Defining a local ring using setMaxIdeal and localRing:

    i1 : S = ZZ/32003[x,y,z,w]

    o1 = S

    o1 : PolynomialRing

    i2 : P = ideal(x,y,z,w)

    o2 = ideal (x, y, z, w)

    o2 : Ideal of S

    i3 : setMaxIdeal P -- version 1.0

    o3 = ideal (x, y, z, w)

    o3 : Ideal of S

    i4 : R = localRing(S, P) -- version 2.0 and above

    o4 = R

    o4 : LocalRing, maximal ideal (x, y, z, w)

Computing syzygies using localsyz and syz:

    i5 : use S

    o5 = S

    o5 : PolynomialRing

    i6 : m = matrix{{x,y*z},{z*w,x}}

    o6 = | x  yz |
         | zw x  |

                 2      2
    o6 : Matrix S  <-- S

    i7 : m * localsyz m

    o7 = 0

                 2
    o7 : Matrix S  <-- 0

    i8 : use R

    o8 = R

    o8 : LocalRing, maximal ideal (x, y, z, w)

    i9 : m = matrix{{x,y*z},{z*w,x}}

    o9 = | x  yz |
         | zw x  |

                 2      2
    o9 : Matrix R  <-- R

    i10 : m * syz m

    o10 = 0

                  2
    o10 : Matrix R  <-- 0

Computing syzygies using localMingens and mingens:

    i11 : use S

    o11 = S

    o11 : PolynomialRing

    i12 : localMingens matrix{{x-1,x,y},{x-1,x,y}}

    o12 = | x-1 |
          | x-1 |

                  2      1
    o12 : Matrix S  <-- S

    i13 : use R

    o13 = R

    o13 : LocalRing, maximal ideal (x, y, z, w)

    i14 : mingens image matrix{{x-1,x,y},{x-1,x,y}}

    o14 = | x-1 |
          | x-1 |

                  2      1
    o14 : Matrix R  <-- R

Computing syzygies using localModulo and modulo:

    i15 : use S

    o15 = S

    o15 : PolynomialRing

    i16 : localModulo(matrix {{x-1,y}}, matrix {{y,z}})

    o16 = {1} | z y    0  |
          {1} | 0 -x+1 -1 |

                  2      3
    o16 : Matrix S  <-- S

    i17 : use R

    o17 = R

    o17 : LocalRing, maximal ideal (x, y, z, w)

    i18 : modulo(matrix {{x-1,y}}, matrix {{y,z}})

    o18 = {1} | 0  y    z |
          {1} | -1 -x+1 0 |

                  2      3
    o18 : Matrix R  <-- R

Computing syzygies using localPrune and prune:

    i19 : use S

    o19 = S

    o19 : PolynomialRing

    i20 : localPrune image matrix{{x-1,x,y},{x-1,x,y}}

           1
    o20 = S

    o20 : S-module, free, degrees {1}

    i21 : use R

    o21 = R

    o21 : LocalRing, maximal ideal (x, y, z, w)

    i22 : prune image matrix{{x-1,x,y},{x-1,x,y}}

           1
    o22 = R

    o22 : R-module, free, degrees {1}

Computing syzygies using localResolution and freeResolution:

    i23 : use S

    o23 = S

    o23 : PolynomialRing

    i24 : localResolution coker matrix{{x,y*z},{z*w,x}}

           2      2
    o24 = S  <-- S  <-- 0

          0      1      2

    o24 : ChainComplex

    i25 : oo.dd

               2                 2
    o25 = 0 : S  <------------- S  : 1
                    | yz x  |
                    | x  zw |

               2
          1 : S  <----- 0 : 2
                    0

    o25 : ChainComplexMap

    i26 : use R

    o26 = R

    o26 : LocalRing, maximal ideal (x, y, z, w)

    i27 : freeResolution coker matrix{{x,y*z},{z*w,x}}

           2      2
    o27 = R  <-- R

          0      1

    o27 : Complex

    i28 : oo.dd

               2                 2
    o28 = 0 : R  <------------- R  : 1
                    | yz x  |
                    | x  zw |

    o28 : ComplexMap

### Menu

- setMaxIdeal -- set the maximal ideal for local ring methods
- localComplement -- find the splitting of the target of a map
- localsyz -- find syzygies
- localMingens -- finds a minimal set of generators
- localModulo -- find the pre-image (pullback) of image of a map over a local ring
- localPrune -- find a minimal presentation
- localResolution -- find a resolution over a local ring

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/LocalRings/doc.m2:133:0.