Spis treści

# SUMA.WARUNKÓW

Zwraca sumę wartości komórek w zakresie, który spełnia wielokrotność kryteriów w wielokrotności zakresów.

Ta funkcja jest dostępna od wersji 4.0 LibreOffice.

### Składnia

SUMA.WARUNKÓW(Zakres_funkcji; Zakres1; Kryterium1[; Zakres2; Kryterium2][; … ; [Zakres127; Kryterium127]])

Zakres_funkcji – wymagany argument. Jest to zakres komórek, nazwa zakresu lub etykieta kolumny lub wiersz zawierający wartości do obliczenia sumy.

Zakres1 – wymagany argument. Jest to zakres komórek, nazwa nazwanego zakresu lub etykieta kolumny lub wiersza, do którego ma zostać zastosowane odpowiednie kryterium.

Kryterium1: kryterium to wyrażenie tekstowe obliczone z pojedynczej komórki Odwołanie, Formuła, Liczba lub Tekst. Jest używane w porównaniach z zawartością komórki.

Odwołanie do pustej komórki jest interpretowane jako wartość liczbowa 0.

Pasującym wyrażeniem może być:

- Liczba lub wartość logiczna. Pasująca zawartość komórki jest równa liczbie lub wartości logicznej.

- Wartość rozpoczynająca się od komparatora (<, <=, =, >, >=, <>).

  W przypadku =, jeśli wartość jest pusta, dopasowuje puste komórki.

  W przypadku <>, jeśli wartość jest pusta, dopasowuje niepuste komórki.

  W przypadku <>, jeśli wartość nie jest pusta, dopasowuje dowolną zawartość komórki z wyjątkiem wartości, łącznie z pustymi komórkami.

  Uwaga: "=0" nie pasuje do pustych komórek.

  W przypadku = i <>, jeśli wartość nie jest pusta i nie może być interpretowana jako typ liczbowy lub jeden z jego podtypów oraz właściwość Kryteria wyszukiwania = i <> muszą się odnosić do całych komórek jest zaznaczona, porównanie dotyczy całej zawartości komórki, jeśli niezaznaczona, porównanie dotyczy dowolnej podczęści pola spełniającej kryteria. W przypadku = i <>, jeśli wartość nie jest pusta i nie może być interpretowana jako typ liczbowy lub jeden z jego podtypów.

- Inna wartość tekstowa. Jeśli właściwość Kryteria wyszukiwania = i <> muszą się odnosić do całych komórek jest prawdziwa, porównanie dotyczy całej zawartości komórki, jeśli fałszywe, porównanie dotyczy dowolnej podczęści pola spełniającej kryteria. Wyrażenie może zawierać tekst, liczby, wyrażenia regularne lub symbole wieloznaczne (jeśli włączono je w opcjach obliczeń).

Zakres2 – Opcjonalnie. Zakres2 i wszystkie następujące oznaczają to samo co Zakres1.

Kryterium2 – opcjonalne. Kryterium2 i wszystkie poniższe oznaczają to samo co Kryterium.

Wyszukiwanie obsługuje symbole wieloznaczne lub wyrażenia regularne. Przy włączonych wyrażeniach regularnych możesz wpisać „all.*”, na przykład, aby znaleźć pierwszą lokalizację „all”, po której następuje dowolny znak. Jeśli chcesz wyszukać tekst, który jest również wyrażeniem regularnym, musisz poprzedzić każdy metaznak lub operator wyrażenia regularnego znakiem „\” albo umieścić tekst w \Q...\E. Możesz włączać i wyłączać automatyczną ocenę symboli wieloznacznych lub wyrażeń regularnych w LibreOffice - Preferencje Narzędzia - Opcje - LibreOffice Calc - Oblicz.

W przypadku korzystania z funkcji, w których jeden lub więcej argumentów to ciągi kryteriów wyszukiwania reprezentujące wyrażenie regularne, pierwszą próbą jest przekonwertowanie kryteriów ciągu na liczby. Na przykład „.0” zostanie przekonwertowane na 0,0 i tak dalej. Jeśli się powiedzie, dopasowanie nie będzie dopasowaniem wyrażenia regularnego, ale dopasowaniem liczbowym. Jednak po przełączeniu na ustawienia regionalne, w których separatorem dziesiętnym nie jest kropka, konwersja wyrażeń regularnych działa. Aby wymusić ocenę wyrażenia regularnego zamiast wyrażenia liczbowego, użyj wyrażenia, którego nie można błędnie odczytać jako liczbowego, takiego jak „.[0]”, „.\0” lub „(?i).0”.

