reverbsc
Prev | Orchestra Opcodes and Operators | Next

## reverbsc

reverbsc — 8 delay line stereo FDN reverb, based on work by Sean Costello

## Description

8 delay line stereo FDN reverb, with feedback matrix based upon physical modeling scattering junction of 8 lossless waveguides of equal characteristic impedance. Based on Csound orchestra version by Sean Costello.

## Syntax

    aoutL, aoutR reverbsc ainL, ainR, kfblvl, kfco[, israte[, ipitchm[, iskip]]]

## Initialization

israte (optional, defaults to the orchestra sample rate) -- assume a sample rate of israte. This is normally set to sr, but a different setting can be useful for special effects.

ipitchm (optional, defaults to 1) -- depth of random variation added to delay times, in the range 0 to 10. The default is 1, but this may be too high and may need to be reduced for held pitches such as piano tones.

iskip (optional, defaults to zero) -- if non-zero, initialization of the opcode is skipped, whenever possible.

## Performance

aoutL, aoutR -- output signals for left and right channel

ainL, ainR -- left and right channel input. Note that having an input signal on either the left or right channel only will still result in having reverb output on both channels, making this unit more suitable for reverberating stereo input than the freeverb opcode.

kfblvl -- feedback level, in the range 0 to 1. 0.6 gives a good small "live" room sound, 0.8 a small hall, and 0.9 a large hall. A setting of exactly 1 means infinite length, while higher values will make the opcode unstable.

kfco -- cutoff frequency of simple first order lowpass filters in the feedback loop of delay lines, in Hz. Should be in the range 0 to israte/2 (not sr/2). A lower value means faster decay in the high frequency range.

## Examples

Here is an example of the reverbsc opcode. It uses the file reverbsc.csd.

Example 904. An example of the reverbsc opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o reverbsc.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>
    sr      =  48000
    ksmps   =  32
    nchnls  =  2
    0dbfs   =  1

            instr 1
    a1      vco2 0.85, 440, 10
    kfrq    port 100, 0.004, 20000
    a1      butterlp a1, kfrq
    a2      linseg 0, 0.003, 1, 0.01, 0.7, 0.005, 0, 1, 0
    a1      =  a1 * a2
    a2      =  a1 * p5
    a1      =  a1 * p4
            denorm a1, a2
    aL, aR  reverbsc a1, a2, 0.85, 12000, sr, 0.5, 1
            outs a1 + aL, a2 + aR
            endin

    </CsInstruments>
    <CsScore>
    i 1 0 1 0.71 0.71
    i 1 1 1 0 1
    i 1 2 1 -0.71 0.71
    i 1 3 1 1 0
    i 1 4 4 0.71 0.71
    e
    </CsScore>
    </CsoundSynthesizer>

## See also

Reverberation

## Credits

Author: Istvan Varga
2005

Prev | Up | Next
reverb2 | Home | rewindscore