midicontrolchange
Prev | Orchestra Opcodes and Operators | Next

## midicontrolchange

midicontrolchange — Gets a MIDI control change value.

## Description

midicontrolchange is designed to simplify writing instruments that can be used interchangeably for either score or MIDI input, and to make it easier to adapt instruments originally written for score input to work with MIDI input.

In general, it should be possible to write instrument definitions that work identically with both scores and MIDI, including both MIDI files and real-time MIDI input, without using any conditional statements, and that take full advantage of MIDI voice messages.

Note that correlating Csound instruments with MIDI channel numbers is done using the massign opcode for real-time performance,. For file-driven performance, instrument numbers default to MIDI channel number + 1, but the defaults are overridden by any MIDI program change messages in the file.

## Syntax

    midicontrolchange xcontroller, xcontrollervalue [, ilow] [, ihigh]

## Initialization

ilow (optional) -- optional low value after rescaling, defaults to 0.

ihigh (optional) -- optional high value after rescaling, defaults to 127.

## Performance

xcontroller -- specifies the MIDI controller number (0-127) to read from.

xcontrollervalue -- returns the value of the MIDI controller during MIDI activation, remains unchanged otherwise.

If the instrument was activated by MIDI input, the opcode overwrites the value of xcontrollervalue with the corresponding value from the MIDI data of the specified xcontroller. If the instrument was NOT activated by MIDI input, the value remains unchanged.

This enables score p-fields to receive MIDI input data during MIDI activation, and score values otherwise.

| Adapting a score-activated Csound instrument.
See the MIDI interop opcodes section for details on adapting score driven instruments for MIDI or vice-versa.

## Examples

Here is an example of the midicontrolchange opcode. It uses the file midicontrolchange.csd

Example 598. Example of the midicontrolchange opcode.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac  -+rtmidi=virtual   -M0  ;;;realtime audio out and midi in
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o midicontrolchange.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1
    ; use slider of contr. 7 of virtual keyboard
    kcont init 1	; max. volume
    midicontrolchange 7, kcont, 0, 1; use controller 7, scaled between 0 and 1
    printk2 kcont	; Display the key value when it changes and key is pressed

    kenv madsr 0.5, 0.8, 0.8, 0.5		; envelope multiplied by
    asig pluck kenv*kcont, 220, 220, 2, 1	; value of controller 7
         outs  asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f 0 30
    f 2 0 4096 10 1

    i 1 10 2	; play a note from score as well
    e

    </CsScore>
    </CsoundSynthesizer>

## See also

MIDI/Score Interoperability

## Credits

Author: Michael Gogins

New in version 4.20

Thanks goes to Rasmus Ekman for pointing out the correct MIDI channel and controller number ranges.

Prev | Up | Next
midichn | Home | midictrl