#### 3.25.7 border

The border and border commands control the display of the graph borders for the ‘plot‘ and ‘splot‘ commands. Note that the borders do not necessarily coincide with the axes; with ‘plot‘ they often do, but with ‘splot‘ they usually do not.

Syntax:

          set border {<integer>} {front | back} {linewidth | lw <line_width>}
                     {{linestyle | ls <line_style>} | {linetype | lt <line_type>}}
          unset border
          show border

With a ‘splot‘ displayed in an arbitrary orientation, like ‘set view 56,103‘, the four corners of the x-y plane can be referred to as "front", "back", "left" and "right". A similar set of four corners exist for the top surface, of course. Thus the border connecting, say, the back and right corners of the x-y plane is the "bottom right back" border, and the border connecting the top and bottom front corners is the "front vertical". (This nomenclature is defined solely to allow the reader to figure out the table that follows.)

The borders are encoded in a 12-bit integer: the bottom four bits control the border for ‘plot‘ and the sides of the base for ‘splot‘; the next four bits control the verticals in ‘splot‘; the top four bits control the edges on top of the ‘splot‘. In detail, ‘<integer>‘ should be the sum of the appropriate entries from the following table:

                Bit     plot        splot
                  1   bottom      bottom left front
                  2   left        bottom left back
                  4   top         bottom right front
                  8   right       bottom right back
                 16   no effect   left vertical
                 32   no effect   back vertical
                 64   no effect   right vertical
                128   no effect   front vertical
                256   no effect   top left back
                512   no effect   top right back
               1024   no effect   top left front
               2048   no effect   top right front

Various bits or combinations of bits may be added together in the command.

The default is 31, which is all four sides for ‘plot‘, and base and z axis for ‘splot‘.

In 2D plots the border is normally drawn on top of all plots elements (‘front‘). If you want the border to be drawn behind the plot elements, use ‘set border back‘.

Using the optional <line_style>, <line_type> and <line_width> specifiers, the way the border lines are drawn can be influenced (limited by what the current terminal driver supports).

For ‘plot‘, tics may be drawn on edges other than bottom and left by enabling the second axes – see ‘set xtics‘ for details.

If a ‘splot‘ draws only on the base, as is the case with "‘unset surface; set contour base‘", then the verticals and the top are not drawn even if they are specified.

The ‘set grid‘ options ’back’, ’front’ and ’layerdefault’ also control the order in which the border lines are drawn with respect to the output of the plotted data.

Examples:

Draw default borders:

          set border

Draw only the left and bottom (‘plot‘) or both front and back bottom left (‘splot‘) borders:

          set border 3

Draw a complete box around a ‘splot‘:

          set border 4095

Draw a topless box around a ‘splot‘, omitting the front vertical:

          set border 127+256+512 # or set border 1023-128

Draw only the top and right borders for a ‘plot‘ and label them as axes:

          unset xtics; unset ytics; set x2tics; set y2tics; set border 12