outs
Prev | Orchestra Opcodes and Operators | Next

## outs

outs — Writes stereo audio data to an external device or stream.

## Description

Writes stereo audio data to an external device or stream.

## Syntax

    outs asig1, asig2

## Performance

Sends stereo audio samples to an accumulating output buffer (created at the beginning of performance) which serves to collect the output of all active instruments before the sound is written to disk. There can be any number of these output units in an instrument.

The type (mono, stereo, quad, hex, or oct) should agree with nchnls. But as of version 3.50, Csound will attempt to change an incorrect opcode to agree with the nchnls statement. Opcodes can be chosen to direct sound to any particular channel: outs1 sends to stereo channel 1, outq3 to quad channel 3, etc.

## Examples

Here is an example of the outs opcode. It uses the file outs.csd.

Example 725. Example of the outs opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac    ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o outs.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    asig vco2 .01, 110	; sawtooth waveform at low volume
    ;filter a channel
    kcut1 line 60, p3, 300	; Vary cutoff frequency
    kresonance1 = 3
    inumlayer1 = 3
    asig1 lowresx asig, kcut1, kresonance1, inumlayer1
    ;filter the other channel
    kcut2 line 300, p3, 60	; Vary cutoff frequency
    kresonance2 = 3
    inumlayer2 = 3
    asig2 lowresx asig, kcut2, kresonance2, inumlayer2

          outs asig1, asig2	; output both channels 1 & 2

    endin
    </CsInstruments>
    <CsScore>

    i 1 0 3
    e
    </CsScore>
    </CsoundSynthesizer>

## See also

Signal Output

## Credits

Author: Barry L. Vercoe, Matt Ingalls/Mike Berry
MIT, Mills College
1993-1997

Prev | Up | Next
outs2 | Home | outvalue