Содержимое

# Финансовые функции (часть первая)

В эту категорию входят математические функции LibreOffice Calc для финансовых вычислений.

## PV

Возвращает текущую стоимость инвестиции после ряда платежей.

Эта функция служит для расчёта суммы, необходимой для инвестиций с фиксированным процентом для получения определённой суммы (годовой ренты) за указанное число периодов. Можно также определить, какая сумма будет оставаться после истечения периода. Кроме того, необходимо указать время для выплаты суммы: в начале или в конце каждого периода.

Введите значения в виде чисел, выражений или ссылок. Например, если ежегодный процент составляет 8%, но в качестве периода требуется указать месяц, введите 8%/12 в поле Процент и LibreOffice Calc автоматически рассчитает правильное значение.

#### Синтаксис

ПС(Ставка; КПЕР; Платёж [;Остаток [;Тип]])

Процент: процентная ставка за каждый период.

КПер: общее число периодов (платёжный период).

Выплата: регулярная выплата за период.

Будущее значение (необязательно): определяет будущее значение, оставшееся после итогового платежа.

Тип (необязательно): определяет дату исполнения для платежей. Тип = 1 означает, что срок исполнения находится в начале периода, а Тип = 0 (по умолчанию) означает, что срок исполнения находится в конце периода.

В функциях LibreOffice Calc параметры, отмеченные, как «необязательные» могут быть пропущены, только если нет параметров, идущих после. Например, в функции с четырьмя параметрами, в которой последние два параметра «необязательные», вы можете пропустить 4-й параметр или 3-й и 4-й, но нельзя пропустить только 3-й параметр.

#### Пример

Какова текущая стоимость инвестиций, если ежемесячные выплаты составляют 500 денежных единиц, а ежегодная процентная ставка - 8%? Платёжный период - 48 месяцев; в конце платёжного периода должно остаться 20000 денежных единиц.

=PV(8%/12;48;500;20000) = -35 019,37 денежных единиц. При описанных выше условиях на текущий момент необходимо вложить 35 019,37 денежных единиц, чтобы ежемесячные выплаты составляли 500 денежных единиц в течение 48 месяцев, а остаток на конец периода был равен 20 000 денежных единиц. Перекрёстная проверка показывает, что 48 x 500 денежных единиц + 20 000 денежных единиц = 44 000 денежных единиц. Разница между этой суммой и вложенной суммой, равной 35 000 денежных единиц, составляет выплаченные проценты.

Если вместо значений в формулу ввести ссылки, можно рассчитать любое число сценариев типа «если-то». Обратите внимание, что ссылки на константы должны быть определены как абсолютные ссылки. Примеры такого применения функции можно найти в описании функций амортизации.

## АМОРУВ

Служит для расчёта величины линейной амортизации за платёжный период. Если имущество приобретено в течение платёжного периода, используется пропорционально распределенная амортизация.

#### Синтаксис

АМОРУВ(Стоимость; Дата; Первый период; Остаточная стоимость; Период; Ставка [;Базис])

Стоимость: первоначальная стоимость.

Дата: дата приобретения.

Первый период: дата окончания первого платёжного периода.

Ликвидационная стоимость: ликвидационная стоимость имущества в конце периода амортизации.

Период: рассматриваемый платёжный период.

Процент: процентная ставка амортизации.

Базис (необязательный параметр): выбирается из списка вариантов и указывает метод вычисления года.

Базис | Вычисление
--- | ---
0 или отсутствие | Американский метод (NASD): 12 месяцев по 30 дней в каждом
1 | Точное число дней в месяцах, точное число дней в году
2 | Точное число дней в месяцах, число дней в году принимается за 360
3 | Точное число дней в месяцах, число дней в году принимается за 365
4 | Европейский метод: 12 месяцев по 30 дней в каждом

#### Пример

Имущество было приобретено 2020-02-01 по цене 2000 денежных единиц. Дата окончания первого платёжного периода — 2020-12-31. Ликвидационная стоимость имущества в конце периода его амортизации составит 10 денежных единиц. Процентная ставка амортизации составляет 0,1 (10%), а год вычисляется с применением американского метода (основание 0). Какова будет величина амортизации в четвёртом периоде амортизации, с учётом линейной амортизации?

