#### 3.25.43 mxtics

Minor tic marks along the x axis are controlled by mxtics. They can be turned off with mxtics. Similar commands control minor tics along the other axes.

Syntax:

          set mxtics {<freq> | default}
          unset mxtics
          show mxtics

The same syntax applies to mytics, mztics, mx2tics, my2tics and ‘mcbtics‘.

<freq> is the number of sub-intervals (NOT the number of minor tics) between major tics (the default for a linear axis is either two or five depending on the major tics, so there are one or four minor tics between major tics). Selecting ‘default‘ will return the number of minor ticks to its default value.

If the axis is logarithmic, the number of sub-intervals will be set to a reasonable number by default (based upon the length of a decade). This will be overridden if <freq> is given. However the usual minor tics (2, 3, ..., 8, 9 between 1 and 10, for example) are obtained by setting <freq> to 10, even though there are but nine sub-intervals.

To set minor tics at arbitrary positions, use the ("<label>" <pos> <level>, ...) form of ‘set {x|x2|y|y2|z}tics‘ with <label> empty and <level> set to 1.

The ‘set m{x|x2|y|y2|z}tics‘ commands work only when there are uniformly spaced major tics. If all major tics were placed explicitly by ‘set {x|x2|y|y2|z}tics‘, then minor tic commands are ignored. Implicit major tics and explicit minor tics can be combined using ‘set {x|x2|y|y2|z}tics‘ and ‘set {x|x2|y|y2|z}tics add‘.

Examples:

          set xtics 0, 5, 10
          set xtics add (7.5)
          set mxtics 5

Major tics at 0,5,7.5,10, minor tics at 1,2,3,4,6,7,8,9

          set logscale y
          set ytics format ""
          set ytics 1e-6, 10, 1
          set ytics add ("1" 1, ".1" 0.1, ".01" 0.01, "10^-3" 0.001, \
                         "10^-4" 0.0001)
          set mytics 10

Major tics with special formatting, minor tics at log positions

By default, minor tics are off for linear axes and on for logarithmic axes. They inherit the settings for ‘axis|border‘ and ‘{no}mirror‘ specified for the major tics. Please see ‘set xtics‘ for information about these.