reinit
Prev | Orchestra Opcodes and Operators | Next

## reinit

reinit — Suspends a performance while a special initialization pass is executed.

## Description

Suspends a performance while a special initialization pass is executed.

Whenever this statement is encountered during a p-time pass, performance is temporarily suspended while a special Initialization pass, beginning at label and continuing to rireturn or endin, is executed. Performance will then be resumed from where it left off.

## Syntax

    reinit label

## Examples

The following statements will generate an exponential control signal whose value moves from 440 to 880 exactly ten times over the duration p3. They use the file reinit.csd.

Example 889. Example of the reinit opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in
    -odac      ;;;RT audio out
    ; For Non-realtime ouput leave only the line below:
    ; -o reinit.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    reset:
            timout 0, p3/p4, contin
            reinit reset

    contin:
            kLine expon 440, p3/p4, 880
            aSig poscil 1, kLine
            outs aSig, aSig
            rireturn

    endin

    </CsInstruments>
    <CsScore>

    i1 0 10 10
    i1 + 10 50
    e
    </CsScore>
    </CsoundSynthesizer>

A musical example featuring the reinit opcode: Reinit_Giordani.csd by Eugenio Giordani.

## See also

Initialization and Reinitialization

Prev | Up | Next
rect2pol | Home | release