Finding Objects
Prev | Chapter 2. CommonSQL Tutorial | Next

## Finding Objects

Now that we have our objects in the database, how do we get them out when we need to work with them? CLSQL provides a functional interface to SQL, which consists of a special Lisp reader macro and some functions. The special syntax allows us to embed SQL in lisp expressions, and lisp expressions in SQL, with ease.

Once we have turned on the syntax with the expression:

    (clsql:locally-enable-sql-reader-syntax)

We can start entering fragments of SQL into our lisp reader. We will get back objects which represent the lisp expressions. These objects will later be compiled into SQL expressions that are optimized for the database backed we are connected to. This means that we have a database independent SQL syntax. Here are some examples:

    ;; an attribute or table name
    [foo] => #<CLSQL-SYS::SQL-IDENT-ATTRIBUTE FOO>

    ;; a attribute identifier with table qualifier
    [foo bar] => #<CLSQL-SYS::SQL-IDENT-ATTRIBUTE FOO.BAR>

    ;; a attribute identifier with table qualifier
    [= "Lenin" [first_name]] =>
       #<CLSQL-SYS::SQL-RELATIONAL-EXP ('Lenin' = FIRST_NAME)>

    [< [emplid] 3] =>
       #<CLSQL-SYS::SQL-RELATIONAL-EXP (EMPLID < 3)>

    [and [< [emplid] 2] [= [first_name] "Lenin"]] =>
       #<CLSQL-SYS::SQL-RELATIONAL-EXP ((EMPLID < 2) AND
                                         (FIRST_NAME = 'Lenin'))>

    ;; If we want to reference a slot in an object we can us the
    ;;  SLOT-VALUE sql extension
    [= [slot-value 'employee 'emplid] 1] =>
       #<CLSQL-SYS::SQL-RELATIONAL-EXP (EMPLOYEE.EMPLID = 1)>

    [= [slot-value 'employee 'emplid]
       [slot-value 'company 'presidentid]] =>
       #<CLSQL-SYS::SQL-RELATIONAL-EXP (EMPLOYEE.EMPLID = COMPANY.PRESIDENTID)>

The `SLOT-VALUE` operator is important because it let's us query objects in a way that is robust to any changes in the object->table mapping, like column name changes, or table name changes. So when you are querying objects, be sure to use the `SLOT-VALUE` SQL extension.

Since we can now formulate SQL relational expression which can be used as qualifiers, like we put after the WHERE keyword in SQL statements, we can start querying our objects. CLSQL provides a function SELECT which can return use complete objects from the database which conform to a qualifier, can be sorted, and various other SQL operations.

The first argument to SELECT is a class name. it also has a set of keyword arguments which are covered in the documentation. For now we will concern ourselves only with the :where keyword. Select returns a list of objects, or nil if it can't find any. It's important to remember that it always returns a list, so even if you are expecting only one result, you should remember to extract it from the list you get from SELECT.

    ;; all employees
    (clsql:select 'employee)
    ;; all companies
    (clsql:select 'company)

    ;; employees named Lenin
    (clsql:select 'employee :where [= [slot-value 'employee 'last-name]
    				"Lenin"])

    (clsql:select 'company :where [= [slot-value 'company 'name]
    			       "Widgets Inc."])

    ;; Employees of Widget's Inc.
    (clsql:select 'employee
    	    :where [and [= [slot-value 'employee 'companyid]
    			   [slot-value 'company 'companyid]]
    			[= [slot-value 'company 'name]
    			   "Widgets Inc."]])

    ;; Same thing, except that we are using the employee
    ;; relation in the company view class to do the join for us,
    ;; saving us the work of writing out the SQL!
    (company-employees company1)

    ;; President of Widgets Inc.
    (president company1)

    ;; Manager of Josef Stalin
    (employee-manager employee2)

Prev | Up | Next
Object Creation | Home | Deleting Objects