Previous | About HAP: The Rosenberger monster - an example of how to piece together information | next

A generalized triangle group is a group given by a presentation
< a, b | ap = bq = Rm = 1 >
where p, q , m are integers greater than 1 and R is a reduced word in the free monoid on a and b. The finite generalized triangle groups were classified in

- [J. Howie, V.Metaftsis & R.M.Thomas, Triangle groups and their generalizations, Groups Korea '94, pages 135-147, (de Gruyter 1995)],
- [L. Levai, G. Rosenberger and B. Souvignier, All finite generalized triangle groups, Transactions American Mathematical Society 347 (9) (1995), 3625-3627].

The largest finite generalized triangle group is
G = < a, b | a2, b3, (abababab2ab2abab2ab2)2 >
and has order |G| = 220 34 5 . It has been named the Rosenberger monster. The following GAP commands, which were shown to me by R.F. Morse, create a solvable subgroup K in G of index 5.

gap> F := FreeGroup("a","b");; a:=F.1;; b:=F.2;; gap> R := [a^2, b^3, (a*b*a*b*a*b*a*b^2*a*b^2*a*b*a*b^2*a*b^2)^2];; gap> G := F/R;; gap> a:= G.1;; b:=G.2;; gap> K:=Subgroup(G, [a, (b^a)^b, (b^a)^(b^2)]);; gap> Index(G,K); 5
The Schur Multiplier H2(G,Z) of the Rosenberger monster is a quotient of H2(K,Z) since K contains the Sylow 2-subgroup and Sylow 3-subgroup of G, and the Sylow 5-subgroup is cyclic and thus has trivial Schur multiplier. The following commands first create a pc-group Kpc isomorphism to K, then construct three terms of a resolution for K, and finally show that H1(K,Z)=H2(K,Z) = Z3+Z6 .

gap> K_iso_Kfp := IsomorphismFpGroup(K);;
gap> Kfp:=Image(K_iso_Kfp);;
gap> Kfp_iso_Kpc:= EpimorphismSolvableQuotient(Kfp,2^20*3^4);;
gap> Kpc:=Image(Kfp_iso_Kpc);;
gap> D:=DerivedSeries(Kpc)[3];;
gap> NatHom:=NaturalHomomorphismByNormalSubgroup(Kpc,D);;
gap> Q:=Image(NatHom);;
gap> N:=NormalSubgroups(Q)[12];;
gap> RQ:=ResolutionNormalSeries([Q,N,TrivialSubgroup(Q)],3);;
gap> RD:=ResolutionNilpotentGroup(D,3);;
gap> RKpc:=ResolutionExtension(NatHom,RD,RQ);;
gap> TRKpc:=TensorWithIntegers(RKpc);;
gap> Homology(TRKpc,1);
[ 3, 6 ]
gap> Homology(TRKpc,2);
[ 3, 6 ]

The following commands construct the group D=[[G,G],[G,G]] and show that H2(G/D,Z)=Z6 and D=[G,D] .
gap> D:=DerivedSubgroup(DerivedSubgroup(G));; gap> GroupHomology(G/D,2); [ 2, 3 ] gap> Index(G,D)=Index(G,CommutatorSubgroup(G,D)); true

The five term exact sequence in integral homology (see this page for details) arising from the normal subgroup D in G yields a surjection H2(G,Z) → H2(G/D,Z) . We conclude that the Schur multiplier of the Rosenberger monster is either
H2(G,Z) = Z3+Z6 or H2(G,Z) = Z6 ..
We can complete the calculation of H2(G,Z) using the following basic result.

For any finite group G with presentation G = < x | r > the minimum number of generator of the Schur multiplier dH2(G,Z) satisfies dH2(G,Z) < |r| - |x| + 1 .

This result follows from the fact that H*(G,Z) is finite and is the homology of a chain complex of free abelian groups with 1 generator in dimension 0, |x| generators in dimension 1 and |r| generators in dimension 2. We now have the following.

Proposition The Rosenberger monster has Schur multiplier H2(G,Z) = Z6 .

Previous Page | Contents | Next page