pvsmix
Prev | Orchestra Opcodes and Operators | Next

## pvsmix

pvsmix — Mix 'seamlessly' two pv signals.

## Description

Mix 'seamlessly' two pv signals. This opcode combines the most prominent components of two pvoc streams into a single mixed stream.

## Syntax

    fsig pvsmix fsigin1, fsigin2

## Performance

fsig -- output pv stream

fsigin1 -- input pv stream.

fsigin2 -- input pv stream, which must have same format as fsigin1.

| Warning
It is unsafe to use the same f-variable for both input and output of pvs opcodes. Using the same one might lead to undefined behavior on some opcodes. Use a different one on the left and right sides of the opcode.

## Examples

Here is an example of the pvsmix opcode. It uses the file pvsmix.csd.

Example 851. Example of the pvsmix opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac  ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o pvsmix.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; by Menno Knevel 2021

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    asig1 diskin2 "drumsMlp.wav", .5,0,1		;signal in 1 at half speed
    asig2 diskin2 "drumsMlp.wav", 1,0,1		;signal in 2
    fsig1 pvsanal asig1,1024,256,1024,0	      ;pvoc analysis
    fsig2 pvsanal asig2,1024,256,1024,0	      ;of both signals
    fsall pvsmix  fsig1, fsig2
    asig  pvsynth fsall
    outs asig, asig

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 8
    e
    </CsScore>
    </CsoundSynthesizer>

## See also

Tools for Real-time Spectral Processing (pvs opcodes)

## Credits

Author: Victor Lazzarini
November 2004

New plugin in version 5

November 2004.

Prev | Up | Next
pvsmaska | Home | pvsmorph