Inhoud

# Logische functies

Deze categorie bevat de Logische functies.

### Niet-logische argumenten verwerken in logische functies

- Nul (0) is gelijk aan ONWAAR en alle andere getallen zijn gelijk aan WAAR.

- Lege cellen en tekst in cellen worden genegeerd.

- De fout #Waarde treedt op als alle argumenten worden genegeerd.

- De fout #Waarde treedt op als een argument een directe tekst is (geen tekst in een cel).

- Fouten in argumenten leiden tot een fout.

Om toegang te krijgen tot deze functie..

Invoegen - Functie - Categorie Logische

### ISNB

Geeft WAAR als een cel de foutwaarde #N/B (waarde niet beschikbaar) bevat.

De functie geeft ONWAAR terug indien er een fout optreedt.

#### Syntaxis

ISNB(Waarde)

Waarde is de waarde of expressie die getest moet worden.

#### Voorbeeld

=ISNB(D3) geeft ONWAAR als resultaat.

### ALS.FOUT

Retourneert de waarde als de cel geen foutwaarde bevat, of de alternatieve waarde als dit wel het geval is.

Deze functie is beschikbaar sinds LibreOffice 4.0.

#### Syntaxis

ALS.FOUT( Waarde; Alternatieve waarde)

Waarde is de waarde of uitdrukking die gegeven wordt als het niet gelijk is of resulteert in een fout.

Alternatieve_waarde is de waarde of uitdrukking die gegeven wordt als de expressie of waarde van Waarde gelijk is of een fout geeft.

#### Voorbeeld

=ALS.FOUT(C8;C9) als cel C8 =1/0 bevat, geeft de waarde C9, omdat 1/0 een fout is.

=ALS.FOUT(C8;C9) als cel C8 13 bevat, geeft 13 de waarde van C8, wat geen fout is.

## ALS.VOORWAARDEN

ALS.VOORWAARDEN is een meervoudige ALS-functie.

## SCHAKELEN

SCHAKELEN vergelijkt Uitdrukking met Waarde 1met waardes en retourneert het resultaat behorend bij de eerste waarde die gelijk is aan de uitdrukking. Als er geen overeenkomst is en een standaardresultaat is gegeven, wordt deze geretourneerd.

## ALS

Geeft een logische test op.

#### Syntaxis

ALS(Test; Waarde als waar (optioneel); Waarde als onwaar (optioneel))

Test is elke waarde of uitdrukking die WAAR of ONWAAR kan zijn.

Waarde als waar (optioneel) is de waarde die wordt teruggegeven als de logische test WAAR is.

Waarde als onwaar (optioneel) is de waarde die wordt teruggegeven als de logische test ONWAAR is.

In de functies van LibreOffice Calc kunnen "optionele" parameters alleen weggelaten worden wanneer er geen parameter volgt. In een functie met vier parameters waarvan de laatste twee als "optioneel" gemarkeerd zijn, kunt u bijvoorbeeld parameter 4 of parameter 3 en 4 weglaten, maar niet alleen parameter 3.

#### Voorbeeld

=ALS(A1>5;100;"te klein") als de waarde in A1 groter is dan 5, wordt de waarde 100 geretourneerd; anders, wordt de tekst te klein geretourneerd.

=ALS(A1>5;;"te klein") als de waarde in A1 groter is dan 5, wordt de waarde 0 geretourneerd, omdat lege parameters beschouwd worden als 0; anders, wordt de tekst te klein geretourneerd.

=ALS(A1<5;100;) als de waarde in A1 kleiner is dan 5, wordt de waarde 0 geretourneerd, omdat lege Waarde als onwaar geïnterpreteerd wordt als 0; anders wordt 100 geretourneerd.

## EN

Geeft WAAR terug als alle argumenten WAAR zijn. Indien één van de argumenten ONWAAR is, geeft deze functie de waarde ONWAAR terug.

De argumenten zijn ofwel zelf logische expressies (WAAR, 1<5, 2+3=7, B8<10) die logische waardes teruggeven of matrices (A1:C3) die logische waardes bevatten.

#### Syntaxis

EN(Logische waarde 1; Logische waarde 2 (optioneel); ...)(Logische waarde 1; Logische waarde 2 (optioneel); ...)

Logische waarde 1; Logische waarde 2 (optioneel); … zijn Booleaanse waardes, verwijzingen naar cellen of naar celbereiken van logische waardes.

Deze functie negeert elke tekst of lege cel binnen een gegevensbereik. Als u verkeerde resultaten van deze functie vermoedt, zoek dan naar tekst in de gegevensbereiken. Gebruik de functie Waardemarkering om tekstinhoud in een gegevensbereik te markeren.