=АМОРУВ(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0.1; 0) возвращает величину амортизации размером 200 денежных единиц.

Имейте в виде, что базис 2 не поддерживается в Microsoft Excel. Поэтому использование базиса 2 при экспорте документов в формат XLSX приведёт к выводу ошибки при попытке открытия в Excel.

## АМОРУМ

Служит для расчёта величины дегрессивной амортизации за платёжный период. В отличие от АМОРУВ для этой функции используется коэффициент амортизации, не зависящий от периода амортизации.

#### Синтаксис

АМОРУМ(Стоимость; Дата; Первый период; Остаточная стоимость; Период; Ставка [;Базис])

Стоимость: первоначальная стоимость.

Дата: дата приобретения.

Первый период: дата окончания первого платёжного периода.

Ликвидационная стоимость: ликвидационная стоимость имущества в конце периода амортизации.

Период: рассматриваемый платёжный период.

Процент: процентная ставка амортизации.

Базис (необязательный параметр): выбирается из списка вариантов и указывает метод вычисления года.

Базис | Вычисление
--- | ---
0 или отсутствие | Американский метод (NASD): 12 месяцев по 30 дней в каждом
1 | Точное число дней в месяцах, точное число дней в году
2 | Точное число дней в месяцах, число дней в году принимается за 360
3 | Точное число дней в месяцах, число дней в году принимается за 365
4 | Европейский метод: 12 месяцев по 30 дней в каждом

#### Пример

Имущество было приобретено 2020-02-01 по цене 2000 денежных единиц. Дата окончания первого платёжного периода — 2020-12-31. Ликвидационная стоимость имущества в конце периода его амортизации составит 10 денежных единиц. Процентная ставка амортизации составляет 0,1 (10%), а год был вычисляется с применением американского метода (основание 0). Какова будет величина амортизации в четвёртом периоде амортизации, с учётом дегрессивной амортизации?

=АМОРУМ(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0.1; 0) возвращает величину амортизации размером 163 денежных единиц.

Имейте в виде, что базис 2 не поддерживается в Microsoft Excel. Поэтому использование базиса 2 при экспорте документов в формат XLSX приведёт к выводу ошибки при попытке открытия в Excel.

## АСЧ

Возвращает процент амортизации, рассчитанной методом «суммы чисел».

Эта функция позволяет рассчитывать величину амортизации для одного периода полной амортизации объекта. При амортизации методом «суммы чисел» величина амортизации уменьшается на фиксированную сумму каждый период.

#### Синтаксис

АСЧ(Стоимость; Ликвидационная стоимость; Время эксплуатации; Период)

Стоимость: начальная стоимость актива.

Ликвидационная стоимость: представляет собой стоимость актива после амортизации.

Время эксплуатации: период, в течение которого стоимость актива амортизируется.

Период: период, для которого рассчитывается амортизация.

#### Пример

Видеосистема, начальная стоимость которой составляет 50000 денежных единиц, амортизируется ежегодно в течение 5 лет. Ликвидационная стоимость будет равна 10000 денежных единиц. Требуется рассчитать амортизацию за первый год.

=АСЧ(50000; 10000; 5; 1)=13 333,33 денежных единиц. Величина амортизации за первый год – 13 333,33 денежных единиц.

Чтобы получить общее представление о процентных ставках амортизации за период, необходимо определить таблицу амортизации. Вводя различные формулы расчёта амортизации, доступные в Calc LibreOffice, можно выбрать наиболее подходящий метод амортизации. Введите значения в таблицу.

