[Overview][Constants][Types][Procedures and functions][Variables][Index] | Reference for unit 'video' (#rtl)

# GetVideoModeCount

Get the number of video modes supported by the driver.

## Declaration

Source position: videoh.inc line 148

`function GetVideoModeCount: Word;`

## Description

GetVideoModeCount returns the number of video modes that the current driver supports. If the driver does not support switching of modes, then 1 is returned.

This function can be used in conjunction with the GetVideoModeData function to retrieve data for the supported video modes.

## Errors

None.

## See also

GetVideoModeData |  | Get the specifications for a video mode
GetVideoMode |  | Return current video mode

## Example

    Program Example8;

    { Program to demonstrate the GetVideoModeCount function. }

    Uses video,keyboard,vidutil;

    Procedure DumpMode (M : TVideoMode; Index : Integer);

    Var
     S : String;

    begin
      Str(Index:2,S);
      inc(Index);
      TextOut(1,Index,'Data for mode '+S+': ');
      if M.Color then
        TextOut(19,Index,'   color,')
      else
        TextOut(19,Index,'No color,');
      Str(M.Row:3,S);
      TextOut(28,Index,S+' rows');
      Str(M.Col:3,S);
      TextOut(36,index,S+' columns');
    end;

    Var
      i,Count : Integer;
      m : TVideoMode;

    begin
      InitVideo;
      InitKeyboard;
      Count:=GetVideoModeCount;
      For I:=1 to Count do
        begin
        GetVideoModeData(I-1,M);
        DumpMode(M,I-1);
        end;
      TextOut(1,Count+1,'Press any key to exit');
      UpdateScreen(False);
      GetKeyEvent;
      DoneKeyboard;
      DoneVideo;
    end.