App::Cmd::Simple(3pm)

NAME
App::Cmd::Simple - a helper for building one-command App::Cmd applications

VERSION
version 0.340

SYNOPSIS
in simplecmd:

  use YourApp::Cmd;
  Your::Cmd->run;

in YourApp/Cmd.pm:

  package YourApp::Cmd 0.01;
  use parent qw(App::Cmd::Simple);

  sub opt_spec {
    return (
      [ "blortex|X",  "use the blortex algorithm" ],
      [ "recheck|r",  "recheck all results"       ],
    );
  }

  sub validate_args {
    my ($self, $opt, $args) = @_;

    # no args allowed but options!
    $self->usage_error("No args allowed") if @$args;
  }

  sub execute {
    my ($self, $opt, $args) = @_;

    my $result = $opt->{blortex} ? blortex() : blort();

    recheck($result) if $opt->{recheck};

    print $result;
  }

and, finally, at the command line:

  knight!rjbs$ simplecmd --recheck

  All blorts successful.

PERL VERSION
This library should run on perls released even a long time ago. It should work on any version of perl released in the last five years.

Although it may work on older versions of perl, no guarantee is made that the minimum required version will not be increased. The version may be increased for any reason, and there is no promise that patches will be accepted to lower the minimum required perl.

SUBCLASSING
When writing a subclass of App::Cmd:Simple, there are only a few methods that you might want to implement. They behave just like the same-named methods in App::Cmd.

  opt_spec
This method should be overridden to provide option specifications. (This is list of arguments passed to "describe_options" from Getopt::Long::Descriptive, after the first.)

If not overridden, it returns an empty list.

  usage_desc
This method should be overridden to provide the top level usage line. It's a one-line summary of how the command is to be invoked, and should be given in the format used for the $usage_desc parameter to "describe_options" in Getopt::Long::Descriptive.

If not overridden, it returns something that prints out like:

  yourapp [-?h] [long options...]

  validate_args
  $cmd->validate_args(\%opt, \@args);

This method is passed a hashref of command line options (as processed by Getopt::Long::Descriptive) and an arrayref of leftover arguments. It may throw an exception (preferably by calling "usage_error") if they are invalid, or it may do nothing to allow processing to continue.

  execute
  Your::App::Cmd::Simple->execute(\%opt, \@args);

This method does whatever it is the command should do! It is passed a hash reference of the parsed command-line options and an array reference of left over arguments.

WARNINGS
This should be considered experimental! Although it is probably not going to change much, don't build your business model around it yet, okay?

App::Cmd::Simple is not rich in black magic, but it does do some somewhat gnarly things to make an App::Cmd::Simple look as much like an App::Cmd::Command as possible. This means that you can't deviate too much from the sort of thing shown in the synopsis as you might like. If you're doing something other than writing a fairly simple command, and you want to screw around with the App::Cmd-iness of your program, Simple might not be the best choice.

One specific warning... if you are writing a program with the App::Cmd::Simple class embedded in it, you must call import on the class. That's how things work. You can just do this:

  YourApp::Cmd->import->run;

AUTHOR
Ricardo Signes <cpan@semiotic.systems>

COPYRIGHT AND LICENSE
This software is copyright (c) 2026 by Ricardo Signes.

This is free software; you can redistribute it and/or modify it under the same terms as the Perl 5 programming language system itself.