| А | В | C | D | E
1 | Начальная стоимость | Ликвидационная стоимость | Срок использования | Период | Аморт. АСЧ
2 | 50 000 денежных единиц | 10 000 денежных единиц | 5 | 1 | 13 333,33 денежных единиц
3 |  |  |  | 2 | 10666,67 денежных единиц
4 |  |  |  | 3 | 8 000,00 денежных единиц
5 |  |  |  | 4 | 5 333,33 денежных единиц
6 |  |  |  | 5 | 2 666,67 денежных единиц
7 |  |  |  | 6 | 0,00 денежных единиц
8 |  |  |  | 7 |
9 |  |  |  | 8 |
10 |  |  |  | 9 |
11 |  |  |  | 10 |
12 |  |  |  |  |
13 | >0 |  |  | Итого | 40 000,00 денежных единиц

Формула в ячейке E2:

=АСЧ($A$2; $B$2; $C$2; D2)

Эта формула копируется во все ячейки столбца E до ячейки E11 (выделите ячейку E2 и потяните за правый нижний угол, удерживая левую клавишу мыши).

Ячейка E13 содержит формулу для проверки общей величины амортизации. Для этого используется функция СУММЕСЛИ, т. к. отрицательные значения ячеек E8:E11 не должны учитываться. Условие >0 содержится в ячейке A13. Формула в ячейке E13:

=СУММЕСЛИ(E2:E11; A13)

После этого можно рассчитать амортизацию за 10-летний период, при ликвидационной стоимости в 1 денежную единицу или при другой начальной стоимости и так далее.

## ВСД

Служит для расчёта внутренней нормы прибыли для инвестиций. Полученные значения описывают денежный поток через равные временные интервалы. Хотя бы одно значение должно быть отрицательным (выплаты) и хотя бы одно — положительным (доход).

Если выплаты происходят нерегулярно, используйте функцию ЧИСТВНДОХ.

#### Синтаксис

ВСД(Значения [;Предположение])

Значения: массив, содержащий значения.

Предположение (необязательно): оценочная стоимость. Для вычисления внутреннего дохода используется циклический метод. Если предоставляется небольшое количество значений, то следует предоставить начальную оценочную стоимость для начала цикла.

Эта функция игнорирует любые текстовые или пустые ячейки в диапазоне данных. Если результаты вычисления этой функции покажутся неверными, обратите внимание на наличие текста в диапазоне данных. Для подсветки текстового содержимого в диапазоне данных используйте функцию выделение значения цветом.

#### Пример

Если ячейка содержит значение A1=-10000, A2=3500, A3=7600 и A4=1000, используется формула =ВСД(A1:A4), результат равен 11,33%.

В связи с использованием итеративного метода при выполнении ВСД может произойти сбой, при котором возвращается Ошибка 523 с выводом сообщения «Ошибка: вычисления не сходятся» в строке состояния. В этом случае нужно использовать другое значение для аргумента Предположение.

## ДДОБ

Возвращает снижение стоимости актива для определённого периода по методу «суммы чисел».

Такой метод снижения стоимости можно применять, если начальное значение обесценивания должно быть выше, чем при линейной амортизации. Значение амортизации уменьшается с каждым периодом и обычно используется для активов, для которых оно повышается после приобретения (например, для автомобилей или компьютеров). Обратите внимание, что балансовая стоимость никогда не достигает нуля при таком методе расчёта.

#### Синтаксис

ДДОБ(Стоимость; Ликвидационная стоимость; Время эксплуатации; Период [;Коэффициент])

Стоимость: начальная стоимость актива.

Ликвидационная стоимость: фиксирует стоимость актива в конце срока службы.

Срок службы: количество периодов, на протяжении которых используется актив (например, годы или месяцы).

Период: период, для которого рассчитывается значение.

Коэффициент (необязательно): коэффициент амортизации. Если значение не введено, то по умолчанию используется коэффициент 2.

#### Пример

Стоимость компьютера, начальная цена которого составляла 75 000 денежных единиц, будет снижаться ежемесячно в течение 5 лет. На конец периода амортизации стоимость составит 1 денежную единицу. Коэффициент равен 2.

=ДДОБ(75000; 1; 60; 12; 2) = 1721,81 денежных единиц. Таким образом, результатом вычисления амортизации методом двойного уменьшающегося остатка на двенадцатый месяц после приобретения будет 1721,81 денежных единиц.

