Содержимое

# Обозначение операций в формулах LibreOffice Calc

В формулах LibreOffice Calc можно использовать следующие операции.

## Арифметические операции

Эти операции возвращают числовые значения.

Операция | Название | Пример
--- | --- | ---
+ | Сложение | 1+1
- | Вычитание | 2-1
- | Унарный минус | -5
* | Умножение | 2*2
/ | Деление | 9/3
% | Процент | 15%
^ | Возведение в степень | 3^2

Prefix "-" (negation) has a higher precedence than "^" (exponentiation). For example -3^2 equals 9, which is the square of a negative number.

## Операции сравнения

Эти операции возвращают значение ИСТИНА или ЛОЖЬ.

Операция | Название | Пример
--- | --- | ---
= | Равно | A1=B1
> | Больше | A1>B1
< | Меньше | A1<B1
>= | Больше или равно | A1>=B1
<= | Меньше или равно | A1<=B1
<> | Не равно | A1<>B1

## Текстовые операции

Эта операция объединяет несколько текстовых строк в одну.

Операция | Имя | Пример
--- | --- | ---
& | text concatenation | Выражение "Воскре" & "сенье" эквивалентно строке "Воскресенье"

## Ссылочные операции

Эти операции возвращают диапазон из нуля, одной или более ячеек.

Операция диапазон имеет самый высокий приоритет, за ней следует пересечение, и, наконец, объединение.

Операция | Название | Пример
--- | --- | ---
: | Диапазон | A1:C108, A:D or 3:13
! | Пересечение диапазонов | SUM(A1:B6!B5:C12) Вычисляет сумму всех ячеек в пересечении; в данном примере результат равен сумме ячеек В5 и В6.

~

Конкатенация или объединение

Takes two references and returns a reference list, which is a concatenation of the left reference followed by the right reference. Double entries are referenced twice.

=COUNT(A1:B2~B2:C3) counts values of A1:B2 and B2:C3. Note that the cell B2 is counted twice.

=INDEX(A1:B2~C1:D2;2;1;2) selects cell C2, that is, the first cell of the second row, first column, of the second range (C1:D2) of the range list.

A reference list is not allowed inside an array expression.

## Operator precedence

Associativity and precedence of operators, from highest to lowest precedence.

Associativity | Operator(s) | Comments
--- | --- | ---
left | : | Range.
left | ! | Reference intersection (A1:C4!B1:B5 is B1:B4).
left | ~ | Reference union.
right | +,- | Prefix unary operators. For example, -5 or -A1. Note that these have a different precedence than add and subtract.
left | % | Postfix unary operator % (divide by 100). Note that this is legal with expressions, for example, B1%.
left | ^ | Power (2^3 is 8).
left | *,/ | Multiply, divide.
left | +,- | Binary operations add, subtract. Note that unary (prefix) + and - have a different precedence.
left | & | Binary operation string concatenation. Note that "&" shall be escaped when included in an XML document.
left | =, <>, <, <=, >, >= | Comparison operators equal to, not equal to, less than, less than or equal to, greater than, greater than or equal to.

Prefix "-" has a higher precedence than "^", "^" is left-associative, and reference intersection has a higher precedence than reference union.

Prefix "+" and "-" are defined to be right-associative. However, note that typical applications which implement at most the operators defined in this specification (as specified) may implement them as left-associative, because the calculated results will be identical.

Precedence can be overridden by using parentheses, so "=2+3*4" computes to 14 but "=(2+3)*4" computes 20.

См. также

OpenDocument v1.3 part 4, Formula Operators