#### Voorbeeld

De logische waardes van de items 12<13; 14>12 en 7<6 moeten worden gecontroleerd:

=EN(12<13;14>12;7<6) geeft ONWAAR terug.

=EN(ONWAAR();WAAR()) geeft ONWAAR.

De matrixformule {=EN(B1:B10;C1:C10)} levert een eendimensionale waarde van WAAR op wanneer alle componenten van B1:B10 en C1:C10 WAAR zijn. De bovenstaande matrixexpressie produceert niet de logische EN per element en produceert dus geen matrix van logische waardes. Om een logische EN van matrixen per element te berekenen, gebruikt u de * operator in matrixcontext. In het voorbeeld voert u {=B1:B10*C1:C10} in.

## EX.OF

Geeft waar als een oneven aantal argumenten op waar uit komt.

De argumenten zijn ofwel logische expressies op zich (WAAR, 1<5, 2+3=7, B8<10) die logische waardes teruggeven, ofwel matrices (A1:A3) die logische waardes bevatten.

Deze functie is beschikbaar sinds LibreOffice 4.0.

#### Syntaxis

EX.OF(Logische waarde 1; Logische waarde 2 (optioneel); ...)(Logische waarde 1; Logische waarde 2 (optioneel); ...)

Logische waarde 1; Logische waarde 2 (optioneel); … zijn Booleaanse waardes, verwijzingen naar cellen of naar celbereiken van logische waardes.

#### Voorbeeld

=EX.OF(WAAR();WAAR()) geeft ONWAAR

=EX.OF(WAAR();WAAR();WAAR()) geeft WAAR

=EX.OF(ONWAAR();WAAR()) geeft WAAR

## NIET

Complementeert een logische waarde (draait de waarde om) .

#### Syntaxis

NIET(Logische waarde)

Logische waarde is elke waarde die moet worden gecomplementeerd.

#### Voorbeeld

=NIET(A). Als A=WAAR dan zal NIET(A) naar ONWAAR beoordelen.

## OF

Geeft als resultaat WAAR als ten minste één argument WAAR is. Deze functie geeft de waarde ONWAAR, als alle argumenten de logische waarde ONWAAR hebben.

De argumenten zijn ofwel zelf logische expressies (WAAR, 1<5, 2+3=7, B8<10) die logische waardes teruggeven of matrices (A1:C3) die logische waardes bevatten.

#### Syntaxis

OF(Logische waarde 1; Logische waarde 2 (optioneel); ...)

Logische waarde 1; Logische waarde 2 (optioneel); … zijn Booleaanse waardes, verwijzingen naar cellen of naar celbereiken van logische waardes.

Deze functie negeert elke tekst of lege cel binnen een gegevensbereik. Als u verkeerde resultaten van deze functie vermoedt, zoek dan naar tekst in de gegevensbereiken. Gebruik de functie Waardemarkering om tekstinhoud in een gegevensbereik te markeren.

#### Voorbeeld

De logische waardes van de items 12<11; 13>22 en 45=45 moeten worden gecontroleerd.

=OF(12<11;13>22;45=45) geeft WAAR terug.

=OF(ONWAAR();WAAR()) geeft WAAR.

De matrixformule {=OF(B1:B10;C1:C10)} levert een eendimensionale waarde van ONWAAR op wanneer alle componenten van B1:B10 en C1:C10 ONWAAR zijn. De bovenstaande matrixexpressie produceert niet de logische OF per element en produceert dus geen matrix van logische waardes. Om een logische OF van matrixen per element te berekenen, gebruikt u de + operator in matrixcontext. In het voorbeeld voert u {=B1:B10+C1:C10} in.

## ONWAAR

Geeft als resultaat de logische waarde ONWAAR. De functie ONWAAR() vereist geen argumenten, en geeft altijd de logische waarde ONWAAR.

#### Syntaxis

ONWAAR()

#### Voorbeeld

=ONWAAR() geeft ONWAAR terug

=NIET(ONWAAR()) geeft WAAR terug

## WAAR

De logische waarde is ingesteld op WAAR. De functie WAAR() vereist geen argumenten, en geeft altijd de logische waarde WAAR terug.

#### Syntaxis

WAAR()

#### Voorbeeld

Als A=WAAR en B=ONWAAR verschijnen de volgende voorbeelden:

=EN(A;B) retourneert ONWAAR

=OF(A;B) retourneert WAAR

=NIET(EN(A;B)) retourneert WAAR

Verwante onderwerpen

Functies per categorie