///////////////////////////////////////////////////////////////////////////////
//                              Lisaac Example                               //
//                                                                           //
//                   LSIIT - ULP - CNRS - INRIA - FRANCE                     //
//                                                                           //
//   This program is free software: you can redistribute it and/or modify    //
//   it under the terms of the GNU General Public License as published by    //
//   the Free Software Foundation, either version 3 of the License, or       //
//   (at your option) any later version.                                     //
//                                                                           //
//   This program is distributed in the hope that it will be useful,         //
//   but WITHOUT ANY WARRANTY; without even the implied warranty of          //
//   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the           //
//   GNU General Public License for more details.                            //
//                                                                           //
//   You should have received a copy of the GNU General Public License       //
//   along with this program.  If not, see <http://www.gnu.org/licenses/>.   //
//                                                                           //
//                     http://isaacproject.u-strasbg.fr/                     //
///////////////////////////////////////////////////////////////////////////////
Section Header
  
  + name        := TEST_GCD;
  
  - author      :="Boutet Jerome (boutet@loria.fr)";
  
  - comment     := "Find the great common divisor between 2 values";
  
Section Inherit
  
  - parent_object:OBJECT := OBJECT;

Section Private
  
  - gcd (value_1,value_2:INTEGER) :INTEGER <-
  // Great Common Divisor of `value_1' and `value_2'.
  ( + value,result:INTEGER;
    ? { value_1 > 0};
    ? { value_2 > 0};
    result := value_1;
    value := value_2;
    {result = value}.until_do {
      (result > value).if {
        result := result - value;
      } else {
        value := value - result;
      };
    };
    result
  );
	 
Section Public

  - main <-
  ( + v1,v2:INTEGER;
    "Enter the first number: ".print;
    IO.read_integer;
    v1 := IO.last_integer;
    "\nEnter the second number: ".print;
    IO.read_integer;
    v2 := IO.last_integer;
    "\nThe Great Common Divisor is: ".print;
    gcd (v1,v2).print;
    '\n'.print;
  );
