outletk
Prev | Orchestra Opcodes and Operators | Next

## outletk

outletk — Sends a krate signal out from an instrument to a named port.

## Description

Plugin opcode in signalflowgraph

Sends a krate signal out from an instrument to a named port.

## Syntax

    outletk Sname, ksignal

## Initialization

Sname -- String name of the outlet port. The name of the outlet is implicitly qualified by the instrument name or number, so it is valid to use the same outlet name in more than one instrument (but not to use the same outlet name twice in one instrument).

## Performance

ksignal -- krate output signal

During performance, the krate output signal is sent to each instance of an instrument containing an inlet port to which this outlet has been connected using the connect opcode. The signals of all the outlets connected to an inlet are summed in the inlet.

## Examples

Here is an example of the outletk opcode. It uses the file outletk.csd.

Example 716. Example of the outletk opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o outletk.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    connect "bend", "bendout", "guitar", "bendin"

    instr bend

    kbend line p4, p3, p5
    printk2 kbend
          outletk "bendout", kbend

    endin

    instr guitar

    kbend inletk "bendin"
    kpch pow 2, kbend/12
    asig oscili .4, p4*kpch, 1
         outs asig, asig
    endin

    </CsInstruments>
    <CsScore>
    f1 0 1024 10 1 0 1 0 1 0 1

    i"guitar" 0  5   440
    i"bend"   2 1.2 -12 12
    i"bend"   4 .2  -17 40
    e
    </CsScore>

## See also

Signal Flow Graph Opcodes

More information on this opcode: http://www.csoundjournal.com/issue13/signalFlowGraphOpcodes.html , written by Michael Gogins

## Credits

By: Michael Gogins 2009

Prev | Up | Next
outletf | Home | outletkid