sfilist
Prev | Orchestra Opcodes and Operators | Next

## sfilist

sfilist — Prints a list of all instruments of a previously loaded SoundFont2 (SF2) file.

## Description

Prints a list of all instruments of a previously loaded SoundFont2 (SF2) sample file. These opcodes allow management the sample-structure of SF2 files. In order to understand the usage of these opcodes, the user must have some knowledge of the SF2 format, so a brief description of this format can be found in the SoundFont2 File Format section.

## Syntax

    sfilist ifilhandle [, Sprintprefix]

## Initialization

ifilhandle -- unique number generated by sfload opcode to be used as an identifier for a SF2 file. Several SF2 files can be loaded and activated at the same time.

Sprintprefix -- A string prefix to prepend to each instrument row printed

## Performance

sfilist prints a list of all instruments of a previously loaded SF2 file to the console.

These opcodes only support the sample structure of SF2 files. The modulator structure of the SoundFont2 format is not supported in Csound. Any modulation or processing to the sample data is left to the Csound user, bypassing all restrictions forced by the SF2 standard.

## Examples

Here is an example of the sfilist opcode. It uses the file sfilist.csd.

Example 963. Example of the sfilist opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac    ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o sfilist.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; By  Menno Knevel - 2020

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    gisf	sfload	"sf_GMbank.sf2"
    	sfilist	gisf						;lists all instruments of Soundfont

    instr 1

    inum	=	p4
    ivel	=	p5
    kamp	linsegr	1, 1, 1, .1, 0
    kamp	= kamp/250000						;scale amplitude, small value due to 0dbfs = 1
    kfreq	=	1						;do not change freq from sf
    a1, a2	sfinstr3 ivel, inum, kamp*ivel, kfreq, p6, gisf        ;p6 chooses instrument, make amp velocity dependent
    	outs	a1, a2

    endin

    </CsInstruments>
    <CsScore>

    i1 0 1 60 127 100       ;Halo Pad
    i1 + 1 62 <     .
    i1 + 1 65 <     .
    i1 + 1 69 10    .

    i1 5 1 60 127 1         ;Piano 2
    i1 + 1 62 <     .
    i1 + 1 65 <     .
    i1 + 1 69 10    .

    e
    </CsScore>
    </CsoundSynthesizer>

Its output should include lines like this:

    Instrument list of "sf_GMbank.sf2"
      0) Piano 1
      1) Piano 2
      2) CP 70
      3) EP 1 layer 1
      4) EP 1 layer 2
      5) E.Piano 2
      6) Harpsichord
      .......
      100) Halo Pad
      .......

## See also

Soundfonts

More information on soundfonts is in the Floss Manuals: https://flossmanual.csound.com/midi/reading-midi-files

For other information on soundfonts look in the Wikipedia: http://en.wikipedia.org/wiki/Soundfont

## Credits

Author: Gabriel Maldonado
Italy
May 2000

New in Csound Version 4.07

Prev | Up | Next
setscorepos | Home | sfinstr3