Mail::Box::Manager(3pm)

NAME
Mail::Box::Manager - manage a set of folders

INHERITANCE
 Mail::Box::Manager
   is a Mail::Reporter

 Mail::Box::Manager is extended by
   Mail::Box::Manage::User

SYNOPSIS
  use Mail::Box::Manager;
  my $mgr     = new Mail::Box::Manager;

  # Create folder objects.
  my $folder   = $mgr->open(folder => $ENV{MAIL});
  my $message1 = $folder->message(0);
  $mgr->copyMessage('Draft', $message);

  my @messages = $folder->message(0,3);
  $mgr->moveMessage('Outbox', @messages, create => 1 );
  $mgr->close($folder);

  # Create thread-detectors (see Mail::Box::Thread::Manager)
  my $t       = $mgr->discoverThreads($inbox, $outbox);

  my $threads = $mgr->discoverThreads(folder => $folder);
  foreach my $thread ($threads->all)
  {   $thread->print;
  }

  $mgr->registerType(mbox => 'Mail::Box::MyType');

DESCRIPTION
The manager keeps track on a set of open folders and a set of message-thread supporting objects. You are not obliged to use this object (you can directly create a Mail::Box::Mbox if you prefer), but you will create more portable and safer code if you do use it.

Extends "DESCRIPTION" in Mail::Reporter.

METHODS
Extends "METHODS" in Mail::Reporter.

  Constructors
Extends "Constructors" in Mail::Reporter.

