Macaulay2 » Documentation
Packages » OldToricVectorBundles :: toricVectorBundle(ZZ,Fan,List,List)
next | previous | forward | backward | up | index | toc

# toricVectorBundle(ZZ,Fan,List,List) -- a toric vector bundle of rank 'k' with given filtrations or degrees

- Function: toricVectorBundle
- Usage:
    `E = toricVectorBundle(k,F,L1,L2)`
- Inputs:
  - k, an integer, strictly positive
  - F, an instance of the type Fan, an object of class Fan
  - L1, a list
  - L2, a list
- Optional inputs:
  - Type
- Outputs:
  - E, an instance of the type ToricVectorBundle

## Description

For a given pure, full dimensional and pointed fan F the function toricVectorBundle generates the toric vector bundle of rank k given by the data in the two lists L1 and L2.

If no further options are given then the resulting bundle will be in Klyachko's description: The first list L1 will give the basis matrices and the second list L2 will give the filtration matrices. Then the resulting vector bundle will have these basis and filtration matrices. The number of matrices in L1 must match the number of rays of the fan and they must be in GL(k,$R$) for $R$ being ZZ or QQ. They will be assigned to the rays in the order they appear in rays F. The number of matrices in L2 must also match the number of rays, and they must be $1$ times k matrices over ZZ. The assignment order is the same as for the basis matrices.

Note that the basis and filtration matrices that are given to the function need not satisfy the compatibility condition. This can by checked by using regCheck.

    i1 : L1 = {matrix {{1,0},{0,1}},matrix{{0,1},{1,0}},matrix{{-1,0},{-1,1}}}

    o1 = {| 1 0 |, | 0 1 |, | -1 0 |}
          | 0 1 |  | 1 0 |  | -1 1 |

    o1 : List

    i2 : L2 = {matrix {{-1,0}},matrix{{-2,-1}},matrix{{0,1}}}

    o2 = {| -1 0 |, | -2 -1 |, | 0 1 |}

    o2 : List

    i3 : E = toricVectorBundle(2,projectiveSpaceFan 2,L1,L2)

    o3 = {dimension of the variety => 2 }
          number of affine charts => 3
          number of rays => 3
          rank of the vector bundle => 2

    o3 : ToricVectorBundleKlyachko

    i4 : details E

    o4 = HashTable{| -1 | => (| 1 0 |, | -1 0 |)}
                   | -1 |     | 0 1 |
                   | 0 | => (| 0 1 |, | -2 -1 |)
                   | 1 |     | 1 0 |
                   | 1 | => (| -1 0 |, | 0 1 |)
                   | 0 |     | -1 1 |

    o4 : HashTable

If the option "Type" => "Kaneyama" is given then the resulting bundle will be in Kaneyama's description; Note that this is only implemented for complete, pointed fans: The first list L1 will give the degree matrices and the second list L2 will give the transition matrices. The number of matrices in L1 must match the number of maximal cones of the fan and they must be $n$ times k matrices over ZZ. They will be assigned to the cones in the order they appear in maxCones F. The number of matrices in L2 must match the number of pairs of maximal cones that intersect in a common codimension-one face and must all be in GL(k,QQ). They will be assigned to the pairs $(i,j)$ in lexicographic order.

Note that the degrees and transition matrices that are given to the function need not satisfy the regularity or the cocycle condition. These can be checked by using regCheck and cocycleCheck.

    i5 : L1 = {matrix {{1,0},{0,1}},matrix{{0,1},{1,0}},matrix{{-1,0},{-1,1}}}

    o5 = {| 1 0 |, | 0 1 |, | -1 0 |}
          | 0 1 |  | 1 0 |  | -1 1 |

    o5 : List

    i6 : L2 = {matrix {{-1,0},{0,-1}},matrix{{0,1},{1,0}},matrix{{0,-1},{-1,0}}}

    o6 = {| -1 0  |, | 0 1 |, | 0  -1 |}
          | 0  -1 |  | 1 0 |  | -1 0  |

    o6 : List

    i7 : E = toricVectorBundle(2,projectiveSpaceFan 2,L1,L2,"Type" => "Kaneyama")

    o7 = {dimension of the variety => 2 }
          number of affine charts => 3
          rank of the vector bundle => 2

    o7 : ToricVectorBundleKaneyama

    i8 : details E

    o8 = (HashTable{0 => (| -1 0 |, | 1 0 |) }, HashTable{(0, 1) => | -1 0  |})
                          | -1 1 |  | 0 1 |                         | 0  -1 |
                    1 => (| 1 0 |, | 0 1 |)               (0, 2) => | 0 1 |
                          | 0 1 |  | 1 0 |                          | 1 0 |
                    2 => (| 1 -1 |, | -1 0 |)             (1, 2) => | 0  -1 |
                          | 0 -1 |  | -1 1 |                        | -1 0  |

    o8 : Sequence

## See also

- addBaseChange -- changing the transition matrices of a toric vector bundle
- addDegrees -- changing the degrees of a toric vector bundle
- addBase -- changing the basis matrices of a toric vector bundle in Klyachko's description
- addFiltration -- changing the filtration matrices of a toric vector bundle in Klyachko's description
- details -- the details of a toric vector bundle
- regCheck -- checking the regularity condition for a toric vector bundle
- cocycleCheck -- checks if a toric vector bundle fulfills the cocycle condition
- isVectorBundle -- checks if the data does in fact define an equivariant toric vector bundle

## Ways to use this method:

- toricVectorBundle(ZZ,Fan,List,List) -- a toric vector bundle of rank 'k' with given filtrations or degrees

The source of this document is in /build/macaulay2-88fgJW/macaulay2-1.25.11+ds/M2/Macaulay2/packages/OldToricVectorBundles.m2:3768:0.