## ДЛИТ

Служит для расчёта срока до погашения ценных бумаг с фиксированным процентом в годах.

#### Синтаксис

ДЛИТ(Соглашение; Погашение; Купон; Доход; Частота [;Базис])

Расчёт: дата приобретения ценных бумаг.

Погашение: дата наступления срока погашения.

Купон: ежегодный уровень купонной ставки (номинальной ставки).

Доход: ежегодный доход от ценных бумаг.

Частота: количество выплат доходов по процентам в год (1, 2 или 4).

Базис (необязательный параметр): выбирается из списка вариантов и указывает метод вычисления года.

Базис | Вычисление
--- | ---
0 или отсутствие | Американский метод (NASD): 12 месяцев по 30 дней в каждом
1 | Точное число дней в месяцах, точное число дней в году
2 | Точное число дней в месяцах, число дней в году принимается за 360
3 | Точное число дней в месяцах, число дней в году принимается за 365
4 | Европейский метод: 12 месяцев по 30 дней в каждом

#### Пример

Ценные бумаги приобретены 01.01.01; срок погашения – 01.01.06. Купонная ставка составляет 8%. Доход составляет 9,0%. Проценты выплачиваются раз в полгода (частота 2). Требуется узнать срок до погашения на основе ежедневного начисления процентов (базис 3).

=ДЛИТ("01.01.2001"; "01.01.2006"; 0,08; 0,09; 2; 3) возвращает 4,2 года.

## НАКОПДОХОД

Служит для расчёта накопленного дохода для ценных бумаг в случае периодических платежей.

#### Синтаксис

НАКОПДОХОД(Выпуск; Первые проценты; Соглашение; Ставка; [Номинал]; Частота [;Базис])

Выпуск (обязательный параметр): дата выпуска ценных бумаг.

Первый процент (обязательный параметр): дата первых процентов по ценным бумагам.

Соглашение (обязательный параметр): дата расчёта накопленного дохода.

Процент (обязательный параметр): ежегодный уровень номинальной ставки (купонной ставки).

Номинал (необязательный): номинальная стоимость ценной бумаги. Если не указано, то по умолчанию используется значение 1000.

Мы рекомендуем всегда указывать значение, которое требуется для аргумента Номинал в функции НАКОПДОХОД вместо того, чтобы позволять Calc применять произвольное значение по умолчанию. Это упростит понимание вашей формулы и упростит обслуживание.

Частота (обязательный параметр): количество выплат доходов по процентам в год (1, 2 или 4).

Базис (необязательный параметр): выбирается из списка вариантов и указывает метод вычисления года.

Базис | Вычисление
--- | ---
0 или отсутствие | Американский метод (NASD): 12 месяцев по 30 дней в каждом
1 | Точное число дней в месяцах, точное число дней в году
2 | Точное число дней в месяцах, число дней в году принимается за 360
3 | Точное число дней в месяцах, число дней в году принимается за 365
4 | Европейский метод: 12 месяцев по 30 дней в каждом

#### Пример

Ценные бумаги приобретены 28.02.01. Дата начисления первых процентов – 31.08.2001. Дата выплаты процентов – 01.05.01. Процентная ставка равна 10% (0,1), а номинал составляет 1000 денежных единиц. Проценты выплачиваются раз в полгода (частота 2). Базис – американский способ (0). Сколько составит накопленный процент?

=НАКОПДОХОД("2001-02-28"; "2001-08-31"; "2001-05-01"; 0,1; 1000; 2; 0) возвращает значение 16,94444.

## НАКОПДОХОДПОГАШ

Служит для расчёта накопленного дохода для ценных бумаг в случае разового платежа на дату соглашения.

#### Синтаксис

НАКОПДОХОДПОГАШ(Выпуск; Соглашение; Ставка; [Номинал [; Базис]])

Выпуск (обязательный параметр): дата выпуска ценных бумаг.

Соглашение (обязательный параметр): дата расчёта накопленного дохода.

