Log::Report::Message(3pm)

NAME
Log::Report::Message - a piece of text to be translated

INHERITANCE
 Log::Report::Message is extended by
   Dancer2::Plugin::LogReport::Message

SYNOPSIS
  # Objects created by Log::Report's __ functions
  # Full feature description in the DETAILS section

  # no interpolation
  __"Hello, World";

  # with interpolation
  __x"age {years}", years => 12;

  # interpolation for one or many
  my $nr_files = @files;
  __nx"one file", "{_count} files", $nr_files;
  __nx"one file", "{_count} files", \@files;

  # interpolation of arrays
  __x"price-list: {prices%.2f}", prices => \@prices, _join => ', ';

  # white-spacing on msgid preserved
  print __"\tCongratulations,\n";
  print "\t", __("Congratulations,"), "\n";  # same

  # Object serialization support
  my $clone = Log::Report::Message->thaw($msg->freeze);

DESCRIPTION
Any use of a constructor function exported by Log::Report, like "__()" (the function is named underscore-underscore) or "__x()" (underscore-underscore-x) will result in this Message object. It will capture some environmental information as well.

The optional translation is delayed until it is really needed. Creating an object first and translating it later, might be slower than translating it immediately. However (by design decissions of Log::Report) on the location where the message is produced, we do not yet know in what language to translate it to: that depends on the actual log dispatcher configurations in the main program.

OVERLOADED

overload: '""' stringification
    When the object is used in string context, it will get translated. Implemented as toString().

overload: '&{}' used as function
    When the object is called as function, a new object is created with the data from the original one but updated with the new parameters. Implemented in clone().

overload: '.' concatenation
    An (accidental) use of concatenation (a dot where a comma should be used) would immediately stringify the object. This is avoided by overloading that operation.

METHODS

  Constructors

$obj->clone(%options, $variables)
    Returns a new object which copies info from original, and updates it with the specified %options and $variables. The advantage is that the cached translations are shared between the objects.

    » example: use of clone()

      my $s = __x "found {nr} files", nr => 5;
      my $t = $s->clone(nr => 3);
      my $t = $s->(nr => 3);      # equivalent
      print $s;     # found 5 files
      print $t;     # found 3 files

$class->new(%options)
    End-users: do not use this method directly, but use Log::Report::__(), Log::Report::__x() and friends. The %options is a mixed list of object initiation parameters (all with a leading underscore) and variables to be filled in into the translated "_msgid" string.

     -Option   --Default
      _append    undef
      _category  undef
      _class     undef
      _classes   undef
      _context   undef
      _count     undef
      _domain    <from "use Log::Report">
      _expand    false
      _join      $" $LIST_SEPARATOR
      _lang      <from locale>
      _msgctxt   undef
      _msgid     undef
      _plural    undef
      _prepend   undef
      _tag       []
      _tags      []
      _to        undef

    _append => $text|$message
        Some $text or other $message object which need to be pasted after this message object.

    _category => INTEGER
        The category when the real gettext library is used, for instance LC_MESSAGES.

    _class => $tags|\@tags
        Deprecated alternative for "_tag".

    _classes => $tags|\@tags
        Deprecated alternative for "_tag".

    _context => $keyword|\@keywords
        [1.00] Set the @keywords which can be used to select alternatives between translations. Read the DETAILS section in Log::Report::Translator::Context

    _count => INTEGER|ARRAY|HASH
        When defined, the "_plural" need to be defined as well. When an ARRAY is provided, the length of the ARRAY is taken. When a HASH is given, the number of keys in the HASH is used.

    _domain => $name|$object
        The text-domain (translation table) to which this "_msgid" belongs.

        With this parameter, your can "borrow" translations from other textdomains. Be very careful with this (although there are good use-cases) The xgettext msgid extractor may add the used msgid to this namespace as well. To avoid that, add a harmless '+':

          print __x(+"errors", _domain => 'global');

        The extractor will not take the msgid when it is an expression. The '+' has no effect on the string at runtime.

    _expand => BOOLEAN
        Indicates whether variables are to be filled-in; whether "__x" or "__" was used to define the message.

    _join => $separator
        Which $separator string to be used then an ARRAY is being filled-in.

    _lang => ISO
        [1.00] Override language setting from locale, for instance because that is not configured correctly (yet). This does not extend to prepended or appended translated message object.

    _msgctxt => $context
        [1.22] Message $context in the translation file, the traditional use. Cannot be combined with "_context" on the same msgids.

    _msgid => $msgid
        The message label, which refers to some translation information. Usually a string which is close the English version of the message. This will also be used if there is no translation possible/known.

        Leading white-space "\s" will be added to "_prepend". Trailing white-space will be added before "_append".

    _plural => $msgid
        Can be used together with "_count". This plural form of the "_msgid" text is used to simplify the work of translators, and as fallback when no translation is possible: therefore, this can best resemble an English message.

        White-space at the beginning and end of the string are stripped off. The white-space provided by the "_msgid" will be used.

    _prepend => $text|$message
        Some $text or other $message object which need to be glued before this message object.

    _tag => $tags|\@tags
        When messages are used for exception based programming, you add a "_tag" parameter to the argument list. Later, with for instance Log::Report::Dispatcher::Try::wasFatal(tag), you can check the category (group, class) of the exception.

        The $tags is interpreted as comma- and/or blank separated list of class tokens (barewords), the ARRAY lists all tags separately. See tags().

    _tags => $tags|\@tags
        Alternative name for "_tag"

    _to => $dispatcher
        Specify the $dispatcher as destination explicitly. Short for "report {to => NAME}, ..." See to()

  Attributes

