zaw
Prev | Orchestra Opcodes and Operators | Next

## zaw

zaw — Writes to a za variable at a-rate without mixing.

## Description

Writes to a za variable at a-rate without mixing.

## Syntax

    zaw asig, kndx

## Performance

asig -- value to be written to the za location.

kndx -- points to the za location to which to write.

zaw writes asig into the za variable specified by kndx.

These opcodes are fast, and always check that the index is within the range of zk or za space. If not, an error is reported, 0 is returned, and no writing takes place.

## Examples

Here is an example of the zaw opcode. It uses the file zaw.csd.

Example 1248. Example of the zaw opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o zaw.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Initialize the ZAK space.
    ; Create 1 a-rate variable and 1 k-rate variable.
    zakinit 1, 1

    ; Instrument #1 -- a simple waveform.
    instr 1
      ; Generate a simple sine waveform.
      asin oscil 20000, 440, 1

      ; Send the sine waveform to za variable #1.
      zaw asin, 1
    endin

    ; Instrument #2 -- generates audio output.
    instr 2
      ; Read za variable #1.
      a1 zar 1

      ; Generate the audio output.
      out a1

      ; Clear the za variables, get them ready for
      ; another pass.
      zacl 0, 1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 16384 10 1

    ; Play Instrument #1 for one second.
    i 1 0 1
    ; Play Instrument #2 for one second.
    i 2 0 1
    e

    </CsScore>
    </CsoundSynthesizer>

## See also

Zak Patch System

## Credits

Author: Robin Whittle
Australia
May 1997

New in version 3.45

Example written by Kevin Conder.

Prev | Up | Next
zarg | Home | zawm