expsegb
Prev | Orchestra Opcodes and Operators | Next

## expsegb

expsegb — Trace a series of exponential segments between specified absolute points.

## Description

Trace a series of exponential segments between specified absolute points.

## Syntax

    ares expsegb ia, itim1, ib [, itim2] [, ic] [...]

    kres expsegb ia, itim1, ib [, itim2] [, ic] [...]

## Initialization

ia -- starting value. Zero is illegal for exponentials.

ib, ic, etc. -- value at tim1 seconds, etc. For exponentials, must be non-zero and must agree in sign with ia.

itim1 -- time in seconds of end of first segment.

itim2, itim3, etc. -- time in seconds of subsequent ends of segments.

## Performance

These units generate control or audio signals whose values can pass through 2 or more specified points. The last tim value may or may not equal the instrument's performance time: a shorter performance will truncate the specified pattern, while a longer one will cause the last-defined segment to continue on in the same direction.

Note that the expsegb opcode does not operate correctly at audio rate when segments are shorter than a k-period. Try the expsegba opcode instead.

## Examples

Here is an example of the expsegb opcode. It uses the file expsegb.csd.

Example 285. Example of the expsegb opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in
    -odac           -iadc    ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o expseg.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      ; p4 = frequency in pitch-class notation.
      kcps = cpspch(p4)

      ; Create an amplitude envelope.
      kenv expsegb 0.01, p3*0.25, 1, p3, 0.01
      kamp = kenv * 30000

      a1 oscil kamp, kcps, 1
      out a1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 16384 10 1

    ; Play Instrument #1 for a half-second, p4=8.00
    i 1 0 0.5 8.00
    ; Play Instrument #1 for a half-second, p4=8.01
    i 1 1 0.5 8.01
    ; Play Instrument #1 for a half-second, p4=8.02
    i 1 2 0.5 8.02
    ; Play Instrument #1 for a half-second, p4=8.03
    i 1 3 0.5 8.03
    e

    </CsScore>
    </CsoundSynthesizer>

## See also

Linear and Exponential Generators

## Credits

Author: Victor Lazzarini
June 2011

New in version 5.14

Prev | Up | Next
expsega | Home | expsegba