$obj->addTags(@tags)
    [1.45] Add zero or more tags to this message.

$obj->append()
    Returns the string or Log::Report::Message object which is appended after this one. Usually "undef".

$obj->classes()
    Deprecated alternative for tags().

$obj->context()
    Returns an HASH if there is a context defined for this message.

$obj->count()
    Returns the count, which is used to select the translation alternatives.

$obj->domain()
    Returns the domain of the first translatable string in the structure.

$obj->errno( [$errno] )
    [1.38] Returns the value of the "_errno" key, to indicate the error number (to be returned from your script). Usually, this method will return "undef". For FAILURE, FAULT, and ALERT, the errno is by default taken from $! and $?.

$obj->msgctxt()
    The message context for the translation table lookup.

$obj->msgid()
    Returns the msgid which will later be translated.

$obj->prepend()
    Returns the string which is prepended to this one. Usually "undef".

$obj->tags()
    [1.44] Returns the LIST of tags which are defined for this message; message group indicators, as often found in exception-based programming.

$obj->to( [$name] )
    Returns the $name of a dispatcher if explicitly specified with the '_to' key. Can also be used to set it. Usually, this will return "undef", because usually all dispatchers get all messages.

$obj->valueOf($parameter)
    Lookup the named $parameter for the message. All pre-defined names have their own method which should be used with preference.

    » example:

    When the message was produced with

      my @files = qw/one two three/;
      my $msg = __xn
         "found one file: {file}",
         "found {nrfiles} files: {files}",
         scalar @files,
         file    => $files[0],
         files   => \@files,
         nrfiles => @files+0,  # or scalar(@files)
         _tags   => [ 'IO', 'files' ],
         _join   => ', ';

    then the values can be takes from the produced message as

      my $files = $msg->valueOf('files');  # returns ARRAY reference
      print @$files;                 # 3
      my $count = $msg->count;       # 3
      my @tags  = $msg->tags;        # 'IO', 'files'
      if($msg->taggedWith('files'))  # true

    Simplified, the above example can also be written as:

      local $" = ', ';  # Perl default
      my $msg  = __xn
         "found one file: {files}",
         "found {_count} files: {files}",
         @files,      # has scalar context
         files   => \@files,
         _tags   => 'IO, files';

  Processing

$obj->concat( $text|$message, [$prepend] )
    This method implements the overloading of concatenation, which is used to delay translations even longer. When $prepend is "true", the $text or $message (another "Log::Report::Message") will be prepended, otherwise it is appended in the final display.

    » example: of concatenation

      print __"Hello" . ' ' . __"World!\n";
      print __("Hello")->concat(' ')->concat(__"World!")->concat("\n");

$obj->freeze(%options)
    Convert the data of this message into a (nested) HASH which optimally preserves its content. Pass this to thaw() to get the object back.

    The returned HASH can be serialized safely with (for instance) YAML or JSON. Then, it can be reconstructed from the de-serialized data. At the moment, all facts can be preserved.

    » example: to thaw a frozen

      my $clone = Log::Report::Message->thaw($msg->freeze);

$obj->inClass($tag|Regexp)
    Deprecated alternative for taggedWith().

$obj->taggedWith($tag|Regexp)
    [1.44] Returns "true" if the message carries the specified $tag (string) or matches the Regexp. The trueth value is the (first matching) tag.

$class->thaw(\%data, %options)

$obj->toHTML( [$locale] )
    [1.11] Translate the message, and then entity encode HTML volatile characters.

    [1.20] When used in combination with a templating system, you may want to use "<content_for =" 'HTML'>> in Log::Report::Domain::configure(formatter).

    » example:

      print $msg->toHTML('NL');

