q Statement
Prev | Score Statements and GEN Routines | Next

## q Statement

q statement — This statement may be used to quiet an instrument.

## Description

This statement may be used to quiet an instrument.

## Syntax

    q p1  p2  p3

## Performance

p1 -- Instrument number to mute/unmute.

p2 -- Action time in beats.

p3 -- determines whether the instrument is muted/unmuted. The value of 0 means the instrument is muted, other values mean it is unmuted.

Note that this does not affect instruments that are already running at time p2. It blocks any attempt to start one afterwards.

## Examples

Here is an example of the q statement. It uses the file q.csd.

Example 1271. Example of the q statement.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o q.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    aenv expseg .01, p3*0.25, 1, p3*0.75, 0.01
    asig poscil3 .8*aenv, p4, 1
         outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    f 1 0 16384 10 1;sine wave
    s
    q 1 6 0		;mute at 6 seconds in this section
    i 1 0 2 110
    i 1 3 2 220
    i 1 6 2 440
    i 1 9 2 880

    s
    q 1 6 1		;unmute again at 6 seconds in this section
    i 1 0 2 110
    i 1 3 2 220
    i 1 6 2 440
    i 1 9 2 880
    e
    </CsScore>
    </CsoundSynthesizer>

## See Also

Score Statements

Prev | Up | Next
n Statement | Home | r Statement (Repeat Statement)