$class->new(%options)
    Inherited, see "Constructors" in Mail::Reporter

     -Option             --Default
      autodetect           undef
      default_folder_type  'mbox'
      folder_types         <all standard types>
      folderdir            [ '.' ]
      folderdirs           <synonym for C<folderdir>>

    autodetect => $type|\@types
        Select only a subset of the folder @types which are implemented by MailBox to be detected automatically. This may improve the auto-detection of folder types. Normally, all folder types will be tried when a folder's name is incorrect, but this option limits the types which are checked and therefore may respond faster.

    default_folder_type => $type|CLASS
        Specifies the default folder $type for newly created folders. If this option is not specified, the most recently registered type is used (see registerType() and the new(folder_types) option.

    folder_types => $typedef|\@typedefs
        Add one or more new folder @typedefs to the list of known types. The order is important: when you open a file without specifying its type, the manager will start trying the last added list of types, in order.

        Each $typedef is specified as an array which contains name, class, and defaults for options which overrule the usual defaults. You may specify folder-specific defaults as OPTIONS. They override the settings of the manager.

    folderdir => DIRECTORY
        The default directory, or directories, where folders are located. The "Mail::Box::Manager" can autodetect the existing folder-types. There may be different kinds of folders opened at the same time, and messages can be moved between those types, although that may result in a loss of information depending on the folder types.

    folderdirs => [DIRECTORIES]

  Attributes
Extends "Attributes" in Mail::Reporter.

$obj->defaultFolderType()
    Returns the default folder type, some class name.

$obj->folderTypeDefs()

$obj->folderTypes()
    Returns the list of currently defined folder types.

    » example:

      print join("\n", $manager->folderTypes), "\n";

$obj->folderdir()
    In list context, this returns all folderdirs specified. In SCALAR context only the first.

$obj->registerType($type, $class, %options)
    With "registerType" you can register one $type of folders. The $class is compiled automatically, so you do not need to "use" them in your own modules. The $type is just an arbitrary name.

    The added types are prepended to the list of known types, so they are checked first when a folder is opened in autodetect mode.

    » example:

      $manager->registerType(mbox => 'Mail::Box::Mbox',
          save_on_exit => 0, folderdir => '/tmp');

$obj->threads( [@params] )
    [3.012] return the descovered threads (cached value). When any @params are passed, then discoverThreads() will be called for backwards compatibility.

  Manage open folders

$obj->close($folder, %options)
    Remove the specified $folder from the index of open folders. Indirectly it will update the files on disk if needed (depends on the Mail::Box::new(save_on_exit) flag for each folder). %options are passed to Mail::Box::close() of the folder.

    The folder's messages will also be withdrawn from the known message threads. You may also close the folder directly. The manager will be informed about this event and take appropriate actions.

     -Option       --Default
      close_by_self  <C<false>>

    close_by_self => BOOLEAN
        Used internally to avoid confusion about how the close was started. Do not change this.

    » example:

      my $inbox = $mgr->open('inbox');
      $mgr->close($inbox);
      $inbox->close;        # alternative

$obj->closeAllFolders(%options)
    "closeAllFolders" calls close() for each folder managed by this object. It is called just before the program stops (before global cleanup).

$obj->isOpenFolder($folder)
    Returns "true" if the $folder is currently open.

    » example:

      print "Yes\n" if $mgr->isOpenFolder('Inbox');

$obj->open( [$foldername], %options )
    Open a folder which name is specified as first parameter or with the option flag "folder". The folder type is autodetected unless the "type" is specified.

    "open" carries options for the manager which are described here, but may also have additional options for the folder type. For a description of the folder options, see the options to the constructor Mail::Box::new() for each type of mail box.

     -Option      --Default
      authenticate  'AUTO'
      create        false
      folder        $ENV{MAIL}
      folderdir     '.'
      type          <first, usually 'mbox'>

    authenticate => $type|\@types|'AUTO'
        The $type of authentication to be used, or an ARRAY of @types which the client prefers. The server may provide preferences as well, and that order will be kept. This option is only supported by a small subset of folder types, especially by POP and IMAP.

    create => BOOLEAN
        Create the folder if it does not exist. By default, this is not done. The "type" option specifies which type of folder is created.

    folder => $name|$url
        Which folder to open, specified by $name or special $url. The URL format is composed as

          type://username:password@hostname:port/foldername

        Like real URLs, all fields are optional and have smart defaults, as long as the string starts with a known folder type. Far from all folder types support all these options, but at least they are always split-out. Be warned that special characters in the password should be properly url-encoded.

        When you specify anything which does not match the URL format, it is passed directly to the "new" method of the folder which is opened.

    folderdir => DIRECTORY
        The directory where the folders are usually stored.

    type => $foldertypename|$foldertype
        Specify the type of the folder. If you do not specify this option while opening a folder for reading, the manager checks all registered folder types in order for the ability to open the folder. If you open a new folder for writing, then the default will be the most recently registered type. (If you add more than one type at once, the first of the list is used.)

        Currently, the types are "mbox", "mh", "maildir", "pop3", "pop3s", "imap4", and "imap4s". You may also use names "pop", "pops", "imap", and "imaps".

    » example: opening folders via the manager

      my $jack  = $manager->open(folder => '=jack', type => 'mbox');

      my $rcvd  = $manager->open('myMail',
         type => 'Mail::Box::Mbox', access => 'rw');

      my $inbox = $manager->open('Inbox')
         or die "Cannot open Inbox.\n";

      my $pop   = 'pop3://myself:secret@pop3.server.com:120/x';
      my $send  = $manager->open($url);

      my $send  = $manager->open(folder => '/x',
        type => 'pop3', username => 'myself', password => 'secret'
        server_name => 'pop3.server.com', server_port => '120');

$obj->openFolders()
    Returns a list of all open folders.

  Manage existing folders

$obj->delete($foldername, %options)
    Remove the named folder. The %options are the same as those for open().

    The deletion of a folder can take some time. Dependent on the type of folder, the folder must be read first. For some folder-types this will be fast.

     -Option   --Default
      recursive  <folder's default>

    recursive => BOOLEAN
        Some folder can only be recursively deleted, other have more flexibility.

  Move messages to folders

$obj->appendMessage( [$folder|$foldername], $messages, %options )
    Append one or more messages to a folder (therefore, an appendMessages() is defined as well). You may specify a $foldername or an opened folder as the first argument. When the name is that of an open folder, it is treated as if the folder-object was specified, and not directly access the folder-files. You may also specify the foldername as part of the options list.

    If a message is added to an already opened folder, it is only added to the structure internally in the program. The data will not be written to disk until a write of that folder takes place. When the name of an unopened folder is given, the folder is opened, the messages stored on disk, and then the folder is closed.

    A message must be an instance of a Mail::Message. The actual message type does not have to match the folder type--the folder will try to resolve the differences with minimal loss of information. The coerced messages (how the were actually written) are returned as list.

    The %options is a list of key/values, which are added to (overriding) the default options for the detected folder type.

    » example:

      $mgr->appendMessage('=send', $message, folderdir => '/');
      $mgr->appendMessage($received, $inbox->messages);

      my @appended = $mgr->appendMessages($inbox->messages, folder => 'Drafts');
      $_->label(seen => 1) for @appended;

$obj->copyMessage( [$folder|$foldername], @messages, %options )
    Copy @messages from one folder into another folder. If the destination folder is already opened, Mail::Box::copyTo() is used. Otherwise, Mail::Box::appendMessages() is called.

    You need to specify a folder's name or folder object as the first argument, or in the options list. The options are the same as those which can be specified when opening a folder.

     -Option--Default
      share   false

    share => BOOLEAN
        Try to share the physical storage of the messages. The folder types may be different, but it all depends on the actual folder where the message is copied to. Silently ignored when not possible to share.

    » example:

      my $drafts = $mgr->open(folder => 'Drafts');
      my $outbox = $mgr->open(folder => 'Outbox');
      $mgr->copyMessage($outbox, $drafts->message(0));

      my @messages = $drafts->message(1,2);
      $mgr->copyMessage('=Trash', @messages,
         folderdir => '/tmp', create => 1);

      $mgr->copyMessage($drafts->message(1), create => 1,
         folder => '=Drafts' folderdir => '/tmp');

$obj->moveMessage( [$folder|$foldername], @messages, %options )
    Move @messages from one $folder to another.

    BE WARNED that removals from a folder only take place when the folder is closed, so the message is only flagged to be deleted in the opened source folder.

    BE WARNED that message labels may get lost when a message is moved from one folder type to an other. An attempt is made to translate labels, but there are many differences in interpretation by applications.

      $mgr->moveMessage($received, $inbox->message(1))

    is equivalent to

      $mgr->copyMessage($received, $inbox->message(1), share => 1);
      $inbox->message(1)->delete;

     -Option--Default
      share   true

    share => BOOLEAN

  Manage message threads
$obj->discoverThreads( [@folders], %options )
    [3.012] Create a new Mail::Box::Thread::Manager object which collects the message threads found in the combined specified @folders.

    All other %options are passed to Mail::Box::Thread::Manager::new().

     -Option       --Default
      folders        <positional folder arguments>
      threader_type  Mail::Box::Thread::Manager

    folders => \@folders
        As alternative for positional parameters to select the @folders, you can also pass them via this named parameter.

    threader_type => CLASS

    » example:

      my $t2 = $mgr->discoverThreads($inbox);
      my $t3 = $mgr->discoverThreads($inbox, $send);
      my $t1 = $mgr->discoverThreads(folders => [ $inbox, $send ]);

  Internals

$obj->decodeFolderURL($url)
    Try to decompose a folder name which is specified as $url (see open()) into separate options. Special characters like @-sign, colon, and slash used in the user or password parts must be passed $url-encoded.

$obj->toBeThreaded($folder, $messages)
    Signal to the manager that all thread managers which are using the specified folder must be informed that new messages are coming in.

$obj->toBeUnthreaded($folder, $messages)
    Signal to the manager that all thread managers which are using the specified folder must be informed that new messages are or going out.

  Error handling
Extends "Error handling" in Mail::Reporter.

$obj->AUTOLOAD()
    Inherited, see "Error handling" in Mail::Reporter

$obj->notImplemented()
    Inherited, see "Error handling" in Mail::Reporter

  Cleanup
Extends "Cleanup" in Mail::Reporter.

$obj->DESTROY()
    Inherited, see "Cleanup" in Mail::Reporter

DETAILS
On many places in the documentation you can read that it is useful to have a manager object. There are two of them: the Mail::Box::Manager, which maintains a set of open folders, and an extension of it: the Mail::Box::Manage::User.

  Managing open folders
It is useful to start your program by creating a folder manager object, an Mail::Box::Manager. The object takes a few burdons from your neck:

•   autodetect the type of folder which is used.

    This means that your application can be fully folder type independent.

•   autoload the required modules

    There are so many modules involved in MailBox, that it is useful to have some lazy autoloading of code. The manager knows which modules belong to which type of folder.

•   avoid double openings

    Your programming mistakes may cause the same folder to be opened twice. The result of that could be very destructive. Therefore, the manager keeps track on all open folders and avoids the same folder to be opened for the second time.

•   close folders at clean-up

    When the program is ending, the manager will cleanly close all folders which are still open. This is required, because the autodestruct sequence of Perl works in an unpredicatable order.

•   message thread detection

    MailBox can discover message threads which span multiple folders. Any set of open folders may be grouped in a tree of replies on replies on replies. When a folder is closed, it will automatically be removed from the threads, and a new folder can dynamically be added to the structure.

The manager is really simplifying things, and should therefore be the base of all programs. However, it is possible to write useful programs without it.

  Managing a user
One step further is the Mail::Box::Manage::User object (since MailBox v2.057), which not only keeps track on open folders, but also collects information about not-open folders.

The user class is, as the name says, targeted on managing one single user. Where the Mail::Box::Manager will open any set of folder files, probably from multiple users, the user class want one root folder directory.

In many aspects, the user manager simplifies the task for user-based servers and other user-centric applications by setting smart defaults.

DIAGNOSTICS

Error: Folder $name is not a Mail::Box; cannot add a message.
    The folder where the message should be appended to is an object which is not a folder type which extends Mail::Box. Probably, it is not a folder at all. Cast by appendMessage()

Error: Use appendMessage() to add messages which are not in a folder.
    You do not need to copy this message into the folder, because you do not share the message between folders. Cast by copyMessage()

Warning: Use moveMessage() or copyMessage() to move between open folders.
    The message is already part of a folder, and now it should be appended to a different folder. You need to decide between copy or move, which both will clone the message (not the body, because they are immutable). Cast by appendMessage()

Error: class $package does not implement method $method.
    Fatal error: the specific $package (or one of its superclasses) does not implement this method where it should. This message means that some other related classes do implement this method however the class at hand does not. Probably you should investigate this and probably inform the author of the package. Cast by notImplemented()

Error: failed for folder default $class: $@
    Cast by open()

Error: folder $name does not exist, failed opening $type.
    The folder does not exist and creating is not permitted (see open(create)) or did not succeed. When you do not have sufficient access rights to the folder (for instance wrong password for POP3), this warning will be produced as well.

    The manager tried to open a folder of the specified type. It may help to explicitly state the type of your folder with the "type" option. There will probably be another warning or error message which is related to this report and provides more details about its cause. You may also have a look at new(autodetect) and new(folder_types). Cast by open()

Error: folder $name is already open.
    You cannot ask the manager for a folder which is already open. In some older releases (before MailBox 2.049), this was permitted, but then behaviour changed, because many nasty side-effects are to be expected. For instance, an Mail::Box::update() on one folder handle would influence the second, probably unexpectedly. Cast by open()

Warning: folder type $type is unknown, using autodetect.
    The specified folder type (see open(type), possibly derived from the folder name when specified as url) is not known to the manager. This may mean that you forgot to require the Mail::Box extension which implements this folder type, but probably it is a typo. Usually, the manager is able to figure-out which type to use by itself. Cast by open()

Error: illegal folder URL '$url'.
    The folder name was specified as URL, but not according to the syntax. See decodeFolderURL() for an description of the syntax. Cast by open()

Error: no foldername specified to open.
    open() needs a folder name as first argument (before the list of options), or with the "folder" option within the list. If no name was found, the MAIL environment variable is checked. When even that does not result in a usable folder, then this error is produced. The error may be caused by an accidental odd-length option list. Cast by open()

Error: threader $class is not derived from $base.
    Cast by discoverThreads()

Error: unusable threader $class: $@
    Cast by discoverThreads()

Warning: will never create a folder $name without having write access.
    You have set open(create), but only want to read the folder. Create is only useful for folders which have write or append access modes (see Mail::Box::new(access)). Cast by open()

Error: you need to pass a $base derived threader, got $class.
    Cast by discoverThreads()

SEE ALSO
This module is part of Mail-Box version 4.01, built on December 13, 2025. Website: http://perl.overmeer.net/CPAN/

LICENSE
For contributors see file ChangeLog.

This software is copyright (c) 2001-2025 by Mark Overmeer.

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.