$obj->toString( [$locale] )
    Translate a message. If not specified, the default locale is used.

$obj->untranslated()
    Return the concatenation of the prepend, msgid, and append strings. Variable expansions within the msgid is not performed.

DETAILS
The message cast by the Log::Report exception framework can be plain strings. This is sufficient for some cases, for instance: which would you bother much about the content of "trace" messages? Message which are destined for end-users or log-files however, need more care; require a higher quality. In this case, you can better use cast message objects which support interpolation.

  Message-IDs
An exception message as a string is pretty inflexible. It cannot be translated anymore, and it cannot contain related information like an error code. An exception message as an object (as this module implements) is able to contain additional information.

The easiest way to create Log::Report::Message objects, is via the "__x()" (and friends) functions which are exported by Log::Report. These are nearly equivalent:

  my $msg = Log::Report::Message->new(_msgid => "Hello, World!");
  my $msg = __"Hello, World!";

The name "msgid" is used, because this object can do translations. In the GNU gettext library for translations, the term "msgid" is used to describe the string which has to be looked-up in translation tables. When there are no tables, or the "msgid" is not found, then the output string is equivalent to the "msgid".

So, without any translation configuration, this happens:

  my $msg = __"Hello, World!";
  print "$msg\n";      # Hello, World!⏎

The "__()" function can be used with a static string, although you could do this:

  my $msg = __"Hello $name!";      #XXX Don't do this!
  print "$msg\n";      # Hello Mark!⏎

With the "__x()" or "__nx()", interpolation will take place on the (optionally) translated "msgid" string. This is how to write above:

  my $msg = __x"Hello {name}!", name => $name;

So: the "msgid" is usually a format string. Only when you use formats correctly, you will be able to introduce translation later.

  Why use format strings?
Simple perl scripts will use print() with variables in the string. However, when the content of the variable gets more unpredictable or needs some pre-processing, then it gets tricky. When you do want to introduce translations (in the far future of your successful project) it gets impossible. Let me give you some examples:

  print "product: $name\n";    # simple perl

  # Will not work because "$name" is interpolated too early
  print translate("product: $name"), "\n";

  # This is the gettext solution, with formats
  printf translate("product: %s\n"), $name;

  # With named in stead of positional parameters
  print translate("product: {p}\n", p => $name);

  # With Log::Report, the translate() is hidden in __x()
  print __x"product: {p}\n", p => $name;

Besides making translation possible, interpolation via format strings is much cleaner than in the simpelest perl way. For instance, these cases:

  # Safety measures while interpolation
  my $name = undef;
  print "product: $name\n";   # uninitialized warning
  print __x"product: {p}\n", p => $name;  # --> product: undef

  # Interpolation of more complex data
  my @names = qw/a b c/;
  print "products: ", join(', ', @names), "\n";
  print __x"products: {p}\n", p => \@names;

  # Padded values hard to do without format strings
  print "padded counter: ", ' ' x (6-length $c), "$c\n";
  printf "padded counter: %6d\n", $counter;
  print __x"padded counter: {c%6d}\n", c => $counter;

So: using formats has many advantages. Advice: use simple perl only in "trace" and "assert" messages, maybe also with panics. For serious output of your program, use formatted output.

  Messages with plural forms
The Log::Report::__xn() message constructor is used when you need a different translation based on the count of one of the inserted fields.

  fault __x"cannot read {file}", file => $fn;
  # --> FAULT: cannot read /etc/shadow: Permission denied\n

  print __xn"directory {dir} contains one file",
            "directory {dir} contains {nr_files} files",
            scalar(@files),            # (1) (2) (3)
            nr_files => scalar @files, # (4)
            dir      => $dir;

(1) this required third parameter is used to switch between the different plural forms. English has only two forms, but some languages have many more.

(2) the "scalar" keyword is not needed, because the third parameter is in SCALAR context. You may also pass " \@files " there, because ARRAYs will be converted into their length. A HASH will be converted into the number of keys in the HASH.

(3) you could also simply pass a reference to the ARRAY: it will take the length as counter. With a HASH, it will count the number of keys.

(4) the "scalar" keyword is required here, because it is LIST context: otherwise all filenames will be filled-in as parameters to "__xn()". See below for the available "_count" value, to see how the "nr_files" parameter can disappear.

  print __xn"directory {dir} contains one file",
            "directory {dir} contains {_count} files",
            \@files, dir => $dir;

Some languages need more than two translations based on the counter. This is solved by the translation table definition. The two msgids give here are simply the fallback, when there is not translation table active.

Interpolation with String::Print

There is no way of checking beforehand whether you have provided all required values, to be interpolated in the translated string.

