foscili
Prev | Orchestra Opcodes and Operators | Next

## foscili

foscili — Basic frequency modulated oscillator with linear interpolation.

## Description

Basic frequency modulated oscillator with linear interpolation.

## Syntax

    ares foscili xamp, kcps, xcar, xmod,
        kndx [, ifn, iphs]

## Initialization

ifn (optional) -- function table number. Requires a wrap-around guard point. Defaults to a sine wave/

iphs (optional, default=0) -- initial phase of waveform in table ifn, expressed as a fraction of a cycle (0 to 1). A negative value will cause phase initialization to be skipped. The default value is 0.

## Performance

xamp -- the amplitude of the output signal.

kcps -- a common denominator, in cycles per second, for the carrier and modulating frequencies.

xcar -- a factor that, when multiplied by the kcps parameter, gives the carrier frequency.

xmod -- a factor that, when multiplied by the kcps parameter, gives the modulating frequency.

kndx -- the modulation index.

foscili differs from foscil in that the standard procedure of using a truncated phase as a sampling index is here replaced by a process that interpolates between two successive lookups. Interpolating generators will produce a noticeably cleaner output signal, but they may take as much as twice as long to run. Adequate accuracy can also be gained without the time cost of interpolation by using large stored function tables of 2K, 4K or 8K points if the space is available.

## Examples

Here is an example of the foscili opcode. It uses the file foscili.csd.

Example 372. Example of the foscili opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac      ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o foscili.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kcps = 440
    kcar = 1
    kmod = p4
    kndx line 0, p3, 20	;intensivy sidebands

    asig foscili .5, kcps, kcar, kmod, kndx, 1
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    ; sine
    f 1 0 16384 10 1

    i 1 0  9 .01	;vibrato
    i 1 10 .  1
    i 1 20 . 1.414	;gong-ish
    i 1 30 5 2.05	;with "beat"
    e
    </CsScore>
    </CsoundSynthesizer>

## See Also

FM Synthesis

More information about frequency modulation on Wikipedia: http://en.wikipedia.org/wiki/Frequency_modulation_synthesis

Prev | Up | Next
foscil | Home | fout