	PLEASE NOTE: A simple Gopher client program.
	Requires the system call and INTERNET (INTERcal NETworking)
	extensions: the suffix ".rsi" asks for them.

	Run with:

	    sick -lRun gopher-get.rsi

	or compile and run with:

	    sick -lObject gopher-get.rsi
	    ./gopher-get.io

	then type the server:port on the first line (max 1024 characters)
	and type the path within the server on the second line (max 1024)
	then wait for the result.

	For example:

	    ./gopher-get.io
	    gopher.floodgap.com:70
	    /gopher

	NO USER SERVICEABLE PARTS BEYOND THIS POINT.

	PLEASE NOTE: READING SERVER:PORT
	DO ,1 <- #1024
	DO WRITE IN ,1

	PLEASE NOTE: READING PATH
	DO ,2 <- #1024
	DO WRITE IN ,2

	PLEASE NOTE: OPENING CONNECTION (OR SPLAT)
	DO :1 <- #117
(666)	DO .1 <- #6

	PLEASE NOTE: SENDING REQUEST
	PLEASE DO ,3 <- #4
	DO ,3 SUB #1 <- #91
	DO ,3 SUB #2 <- #95
	DO ,3 SUB #3 <- #72
	DO ,3 SUB #4 <- #66
(666)	DO .1 <- #7
	DO READ OUT @1 + ,2 + ,3

	PLEASE NOTE: GETTING RESULT AND PRINTING IT
	PLEASE DO ;1 <- #1024
	PLEASE DO .1 <- #0
	DO COME FROM .1
	DO WRITE IN @1 + ;1
	DO READ OUT @2 + ;1
(1)	DO .1 <- ';1 SUB #1 ~ ;1 SUB #1' ~ #1
	PLEASE GIVE UP