This Log::Report::Message uses String::Print to handle formatted strings. On object of that module is hidden in the logic of "__x()" and friends.

String::Print is a very capable format string processor, and you should really read its manual page to see how it can help you. It would be possible to support an other formatter (pretty simple even), but this is not (yet) supported.

» Example: using format features

  # This tries to display the $param as useful and safe as possible,
  # where you have totally no idea what its contents is.
  error __x"illegal parameter {p UNKNOWN}.", p => $param;
  # ---> "illegal parameter 'accidentally passed text'."
  # ---> "illegal parameter Unexpected::Object::Type."

  # fault() adds ": $!", with $! translated when configured.
  open my($fh), "<:encoding(utf-8)", $filename
         or fault __x"cannot read {file}", file => $filename;

  # Auto-abbreviation
  trace __x"first lines: '{text EL}'\n", text => $t;
  # ---> "first lines: 'This text is long, we sho⋯'.\n"

  trace __x"first lines: {text CHOP}\n", text => $t;
  # ---> "This text is long, we [+3712 chars]\n"

  info __x"file {file} size {size BYTES}\n", file => $fn, size => -s $fn;
  # --> "/etc/passwd size 23kB\n"

  # HASH or object values
  print __x"Name: {user.first} {user.surname}\n", user => $login;

There are more nice standard interpolation modifiers, and you can add your own. Besides, you can add serializers which determine how objects are inlined.

  Automatic parameters
Besides the parameters which you specify yourself, Log::Report will add a few which can also be interpolated. The all start with an underscore ("_"). These are collected when this Message object is instantiated, see the %options of new(). These parameters have a purpose, but you are also permitted tp interpolate them in your message. This may simplify your coding.

The useful names are:

_msgid
    The MSGID as provided with Log::Report::__() and Log::Report::__x()

_plural, _count
    The plural (second) msgid, respectively the counter value as used with Log::Report::__n() and Log::Report::__nx()

_textdomain
    The label of the textdomain in which the translation takes place.

_join
    The string which is used between elements of an ARRAY, when it gets interpolated in a single field.

_tags
    [1.44] Tags are to be used to group exceptions, and can be queried with taggedWith(), Log::Report::Exception::taggedWith(), or Log::Report::Dispatcher::Try::wasFatal(tag).

» Example: using the _count

With Locale::TextDomain, you have to do

  use Locale::TextDomain;
  print __nx(
     "One file has been deleted.\n",
     "{num} files have been deleted.\n",
     $num_files,
     num => $num_files,
  );

With "Log::Report", you can do

  use Log::Report;
  print __nx(
     "One file has been deleted.\n",
     "{_count} files have been deleted.\n",
     $num_files,
  );

Of course, you need to be aware that the name used to reference the counter is fixed to "_count". The first example works as well, but is more verbose.

Handling white-spaces

In above examples, the msgid and plural form have a trailing new-line. In general, it is much easier to write

  print __x"Hello, World!\n";

than

  print __x("Hello, World!") . "\n";

For the translation tables, however, that trailing new-line is "ignorable information"; it is an layout issue, not a translation issue.

Therefore, the first form will automatically be translated into the second. All leading and trailing white-space (blanks, new-lines, tabs, ...) are removed from the msgid before the look-up, and then added to the translated string.

Leading and trailing white-space on the plural form will also be removed. However, after translation the spacing of the msgid will be used.

Avoiding repetative translations

This way of translating is somewhat expensive, because an object to handle the "Log::Report::__x()" is created each time.

  for my $i (1..100_000)
  {   print __x "Hello World {i}\n", i => $i;
  }

The suggestion that Locale::TextDomain makes to improve performance, is to get the translation outside the loop, which only works without interpolation:

  use Locale::TextDomain;
  my $i = 42;
  my $s = __x("Hello World {i}\n", i => $i);
  foreach $i (1..100_000)
  {   print $s;
  }

Oops, not what you mean because the first value of $i is captured in the initial message object. With Log::Report, you can do it (except when you use contexts)

  use Log::Report;
  my $i;
  my $s = __x("Hello World {i}\n", i => \$i);
  foreach $i (1..100_000)
  {   print $s;
  }

Mind you not to write: "for my $i" in above case!!!!

You can also write an incomplete translation:

  use Log::Report;
  my $s = __x "Hello World {i}\n";
  foreach my $i (1..100_000)
  {   print $s->(i => $i);
  }

In either case, the translation will be looked-up only once.

SEE ALSO
This module is part of Log-Report version 1.45, built on April 10, 2026. Website: http://perl.overmeer.net/CPAN/

LICENSE
For contributors see file ChangeLog.

This software is copyright (c) 2007-2026 by Mark Overmeer.

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.