*
Prev | Orchestra Opcodes and Operators | Next

## *

* — Multiplication operator.

## Description

Arithmetic operators perform operations of change-sign (negate), don't-change-sign, logical AND logical OR, add, subtract, multiply and divide. Note that a value or an expression may fall between two of these operators, either of which could take it as its left or right argument, as in

a + b * c.

In such cases three rules apply:

1. * and / bind to their neighbors more strongly than + and −. Thus the above expression is taken as

a + (b * c)

with * taking b and c and then + taking a and b * c.

2. + and − bind more strongly than &&, which in turn is stronger than ||:

a && b - c || d

is taken as

(a && (b - c)) || d

3. When both operators bind equally strongly, the operations are done left to right:

a - b - c

is taken as

(a - b) - c

Parentheses may be used as above to force particular groupings.

## Syntax

    a *  b  (no rate restriction)

where the arguments a and b may be further expressions.

## Arguments

The arguments of * can be scalar values or k-rate one dimensional arrays (vectors), or any combination. If one of the arguments is an array, so is the value.

## Examples

Here is an example of the * operator. It uses the file multiplies.csd.

Example 23. Example of the * operator.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o multiplies.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kenv    expon 0.01, p3, 1
    aout    poscil	0.8*kenv, 440, 1	;multiply amplitude from 0 to 1 * 0.8
    printks "base amplitude * rising expon output = 0.8 * %f\n", .1, kenv
    	outs 	aout, aout
    endin

    </CsInstruments>
    <CsScore>

    f 1 0 16384 10 1	; sine wave

    i 1 0 2

    e

    </CsScore>
    </CsoundSynthesizer>

Its output should include a line like this:

    base amplitude * rising expon output = 0.8 * 0.010000
    base amplitude * rising expon output = 0.8 * 0.012589
    ..........
    base amplitude * rising expon output = 0.8 * 0.794328
    base amplitude * rising expon output = 0.8 * 0.998466

## See also

Arithmetic and Logic Operations

## Credits

Arithmetic on vectors is new in version 6.00

Prev | Up | Next
<= | Home | +