sum
Prev | Orchestra Opcodes and Operators | Next

## sum

sum — Sums any number of a-rate signals, or array elements.

## Description

Sums any number of a-rate signals, or array elements.

## Syntax

    ares sum asig1 [, asig2] [, asig3] [...]

    kres sum karr

    ires sum iarr

## Performance

asig1, asig2, ... -- a-rate signals to be summed (mixed or added).

karr, iarr -- Csound 1-dimensional arrays

## Examples

Here is an example of the sum opcode. It uses the file sum.csd.

Example 1057. Example of the sum opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac   ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o sum.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    gisine ftgen 0, 0, 2^10, 10, 1

    instr 1

    a1   oscili 1, 10.0, gisine		;combine 3 sinusses
    a2   oscili 1, 1.0, gisine		;at different rates
    a3   oscili 1, 3.0, gisine
    ares sum a1, a2, a3			;sum them

    ares = ares*100				;scale result and
    asig poscil .5, ares+110, gisine	;add to frequency
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>

    i1 0 5
    e
    </CsScore>
    </CsoundSynthesizer>

## See also

Opcode Equivalents of Functions

## Credits

Author: Gabriel Maldonado
Italy
April 1999

New in Csound version 3.54

Array versions new in version 6.09

Prev | Up | Next
subinstrinit | Home | sumarray