### 2.6 circles

The circles style plots a circle with an explicit radius at each data point. If three columns of data are present, they are interpreted as x, y, radius. The radius is always interpreted in the units of the plot’s horizontal axis (x or x2). The scale on y and the aspect ratio of the plot are both ignored. If only two columns are present, the radius is taken from ‘set style circle‘. In this case the radius may be given in graph or screen coordinates. By default a full circle will be drawn. It is possible to plot arc segments instead of full circles by specifying a start and end angle in the 4th and 5th columns. An optional 4th or 6th column can specify per-circle color. The start and end angles of the circle segments must be specified in degrees.

Examples:

        # draws circles whose area is proportional to the value in column 3
        set style fill transparent solid 0.2 noborder
        plot 'data' using 1:2:(sqrt($3)) with circles, \
             'data' using 1:2 with linespoints

        # draws Pac-men instead of circles
        plot 'data' using 1:2:(10):(40):(320) with circles

        # draw a pie chart with inline data
        set xrange [-15:15]
        set style fill transparent solid 0.9 noborder
        plot '-' using 1:2:3:4:5:6 with circles lc var
        0    0    5    0    30    1
        0    0    5   30    70    2
        0    0    5   70   120    3
        0    0    5  120   230    4
        0    0    5  230   360    5
        e

The result is similar to using a ‘points‘ plot with variable size points and pointstyle 7, except that the circles will scale with the x axis range. See also ‘set object circle‘ and ‘fillstyle‘.