Zakres_funkcji oraz Zakres1, Zakres2... muszą mieć ten sam rozmiar, w przeciwnym razie funkcja zwróci Błąd:502 - nieprawidłowy argument.

Logiczną relację między kryteriami można zdefiniować jako logiczne I (koniunkcja). Innymi słowy, wtedy i tylko wtedy, gdy spełnione są wszystkie podane kryteria, do obliczeń brana jest wartość z odpowiedniej komórki danego Zakresu_funkcji.

Ta funkcja może mieć do 255 argumentów, co oznacza, że ​​można podać 127 zakresów kryteriów i kryteriów dla nich.

Jeśli komórka zawiera PRAWDA, jest traktowana jak 1. Jeśli zawiera FAŁSZ – jak 0 (zero).

### Przykłady

Poniżej opisano działanie tego pola na tabeli

| A | B | C
1 | Nazwa produktu | Sales | Revenue
2 | ołówek | 20 | 65
3 | ołów | 35 | 85
4 | fotoalbum | 20 | 190
5 | album | 17 | 180
6 | ołóweczek | nie | nie

We wszystkich przykładach poniżej, zakresy dla sumy obliczeń zawierają wiersz #6, który jest ignorowany, ponieważ zawiera tekst.

#### Proste użycie

=SUMA.WARUNKÓW(B2:B6;B2:B6;">=20")

Oblicza sumę wartości z zakresu B2:B6, które są większe niż lub równe do 20. Zwraca 75, ponieważ piąty wiersz nie spełnia kryterium.

=SUMA.WARUNKÓW(C2:C6;B2:B6;">=20";C2:C6;">70")

Oblicza sumę wartości z zakresu C2:C6, które są większe niż 70 i odpowiadają komórkom z zakresu B2:B6 z wartościami większymi niż lub równymi do 20. Zwraca 275, ponieważ drugi i piąty wiersz nie spełniają co najmniej jednego kryterium.

#### Użycie wyrażeń regularnych i funkcji zagnieżdżonych

=SUMA.WARUNKÓW(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAKS(B2:B6))

Oblicza sumę wartości z zakresu C2:C6, które odpowiadają wszystkim wartościom z zakresu B2:B6, oprócz jego minimum i maksimum. Zwraca 255, ponieważ trzeci i piąty wiersz nie spełniają co najmniej jednego kryterium.

=SUMA.WARUNKÓW(C2:C6;A2:A6;"ołów.*";B2:B6;"<"&MAKS(B2:B6))

Oblicza sumę wartości z zakresu C2:C6, które odpowiadają wszystkim komórkom z zakresu A2:A6 zaczynającym się od słowa "ołów" i do wszystkich komórek z zakresu B2:B6, oprócz ich maksimum. Zwraca 65, ponieważ tylko drugi wiersz spełnia wszystkie kryteria.

#### Odwołanie do komórki jako kryterium

Jeśli chcesz łatwo zmienić kryterium, możesz określić je w osobnej komórce i użyć odwołań do tej komórki w warunku funkcji SUMA.WARUNKÓW. Na przykład: powyższa funkcja może być przepisana następująco:

=SUMA.WARUNKÓW(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAKS(B2:B6))

Jeśli E2 = ołów, funkcja zwraca 65, ponieważ łącze do komórki jest zastąpione jego treścią.

#### Szczegóły techniczne

Funkcja ta jest częścią standardu Open Document Format for Office Applications (OpenDocument) w wersji 1.2. (ISO/IEC 26300:2-2015)

Tematy pokrewne

Strona wiki SUMA.WARUNKÓW.

SUMA, SUMA.JEŻELI

LICZ.WARUNKI, MIN.WARUNKÓW, MAKS.WARUNKÓW, ŚREDNIA.JEŻELI, SUMA.WARUNKÓW

Lista wyrażeń regularnych

Prosimy o wsparcie!