STKBeeThree
Prev | Orchestra Opcodes and Operators | Next

## STKBeeThree

STKBeeThree — STK Hammond-oid organ-like FM synthesis instrument.

## Description

Plugin opcode in stkopd. This opcode is part of the plugin repository and has to be installed separately. The plugin repository can be found here: https://github.com/csound/plugins

STK Hammond-oid organ-like FM synthesis instrument.

This opcode a simple 4 operator topology, also referred to as algorithm 8 of the TX81Z. It simulates the sound of a Hammond-oid organ, and some related sounds.

## Syntax

    asignal STKBeeThree ifrequency, iamplitude, [kop4, kv1[, kop3, kv2[, klfo, kv3[, klfodepth, kv4[, kadsr, kv5]]]]]

## Initialization

ifrequency -- Frequency of note played, in Hertz.

iamplitude -- Amplitude of note played (range 0-1).

## Performance

kop4 -- controller 2, gain of feedback of operator 4. Value range of kv1 is 0-127.

kop3 -- controller 4, gain of operator 3. Value range of kv2 is 0-127.

klfo -- controller 11, speed of low-frequency oscillator. Value range of kv3 is 0-127.

klfodepth -- controller 1, depth of low-frequency oscillator. Value range of kv4 is 0-127.

kadsr -- controller 128, ADSR 2 and 4 target. Value range of kv5 is 0-127.

| Notes

The code for this opcode is taken directly from the BeeThree class in the Synthesis Toolkit in C++ by Perry R. Cook and Gary P. Scavone. More on the STK classes can be found here: https://ccrma.stanford.edu/software/stk/classes.html

kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Up to 8 optional k-rate controller pairs for the STK opcodes. Each controller pair consists of a controller number (kc) followed by a controller value (kv). Both the controller numbers and the controller values are krate variables. However, during a performance, normally the controller numbers stay fixed while the corresponding controller values may change at any time. The order of the controller pair is arbitrary, as long as they are after iamplitude. Also, it is not needed that all controller pairs are used.

## Examples

Here is an example of the STKBeeThree opcode. It uses the file STKBeeThree.csd.

Example 1014. Example of the STKBeeThree opcode.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o STKBeeThree.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kv1	=	p6					;feedback of operator 4
    kv2	line	p4, p3, p5				;gain of operator 3
    kv5	line	0, p3, 100
    ipch	=	p7

    asig	STKBeeThree	cpspch(ipch), 1, 2, kv1, 4, kv2, 11, 50, 1, 0, 128, kv5
    	outs	asig, asig
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 2 20 100 127 8.00
    i 1 + 8 120 0 0 6.09
    e
    </CsScore>
    </CsoundSynthesizer>

## See also

STK Opcodes

## Credits

Author: Michael Gogins (after Perry Cook)
Irreducible Productions
New York, NY

New in Csound version 5.11

Prev | Up | Next
STKBandedWG | Home | STKBlowBotl