Процент (обязательный параметр): ежегодный уровень номинальной ставки (купонной ставки).

Номинал (необязательный): номинальная стоимость ценной бумаги. Если не указано, то по умолчанию используется значение 1000.

Мы рекомендуем всегда указывать значение, которое требуется для аргумента Номинал в функции НАКОПДОХОДПОГАШ вместо того, чтобы позволять Calc применять произвольное значение по умолчанию. Это упростит понимание вашей формулы и упростит обслуживание.

Базис (необязательный параметр): выбирается из списка вариантов и указывает метод вычисления года.

Базис | Вычисление
--- | ---
0 или отсутствие | Американский метод (NASD): 12 месяцев по 30 дней в каждом
1 | Точное число дней в месяцах, точное число дней в году
2 | Точное число дней в месяцах, число дней в году принимается за 360
3 | Точное число дней в месяцах, число дней в году принимается за 365
4 | Европейский метод: 12 месяцев по 30 дней в каждом

#### Пример

Дата выпуска ценной бумаги – 01.04.01. Дата погашения – 15.06.01. Процентная ставка равна 10% или 0,1, а номинал – 1000 денежных единиц. Базис для начисления суточных или годовых процентов – ежедневный остаток (3). Сколько составит накопленный процент?

=НАКОПДОХОДПОГАШ("2001-04-01"; "2001-06-15"; 0,1; 1000; 3) возвращает значение 20,54795.

## ПОЛУЧЕНО

Служит для расчёта полученной суммы, которая выплачивается по ценным бумагам с фиксированным процентом в определённый момент времени.

#### Синтаксис

ПОЛУЧЕНО(Соглашение; Погашение; Инвестиция; Дисконт [;Базис])

Расчёт: дата приобретения ценных бумаг.

Погашение: дата наступления срока погашения.

Инвестиция: сумма приобретения.

Скидка: процент скидки на приобретение ценных бумаг.

Базис (необязательный параметр): выбирается из списка вариантов и указывает метод вычисления года.

Базис | Вычисление
--- | ---
0 или отсутствие | Американский метод (NASD): 12 месяцев по 30 дней в каждом
1 | Точное число дней в месяцах, точное число дней в году
2 | Точное число дней в месяцах, число дней в году принимается за 360
3 | Точное число дней в месяцах, число дней в году принимается за 365
4 | Европейский метод: 12 месяцев по 30 дней в каждом

#### Пример

Дата соглашения: 15 февраля 1999, дата погашения: 15 мая 1999, сумма инвестиции: 1000 денежных единиц, скидка: 5,75 процентов, основание: ежедневный остаток/360 = 2.

Полученная сумма на дату погашения рассчитывается следующим образом:

=RECEIVED("1999-02-15"; "1999-05-15"; 1000; 0,0575; 2) возвращает значение 1014,420266.

## ПРОЦПЛАТ

Служит для расчёта процентов для фиксированных амортизационных отчислений.

#### Синтаксис

ПРОЦПЛАТ(Процент; Период; Всего периодов; Инвестиция)

Процент: периодическая процентная ставка.

Период: количество выплат для расчёта процента.

Всего периодов: общее число периодов выплат.

Инвестиция: объём инвестиций.

#### Пример

Для суммы кредита, равной 120 000 денежных единиц, с двухлетним сроком, ежемесячными выплатами и годовой процентной ставкой в 12% требуется рассчитать процент после 1,5 лет.

=ПРОЦПЛАТ(1%; 18; 24; 120000) = -300 денежных единиц. Ежемесячный процент после 1,5 лет составит 300 денежных единиц.

## СКИДКА

Служит для расчёта процента скидки на ценные бумаги.

#### Синтаксис

СКИДКА(Соглашение; Погашение; Цена; Выкуп [;Базис])

Расчёт: дата приобретения ценных бумаг.

Погашение: дата наступления срока погашения.

Стоимость: стоимость ценных бумаг на каждые 100 денежных единиц номинала.

Выкуп: выкупная стоимость ценных бумаг на каждые 100 денежных единиц номинала.

