Inhoud
Index 🔎︎

# REGEX

Komt overeen en extraheert of vervangt optioneel tekst met behulp van reguliere expressies.

Deze functie is beschikbaar sinds LibreOffice 6.2.

#### Syntaxis

REGEX( Tekst ; Expressie [ ; [ Vervanging ] [ ; Vlaggen|Voorkomen ] ] )

Tekst: Een tekst of verwijzing naar een cel waar de reguliere expressie moet worden toegepast.

Expressie: Een tekst die de reguliere expressie vertegenwoordigt, met behulp van ICU reguliere expressies. Als er geen overeenkomst is en Vervanging wordt niet gegeven, wordt #N/A geretourneerd.

Vervanging: Optioneel. De vervangende tekst en verwijzingen naar vanggroepen. Als er geen overeenkomst is, wordt Tekst ongewijzigd terug gegeven.

Vlaggen: Optioneel. "g" vervangt alle overeenkomsten van Expressie in Tekst, niet geëxtraheerd. Als er geen overeenkomst is, wordt Tekst ongewijzigd terug gegeven.

Voorkomen: Optioneel. Getal om aan te geven welke overeenkomst van Expressie in Tekst moet worden geëxtraheerd of vervangen. Als er geen overeenkomst is en Vervanging niet wordt gegeven, wordt #NVT geretourneerd. Als er geen overeenkomst is en Vervanging wordt gegeven, wordt Tekst ongewijzigd geretourneerd. Als Voorkomen 0 is, wordt Tekst ongewijzigd geretourneerd.

#### Voorbeelden

=REGEX("123456ABCDEF";"[:digit:]";"Z") geeft "Z23456ABCDEF", waarbij de eerste overeenkomst van een cijfer werd vervangen door "Z".

=REGEX("123456ABCDEF";"[:digit:]";"Z";"g") geeft "ZZZZZZABCDEF", waarbij alle cijfers werden vervangen door "Z".

=REGEX("123456ABCDEF";"[126]";"";"g") geeft "345ABCDEF", waarbij elk voorkomen van "1", "2" of "6" is vervangen door een lege tekenreeks, dus verwijderd.

=REGEX("axbxcxd";".x";;2) geeft "bx", de tweede overeenkomst van ".x".

=REGEX("axbxcxd";"(.)x";"$1y";2) geeft "axbycxd", de tweede overeenkomst van "(.)x" (d.i. "bx") vervangen door de vastgelegde groep van één teken (d.i. "b") gevolgd door "y".

Verwante onderwerpen

Lijst met reguliere expressies

ICU reguliere expressies