# Boxes

The boxes style is only relevant to 2D plotting. It draws a box centered about the given x coordinate that extends from the x axis (not from the graph border) to the given y coordinate. It uses 2 or 3 columns of basic data. Additional input columns may be used to provide information such as variable line or fill color (see rgbcolor variable (p. )).

        2 columns:  x  y
        3 columns:  x  y  x_width

The width of the box is obtained in one of three ways. If the input data has a third column, this will be used to set the width of the box. If not, if a width has been set using the set boxwidth command, this will be used. If neither of these is available, the width of each box will be calculated automatically so that it touches the adjacent boxes.

The interior of the boxes is drawn according to the current fillstyle. See set style fill (p. ) for details. Alternatively a new fillstyle may be specified in the plot command. For fillstyle empty the box is not filled. For fillstyle solid the box is filled with a solid rectangle of the current drawing color. An optional fillstyle parameter controls the fill density; it runs from 0 (background color) to 1 (current drawing color). For fillstyle pattern the box is filled in the current drawing color with a pattern.

Examples:

To plot a data file with solid filled boxes with a small vertical space separating them (bargraph):

         set boxwidth 0.9 relative
         set style fill solid 1.0
         plot 'file.dat' with boxes

To plot a sine and a cosine curve in pattern-filled boxes style:

         set style fill pattern
         plot sin(x) with boxes, cos(x) with boxes

The sin plot will use pattern 0; the cos plot will use pattern 1. Any additional plots would cycle through the patterns supported by the terminal driver.

To specify explicit fillstyles for each dataset:

        plot 'file1' with boxes fs solid 0.25, \
             'file2' with boxes fs solid 0.50, \
             'file3' with boxes fs solid 0.75, \
             'file4' with boxes fill pattern 1, \
             'file5' with boxes fill empty