Содержимое

# СУММЕСЛИМН

Возвращает сумму значений ячеек в диапазоне, который удовлетворяет нескольким условиям в нескольких диапазонах.

Эта функция доступна начиная с LibreOffice 4.0.

### Синтаксис

СУММЕСЛИМН(Диапазон функции; Диапазон 1; Условие 1[; Диапазон 2; Условие 2][; … ; [Диапазон 127; Условие 127]])

Диапазон функции – обязательный аргумент. Диапазон ячеек, имя именованного диапазона, либо заголовок столбца или строки, содержащих значения для вычисления суммы.

Диапазон 1 — необходимый аргумент. Представляет собой диапазон ячеек, имя именованного диапазона, либо название столбца или строки, к которому применяется соответствующее условие.

Условие 1: Условие является текстовым выражением, вычисляемым из Ссылки на одну ячейку, из Формулы, Числа или Текста. Используется в сравнениях с содержимым ячейки.

Ссылка на пустую ячейку интерпретируется как числовое значение 0.

Совпадающим выражением может быть:

- Число или логическое значение. Содержимое совпадающей ячейки равняется числу или логическому значению.

- Значение, начинающееся с оператора сравнения (<, <=, =, >, >=, <>).

  Для =, пустое значение совпадает с пустыми ячейками.

  Для <>, пустое значение совпадает с непустыми ячейками.

  Для <>, непустое значение совпадает с любым содержимым ячейки, за исключением указанного значения, включая пустые ячейки.

  Примечание: «=0» не совпадает с пустыми ячейками.

  Для = и <>, если значение непустое и не может быть интерпретировано в качестве числового типа или одного из его подтипов, а также включено свойство Условия поиска= и <> должны распространяться на всю ячейку, то сравнение выполняется со всем содержимым ячейки, если же свойство отключено, то сравнение выполняется с любой подчастью поля, совпадающей с условиями. Для = и <> значение применяется, если оно непустое и не может быть интерпретировано как числовой тип или один из его подтипов.

- Другое текстовое значение. Если включено свойство Условия поиска= и <> должны распространяться на всю ячейку, то сравнение выполняется со всем содержимым ячейки. Если же свойство отключено, то сравнение выполняется с любой подчастью поля, совпадающей с условиями. Выражение может содержать текст, числа, регулярные выражения или подстановочные знаки (если включено в параметрах вычисления).

Диапазон 2 — Необязательный параметр. Диапазон 2 и все последующие поля имеет то же значение, что и Диапазон 1.

Условие 2 — Необязательный параметр. Условие 2 и все последующие поля имеет то же значение, что и Условие.

Поиск поддерживает подстановочные знаки и регулярные выражения. При включении регулярных выражений можно ввести, например, «all.*» для поиска первого вхождения «all», за которым следуют любые символы. Если необходимо выполнить поиск текста, который сам является регулярным выражением, то перед каждым метасимволом или оператором регулярного выражения нужно вставлять символ «\», либо заключать текст в \Q...\E. Включить или выключить автоматическое применение подстановочных знаков или регулярных выражений можно в LibreOffice - Параметры Сервис - Параметры - LibreOffice Calc - Вычисления.

При использовании функций, один или несколько аргументов которых являются строками поиска с регулярными выражениями, сначала выполняется попытка преобразовать строку поиска в число. Например, «.0» будет преобразовано в число 0.0 и так далее. В случае удачного поиска, сопоставление будет производиться не по регулярному выражению, а по числовому совпадению. Однако при переключении на локаль, в которой точка не является десятичным разделителем, преобразование в регулярное выражение начинает работать. Для принудительного использования регулярного выражения вместо числового, используйте выражения, которые нельзя ошибочно принять за число, например «.[0]», «.0» или «(?i).0».

Диапазон функции и Диапазон 1, Диапазон 2... должны иметь одинаковый размер, в противном случае функция возвращает ошибку:502 - Недопустимый аргумент.

Логическое отношение между условиями может определяться в виде логической функции И (объединение). Другими словами, если и только если все заданные условия соблюдаются, значение из соответствующей ячейки заданного Диапазона функции будет включено в вычисление.

Функция может иметь до 255 аргументов, что позволяет указать до 127 диапазонов критериев и критериев для них.

Если ячейка содержит значение ИСТИНА, то она обрабатывается как 1, если же ячейка содержит значение ЛОЖЬ, то обрабатывается как 0 (нуль).

### Примеры

Рассмотрите следующую таблицу

| A | B | C
1 | Имя товара | Sales | Revenue
2 | карандаш | 20 | 65
3 | ручка | 35 | 85
4 | тетрадь | 20 | 190
5 | книга | 17 | 180
6 | пенал | нет | нет

Во всех примерах внизу диапазоны вычисления содержат строку №6, которая игнорируется, поскольку содержит текст.

#### Простое использование

=СУММЕСЛИМН(B2:B6; B2:B6; ">=20")

Вычисляет сумму значений диапазона B2:B6, которые больше или равны 20. Возвращает 75, потому что пятая строка не удовлетворяет условию.

=СУММЕСЛИ(C2:C6; B2:B6; ">=20"; C2:C6; ">70")

Вычисляет сумму значений диапазона C2:C6, которые больше 70 и соответствуют ячейкам диапазона B2:B6 со значениями больше или равными 20. Возвращает 275, потому что вторая и пятая строки не удовлетворяют по крайней мере одному условию.

#### Использование регулярных выражений и вложенных функций

=СУММЕСЛИМН(C2:C6; B2:B6; ">"&МИН(B2:B6); B2:B6; "<"&МАКС(B2:B6))

Вычисляет сумму значений диапазона C2:C6, которые соответствуют всем значениям диапазона B2:B6, за исключением их минимальных и максимальных значений. Возвращает 255, потому что третья и пятая строки не удовлетворяют по крайней мере одному условию.

=СУММЕСЛИМН(C2:C6;A2:A6;"pen.*";B2:B6;"<"&МАКС(B2:B6))

Вычисляет сумму значений диапазона C2:C6, которые соответствуют всем ячейкам диапазона A2:A6, начиная с «pen», и всем ячейкам диапазона B2:B6, за исключением из максимума. Возвращает 65, потому что только вторая строка соответствует всем условиям.

#### Ссылка на ячейку с условием

Для более удобного изменения условия функции можно указать его в отдельной ячейке и использовать ссылку на него в качестве условия функции СУММЕСЛИМН. Например, функцию выше можно переписать следующим образом:

=СУММЕСЛИМН(C2:C6; A2:A6; E2&".*"; B2:B6; "<"&МАКС(B2:B6))

Если E2 = pen, то функция возвращает 65, потому что ссылка на ячейку заменяется на её содержимое.

#### Техническая информация

Эта функция является частью формата Open Document для офисных приложений (OpenDocument) v1.2. (ISO/IEC 26300:2-2015)

См. также

Страница wiki функции СУММЕСЛИМН.

СУММ, СУММЕСЛИ

СЧЁТЕСЛИМН, МИНЕСЛИ, МАКСЕСЛИ, СРЗНАЧЕСЛИМН, СУММЕСЛИМН

Список регулярных выражений

Пожалуйста, поддержите нас!