trandom
Prev | Orchestra Opcodes and Operators | Next

## trandom

trandom — Generates a controlled pseudo-random number series between min and max values according to a trigger.

## Description

Generates a controlled pseudo-random number series between min and max values at k-rate whenever the trigger parameter is different to 0.

## Syntax

    kout trandom ktrig, kmin, kmax

## Performance

ktrig -- trigger (opcode produces a new random number whenever this value is not 0.

kmin -- minimum range limit

kmax -- maximum range limit

trandom is almost identical to random opcode, except trandom updates its output with a new random value only when the ktrig argument is triggered (i.e. whenever it is not zero).

## Examples

Here is an example of the trandom opcode. It uses the file trandom.csd.

Example 1115. Example of the trandom opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o trandom.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    seed 0				; every run time different values

    instr 1

    kmin init 0			;random number between 0 and 220
    kmax init 220
    ktrig = p4
    k1   trandom ktrig, kmin, kmax
         printk2 k1			;print when k1 changes
    asig poscil .4, 220+k1, 1	;if triggered, add random values to frequency
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f1 0 4096 10 1

    i 1 0 2 0	;not triggered
    i 1 + 2 1	;triggered
    e
    </CsScore>
    </CsoundSynthesizer>

## See also

Random (Noise) Generators

## Credits

Written by Gabriel Maldonado.

New in Csound 5.06

Prev | Up | Next
tonex | Home | tradsyn