Базис (необязательный параметр): выбирается из списка вариантов и указывает метод вычисления года.

Базис | Вычисление
--- | ---
0 или отсутствие | Американский метод (NASD): 12 месяцев по 30 дней в каждом
1 | Точное число дней в месяцах, точное число дней в году
2 | Точное число дней в месяцах, число дней в году принимается за 360
3 | Точное число дней в месяцах, число дней в году принимается за 365
4 | Европейский метод: 12 месяцев по 30 дней в каждом

#### Пример

Ценные бумаги приобретены 25.01.01; дата погашения –15.11.01. Цена (приобретения) составляет 97, цена досрочного выкупа составляет 100 денежных единиц. Требуется узнать сумму расчёта на основе ежедневного начисления процентов (базис 3).

=DISC("2001-01-25"; "2001-11-15"; 97; 100; 3) возвращает значение 0,0372 или 3,72%.

## ФУО

Возвращает снижение стоимости актива для определённого периода по методу «суммы чисел».

Такой метод снижения стоимости можно использовать, если значение в начале амортизации должно быть выше, чем при линейной амортизации. Значение амортизации уменьшается с каждым периодом на величину, которая уже вычтена из начальной стоимости.

#### Синтаксис

ФУО(Стоимость; Ликв_стоим; Время_эксплуатации; Период [;Месяц])

Стоимость: начальная стоимость актива.

Ликвидационная стоимость: стоимость актива в конце амортизации.

Время эксплуатации: период, в течение которого стоимость актива снижается.

Период: длительность каждого периода. Для этого параметра следует использовать тот же формат даты, что и для периода амортизации.

Месяц (необязательно): количество месяцев для первого года амортизации. Если параметр не определен, то используется значение по умолчанию 12.

#### Пример

Стоимость компьютера, начальная цена которого составляла 25000 денежных единиц, будет снижаться в течение трёхлетнего периода. Ликвидационная стоимость должна составлять 1000 денежных единиц. Первый период амортизации составляет 6 месяцев. Какова будет амортизация компьютера по методу фиксированного уменьшающегося остатка во втором периоде, который составляет полный год, начиная с конца шестимесячного периода?

=ФУО(25000; 1000; 3; 2; 6) возвращает 11037,95 денежных единиц.

## ЭФФЕКТ

Возвращает годовой фактический процент для номинальной процентной ставки.

Номинальная процентная ставка - размер процентной ставки на конец расчётного периода. Фактическая процентная ставка повышается с количеством платежей. Другими словами, проценты часто выплачиваются в виде частичных платежей (например, ежемесячно или ежеквартально) до конца расчётного периода.

#### Синтаксис

ЭФФЕКТ(Ном_проц_ставка; П)

Номинальная процентная ставка: номинальная процентная ставка.

Периоды: количество периодов выплат в год.

#### Пример

Если ежегодный уровень номинальной процентной ставки равен 9,75% и определено четыре периода выплат, какова фактическая процентная ставка?

=ЭФФЕКТ(9,75%; 4) = 10,11%. Таким образом, годовая эффективная ставка составляет 10,11%.

## ЭФФЕКТ_ADD

Служит для расчёта ежегодного уровня фактической процентной ставки на основе номинальной процентной ставки и количества выплат в год.

Функции, имена которых заканчиваются на _ADD или _EXCEL2003, возвращают те же результаты, что и соответствующие функции Microsoft Excel 2003 без суффикса. Используйте функции без суффикса для получения результатов, основанных на международных стандартах.

#### Синтаксис

EFFECT_ADD(Номинальная процентная ставка; Периоды)

Номинальная процентная ставка: ежегодный уровень номинальной процентной ставки.

Периоды: количество выплат по ставкам в год.

#### Пример

Каков ежегодный уровень фактической процентной ставки при номинальной ставке в 5,25% и поквартальным выплатам?

=EFFECT_ADD(0,0525; 4) возвращает значение 0,053543 или 5,3543%.

Финансовые функции (часть вторая)

Финансовые функции (часть третья)

Функции по категориям