Spis treści
Indeks 🔎︎

# COUNTIFS

Returns the count of cells that meet criteria in multiple ranges.

This function is available since LibreOffice 4.0.

#### Składnia

COUNTIFS(Range; Criterion[; Range2; Criterion2][; ... ; [Range127; Criterion127]])

Range1 – required argument. It is a range of cells, a name of a named range, or a label of a column or a row, to which the corresponding criterion is to be applied.

Criterion: A criterion is a single cell Reference, Number or Text. It is used in comparisons with cell contents.

A reference to an empty cell is interpreted as the numeric value 0.

A matching expression can be:

- A Number or Logical value. A matching cell content equals the Number or Logical value.

- A value beginning with a comparator (<, <=, =, >, >=, <>).

  For =, if the value is empty it matches empty cells.

  For <>, if the value is empty it matches non-empty cells.

  For <>, if the value is not empty it matches any cell content except the value, including empty cells.

  Note: "=0" does not match empty cells.

  For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes and the property Search criteria = and <> must apply to whole cells is checked, comparison is against the entire cell contents, if unchecked, comparison is against any subpart of the field that matches the criteria. For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes applies.

- Other Text value. If the property Search criteria = and <> must apply to whole cells is true, the comparison is against the entire cell contents, if false, comparison is against any subpart of the field that matches the criteria. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

Zakres2 – Opcjonalnie. Zakres2 i wszystkie następujące oznaczają to samo co Zakres1.

Criterion2 – Optional. Criterion2 and all the following mean the same as Criterion.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - Preferences Tools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

Range, Range2, ... and Criterion, Criterion2, ... must have the same size, otherwise the function returns err:502 - Invalid argument.

The logical relation between criteria can be defined as logical AND (conjunction). In other words, if and only if all given criteria are met, a value from the corresponding cell of the given Func_Range is taken into calculation.

Ta funkcja może mieć do 255 argumentów, co oznacza, że ​​można podać 127 zakresów kryteriów i kryteriów dla nich.

Jeśli komórka zawiera PRAWDA, jest traktowana jak 1. Jeśli zawiera FAŁSZ – jak 0 (zero).

Funkcja ta jest częścią standardu Open Document Format for Office Applications (OpenDocument) w wersji 1.2. (ISO/IEC 26300:2-2015)

#### Przykład

Poniżej opisano działanie tego pola na tabeli

| A | B | C
1 | Nazwa produktu | Sprzedaże | Przychód
2 | ołówek | 20 | 65
3 | ołów | 35 | 85
4 | notes | 20 | 190
5 | książka | 17 | 180
6 | piórnik | nie | nie

We wszystkich przykładach poniżej, zakresy dla sumy obliczeń zawierają wiersz #6, który jest ignorowany, ponieważ zawiera tekst.

#### Proste użycie

=LICZ.WARUNKI(B2:B6;">=20")

Oblicza ilość wierszy z zakresu B2:B6 z wartościami większymi niż lub równymi do 20. Zwraca 3, ponieważ piąty i szósty wiersz nie spełniają kryterium.

=LICZ.WARUNKI(B2:B6;">=20";C2:C6;">70")

Oblicza ilość wierszy zawierających jednocześnie wartości większe niż 70 w zakresie C2:C6 oraz wartości większe niż lub równe do 20 w zakresie B2:B6.Zwraca 2, ponieważ drugi, piąty i szósty wiersz nie nie spełniają co najmniej jednego kryterium.

#### Użycie wyrażeń regularnych i funkcji zagnieżdżonych

For these examples to work as described, make sure that Enable regular expressions in formulas is selected in LibreOffice - Preferences Tools - Options - LibreOffice Calc - Calculate.

=LICZ.WARUNKI(B2:B6;"[:alfa:]*")

Oblicza ilość wierszy z zakresu B2:B6, które zawierają wyłącznie symbole alfabetu. Zwraca 1, ponieważ tylko szósty wiersz spełnia kryterium.

=LICZ.WARUNKI(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAKS(B2:B6))

Oblicza ilość wierszy z zakresu B2:B6, wyłączając wiersze z minimalnymi i maksymalnymi wartościami tego zakresu. Zwraca 2, ponieważ trzeci, piąty i szósty wiersz nie spełniają co najmniej jednego kryterium.

=LICZ.WARUNKI(A2:A6;"ołów.*";B2:B6;"<"&MAKS(B2:B6))

Oblicza ilość wierszy, które odpowiadają wszystkim komórkom z zakresu A2:A6 zaczynającym się od słowa "ołów" i do wszystkich komórek z zakresu B2:B6, oprócz ich maksimum. Zwraca 1, ponieważ tylko drugi wiersz spełnia wszystkie kryteria.

#### Odwołanie do komórki jako kryterium

Jeśli chcesz łatwo zmienić kryterium, możesz określić je w osobnej komórce i użyć odwołań do tej komórki w warunku funkcji LICZ.WARUNKI. Na przykład: powyższa funkcja może być przepisana następująco:

=LICZ.WARUNKI(A2:A6;E2&".*";B2:B6;"<"&MAKS(B2:B6))

Jeśli E2 = ołów, funkcja zwraca 1, ponieważ łącze do komórki jest zastąpione jego treścią i działa jak funkcja powyżej.

Tematy pokrewne

ILE.LICZB, LICZ.JEŻELI, LICZ.PUSTE, ILE.NIEPUSTYCH

COUNTIFS, MIN.WARUNKÓW, MAKS.WARUNKÓW, ŚREDNIA.JEŻELI, SUMIFS

Lista wyrażeń regularnych