#
# Simple demo of scatter data conversion to grid data.
#

set title "Simple demo of scatter data conversion to grid data"
unset hidden3d
set ticslevel 0.5
set view 60,30
set autoscale
set parametric
set style data points
set xlabel "data style point - no dgrid"
set key box
splot "hemisphr.dat"
pause -1 "Hit return to continue (1)"

set dgrid3d 10,10 qnorm 1
set xlabel " data style lines, dgrid3d qnorm 1"
set style data lines
splot "hemisphr.dat"
pause -1 "Hit return to continue (2)"

set dgrid3d qnorm 4
set xlabel " data style lines, dgrid3d qnorm 4 "
set style data lines
splot "hemisphr.dat"
pause -1 "Hit return to continue (3)"

set dgrid3d qnorm 16
set xlabel " data style lines, dgrid3d qnorm 16"
set style data lines
splot "hemisphr.dat"
pause -1 "Hit return to continue (4)"

set contour
set xlabel "data style lines, dgrid3d qnorm 16, contour"
splot "hemisphr.dat"
pause -1 "Hit return to continue (5)"

unset dgrid3d
set style data points
set xlabel "data style points, nodgrid3d"
splot "scatter2.dat"
pause -1 "Hit return to continue (6)"

set key nobox
set dgrid3d qnorm 1
set xlabel "data style lines, dgrid3d qnorm 1"
set style data lines
splot "scatter2.dat"
pause -1 "Hit return to continue (7)"

set dgrid3d qnorm 4
set xlabel "data style lines, dgrid3d qnorm 4"
set style data lines
splot "scatter2.dat"
pause -1 "Hit return to continue (8)"
reset
