Inhoud

# Tekstfuncties

In deze sectie staan beschrijvingen van de Tekst-functies.

Om toegang te krijgen tot deze functie..

Invoegen - Functie - Categorie Tekst

## Dubbele aanhalingstekens gebruiken in formules

Om een tekenreeks in een formule op te nemen, plaatst u de tekenreeks tussen twee dubbele aanhalingstekens (") en Calc neemt de tekens in de tekenreeks zonder te proberen ze te interpreteren. Bijvoorbeeld de formule ="Hallo wereld!" geeft de tekstreeks Hallo wereld! weer in de cel, zonder dubbele aanhalingstekens eromheen.

De meer complexe formule =TEKST.SAMENVOEGEN("Het leven is heel eenvoudig, "; "maar we staan erop het ingewikkeld te maken"; "(Confucius).") voegt drie afzonderlijke strings aan elkaar tussen dubbele aanhalingstekens, met als resultaat Het leven is heel eenvoudig, maar we staan erop het ingewikkeld te maken (Confucius).

Om een letterlijk dubbel aanhalingsteken binnen een tekenreeks in een formule te plaatsen, kunnen twee methoden worden gebruikt:

1. U kunt het dubbele aanhalingsteken "ontsnappen" met een extra dubbel aanhalingsteken, en Calc behandelt het dubbele aanhalingsteken met escapetekens als een letterlijke waarde. Bijvoorbeeld, de formule ="Mijn naam is ""John Doe""." geeft de tekenreeks Mijn naam is "John Doe". Een ander eenvoudig voorbeeld is de formule =UNICODE("""") wat 34 retourneert, de decimale waarde van het Unicode-aanhalingsteken (U+0022) — hier geven de eerste en vierde dubbele aanhalingstekens de begin en einde van de tekenreeks, terwijl het tweede dubbele aanhalingsteken aan de derde ontsnapt.

2. U kunt de functies CHAR of UNITEKEN gebruiken om een dubbel aanhalingsteken in te voegen. Bijvoorbeeld, de formule =UNITEKEN(34) & "The Catcher in the Rye" & UNITEKEN(34) & " is een beroemd boek van JD Salinger." geeft de string "The Catcher" weer in the Rye" is een beroemd boek van JD Salinger.

Houd er rekening mee dat de AutoCorrectie-functie van Calc dubbele aanhalingstekens kan wijzigen. AutoCorrectie zou de dubbele aanhalingstekens in formulecellen niet moeten wijzigen, maar kan de aanhalingstekens die worden gebruikt in niet-formulecellen die tekst bevatten, wijzigen. Als u bijvoorbeeld een tekenreeks kopieert die is omgeven door een andere vorm van typografische dubbele aanhalingstekens, zoals het dubbele dubbele aanhalingsteken links (U+201C) en het rechter dubbele aanhalingsteken (U+201D), en vervolgens in een formulecel, kan er een fout optreden. Open het gebied Dubbele aanhalingstekens van het dialoogvenster Extra - AutoCorrectie-opties - Gelokaliseerde opties om de tekens in te stellen die worden gebruikt om de typografische dubbele aanhalingstekens aan het begin en einde automatisch te corrigeren. Schakel de schakelknop Vervangen uit om de functie uit te schakelen.

## ARABISCH

Retourneert de numerieke waarde die overeenkomt met een Romeins cijfer uitgedrukt als tekst.

## ASC

Converteert double-byte (volledige breedte) tekens naar single-byte (halve breedte) ASCII- en katakana-tekens.

## JIS

Converteert enkelbyte (halve breedte) ASCII- of katakana-tekens naar dubbelbyte (volledige breedte) tekens.

## REGEX

Komt overeen en extraheert of vervangt optioneel tekst met behulp van reguliere expressies.

## ROMEINS

Converteert een getal naar een Romeins cijfer. Het waardebereik moet tussen 0 en 3999 liggen. Een vereenvoudigingsmodus kan worden gespecificeerd in het bereik van 0 tot 4.

## WAARDE

Converteert de tekenreeksrepresentatie van een getal naar een numerieke vorm. Als de opgegeven tekenreeks een geldige datum, tijd of datum-tijd is, wordt het bijbehorende serienummer voor datum-tijd geretourneerd.

### WEBSERVICE

Web-inhoud van een URI verkrijgen.

### XMLFILTER

Pas een XPath-expressie toe op een XML-document.

### URLCODERING

Geeft een URL-gecodeerde tekenreeks

## BAHT.TEXT

Converteert een getal naar Thaise tekst, inclusief de Thaise valutanamen.

#### Syntaxis

BAHT.TEXT(Getal)

Getal is een willekeurig getal. "Baht" wordt aan het integrale deel van het getal toegevoegd, en "Satang" wordt aan het decimale deel van het getal toegevoegd.

#### Voorbeeld

=BAHT.TEKST(12.65) geeft een tekenreeks terug in Thaise tekens in de betekenis van "twaalf Baht en vijfenzestig Satang".

#### Technische informatie

Deze functie maakt geen deel uit van de Open Document Format for Office Applications (OpenDocument) Versie 1.3. Deel 4: Herberekende formule (OpenFormula) indeling standaard. De naamafstand is

COM.MICROSOFT.BAHTTEXT

## BASIS

Converteert een positief geheel getal naar een opgegeven grondtal in een tekst uit het nummeringssysteem. De cijfers 0-9 en de letters AZ worden gebruikt.

#### Syntaxis

BASIS(Getal; Radix [; Minimumlengte])

Getal is het positieve gehele getal dat moet worden geconverteerd.

Radix geeft de basis van het getallenstelsel aan. Het kan elk positief geheel getal tussen 2 en 36 zijn.

MinimumLengte (optioneel) bepaalt de minimumlengte van de tekenreeks die werd gemaakt. Als de tekst korter is dan de opgegeven minimumlengte, worden links van de tekenreeks nullen toegevoegd.

#### Voorbeeld

=BASIS(17;10;4) geeft 0017 terug in het decimale systeem.

=BASIS(17;2) geeft 10001 terug in het binaire systeem.

=BASIS(255;16;4) geeft 00FF terug in het hexadecimale systeem.

#### Zie ook

DECIMAAL

## BEDRAG

Converteert een getal naar een tekenreeks die de hoeveelheid vertegenwoordigt in de valutanotatie, afgerond op gespecificeerde decimalen, met behulp van het decimaalteken dat overeenkomt met de huidige landinstelling. Voer in het veld Waarde het getal in dat moet worden geconverteerd. Optioneel kunt u het aantal decimalen invoeren in het veld Decimalen. Als er geen waarde is opgegeven, worden alle getallen in valuta-indeling weergegeven met twee decimalen.

U kunt de valuta-opmaak in uw systeeminstellingen opgeven.

#### Syntaxis

EURO(Waarde [; Decimalen])

Waarde is een getal, een verwijzing naar een cel die een getal bevat of een formule die een getal teruggeeft.

Decimalen is het optionele aantal plaatsen achter de komma.

#### Voorbeeld

=DOLLAR(255) retourneert $255,00 voor de Engelse (VS) landinstelling en USD (dollar) valuta; ￥ 255,00 voor de Japanse landinstelling en JPY (yen) valuta; of 255,00 € voor de Duitse (Duitsland) locale en EUR (euro) valuta.

=DOLLAR(367.456;2) retourneert $367.46.

## BEGINLETTERS

Wijzigt de eerste letter van elk woord in een tekenreeks in een hoofdletter.

#### Syntaxis

BEGINLETTERS("Tekst")

Zoektekst verwijst naar de tekst die moet worden gevonden.

#### Voorbeeld

=BEGINLETTERS("the document foundation") geeft The Document Foundation terug.

## BIJSNIJDEN

Verwijdert spaties uit een tekenreeks, zodat er slechts één spatie tussen woorden blijft staan.

#### Syntaxis

BIJSNIJDEN("Tekst")

Tekst verwijst naar tekst waarin voorloopspaties verwijderd worden.

#### Voorbeeld

=BIJSNIJDEN(" hallo wereld ") geeft hallo wereld terug zonder voorafgaande of volgende spaties en met een enkele spatie tussen de woorden.

## CODE

Geeft een numerieke code voor het eerste teken in een tekenreeks.

#### Syntaxis

CODE("Tekst")

Tekst is de tekst waarvoor de code van het eerste teken moet worden vastgesteld.

Codes groter dan 127 kunnen afhankelijk zijn van de tekensets op uw systeem (bijvoorbeeld iso-8859-1, iso-8859-2, Windows-1252, Windows-1250) en zouden toch niet overgedragen kunnen worden.

#### Voorbeeld

=CODE("Hiëronymus") geeft 72 terug, =CODE("hiëroglyfisch") geeft 104 terug.

De hier gebruikte code verwijst niet naar ASCII, maar naar de codetabel die momenteel geladen is.

## DECIMAAL

Converteert tekst die een getal vertegenwoordigt in een numeriek systeem met de gegeven basisradix naar een positief geheel getal. De radix moet tussen 2 en 36 liggen. Spaties en tabs worden genegeerd. Het veld Tekst is niet hoofdlettergevoelig.

Als de radix 16 is, worden een voorafgaande x of X of 0x of 0X en een toegevoegde h of H genegeerd. Als de radix 2 is, wordt een toegevoegde b of B genegeerd. Andere tekens die niet tot het cijfersysteem behoren, genereren een fout.

#### Syntaxis

DECIMAAL("Tekst"; Radix)

Tekst is de te converteren tekst.

Radix geeft de basis van het getalsysteem aan. Het kan elk positief geheel getal tussen 2 en 36 zijn.

#### Voorbeeld

=DECIMAAL("17";10) geeft 17 terug.

=DECIMAAL("FACE";16) geeft 64206 terug.

=DECIMAAL("0101";2) geeft 5 terug.

#### Zie ook

BASE

## DEEL

Geeft een tekenreeks uit een tekst terug. De parameters specificeren de startpositie en het aantal tekens.

#### Syntaxis

DEEL("Tekst"; Begin; Getal)

Tekst is de tekst waaruit de tekens moeten worden weggenomen.

Begin is de positie van het eerste teken in de tekst dat moet worden weggenomen.

Getal specificeert het aantal tekens in het gedeelte van de tekst.

#### Voorbeeld

=DEEL("kantoor";2;2) geeft an terug.

## DEELB

Geeft een tekenreeks uit een DBCS-tekst terug. De parameters specificeren de startpositie en het aantal tekens.

Deze functie is beschikbaar sinds LibreOffice 4.2.

#### Syntaxis

DEEL("Tekst"; Begin; Aantal_bytes)

Tekst is de tekst waaruit de tekens moeten worden weggenomen.

Begin is de positie van het eerste teken in de tekst dat moet worden weggenomen.

Aantal_bytes is het aantal tekens dat DEEL van de tekst zal terug geven, in bytes.

#### Voorbeeld

=DEELB("中国";1;0) geeft "" terug (0 bytes is altijd een lege tekenreeks).

=DEELB("中国";1;1) geeft " " terug (1 byte is slechts een half DBCS-teken en daarom is het resultaat een spatie).

=DEELB("中国";1;2) geeft "中" terug (2 bytes vormen één volledig DBCS-teken).

=DEELB("中国";1;3) geeft "中 " terug (3 bytes vormen anderhalf DBCS-teken; de laatste byte resulteert in een spatie).

=DEELB("中国";1;4) geeft "中国" terug (4 bytes vormen twee volledige DBCS-tekens).

=DEELB("中国";2;1) geeft " " terug (bytepositie 2 staat niet aan het begin van een teken in een DBCS-tekenreeks; Er wordt 1 spatie teruggegeven).

=DEELB("中国";2;2) geeft " " terug (bytepositie 2 wijst naar de laatste helft van het eerste teken in de DBCS-tekenreeks; de gevraagde 2 bytes vormen dus de laatste helft van het eerste teken en de eerste helft van het tweede teken in de string; Er worden daarom 2 spatietekens geretourneerd).

=DEELB("中国";2;3) geeft " 国" terug (bytepositie 2 staat niet aan het begin van een teken in een DBCS-tekenreeks; een spatie wordt geretourneerd voor bytepositie 2).

=DEELB("中国";3;1) geeft " " terug (bytepositie 3 staat aan het begin van een teken in een DBCS-tekenreeks, maar 1 byte is slechts een half DBCS-teken en daarom wordt in plaats daarvan een spatie geretourneerd).

=DEELB("中国";3;2) geeft "国" terug (bytepositie 3 staat aan het begin van een teken in een DBCS-tekenreeks, en 2 bytes vormen één DBCS-teken).

=DEELB("office";2;3) geeft "ffi" terug (bytepositie 2 staat aan het begin van een teken in een niet-DBCS-tekenreeks, en 3 bytes van een niet-DBCS-tekenreeks vormen 3 tekens).

## GELIJK

Vergelijkt twee tekenreeksen en geeft WAAR als ze identiek zijn. Deze functie is hoofdlettergevoelig.

#### Syntaxis

GELIJK("Tekst1"; "Tekst2")

Tekst1 verwijst naar de eerste tekst om te vergelijken.

Tekst2 is de tweede tekst om te vergelijken.

#### Voorbeeld

=GELIJK("microsystems";"Microsystems") geeft ONWAAR terug.

## HERHALING

Herhaalt een tekenreeks met het opgegeven aantal kopieën.

#### Syntaxis

HERHALING("Tekst"; Getal)

Tekst is de tekst die moet worden herhaald.

Getal is het aantal herhalingen.

#### Voorbeeld

=HERHALING("Goede morgen";2) geeft Goede morgenGoede morgen terug.

Bekijk de HERHALEN wiki pagina voor meer details over deze functie.

## HOOFDLETTERS

Converteert de opgegeven tekenreeks in het tekstveld naar hoofdletters.

#### Syntaxis

HOOFDLETTERS("Tekst")

Tekst verwijst naar de kleine letters die u wilt converteren naar hoofdletters.

#### Voorbeeld

=HOOFDLETTERS("GOEDE MORGEN") geeft GOEDE MORGEN terug.

## KLEINE.LETTERS

Converteert alle hoofdletters in een tekenreeks naar kleine letters.

#### Syntaxis

KLEINE.LETTERS("Tekst")

Zoektekst verwijst naar de tekst die moet worden gevonden.

#### Voorbeeld

=KLEINE.LETTERS("Sun") geeft sun terug.

## LENGTE

Geeft de lengte van een tekenreeks inclusief de spaties.

#### Syntaxis

LENGTE("Tekst")

Tekst is de tekst waarvan de lengte moet worden bepaald.

#### Voorbeeld

=LENGTE("Goedemiddag") geeft 11 terug.

=LENGTE(12345,67) geeft 8 terug.

## LENGTEB

Geeft het aantal bytes dat, voor de tekens in een tekenreeks voor double-byte tekensetset (DBCS), wordt gebruikt.

Deze functie is beschikbaar sinds LibreOffice 4.2.

#### Syntaxis

LENGTEB("Tekst")

Tekst is de tekst waarvan de lengte moet worden bepaald.

#### Voorbeeld

LENGTEB("中") geeft 2 terug (1 DBCS-teken van 2 bytes).

LENGTEB("中国") geeft 4 terug (2 DBCS-tekens van elk 2 bytes).

LENGTEB("Kantoor")Geeft 6 terug (6 niet-DBCS tekens van elk 1 byte).

=LENGTEB("Goedemiddag") geeft 11 terug.

=LENGTEB(12345,67) geeft 8 terug.

## LINKS

Geeft het eerste teken of tekens van een tekst terug.

#### Syntaxis

LINKS("Tekst" [; Getal])

Tekst is de tekst waarvan de initiële gedeeltelijke woorden moeten worden bepaald.

Aantal (optioneel) geeft het aantal tekens voor de begintekst. Als deze parameter niet gedefinieerd is, wordt er één teken als resultaat gegeven.

#### Voorbeeld

=LINKS("uitvoer";3) geeft “uit” terug.

## LINKSB

Geeft de eerste tekens van een DBCS-tekst terug.

Deze functie is beschikbaar sinds LibreOffice 4.2.

#### Syntaxis

LINKSB("Tekst" [; Getal])

Tekst is de tekst waarvan de initiële gedeeltelijke woorden moeten worden bepaald.

Aantal_bytes (optioneel) geeft het aantal tekens dat u LINKS wilt laten ophalen, op bytes gebaseerd. Als deze parameter niet gedefinieerd is, wordt er één teken als resultaat gegeven.

#### Voorbeeld

=LINKSB("中国";1) geeft " " terug (1 byte is slechts een half DBCS-teken en in plaats daarvan wordt een spatie teruggegeven).

=LINKSB("中国";2) geeft "中" terug (2 bytes vormen één volledig DBCS-teken).

=LINKSB("中国";3) retourneert "中 " (3 bytes vormen anderhalf DBCS-teken; het laatste geretourneerde teken is daarom een spatie).

=LINKSB("中国";4) geeft "中国" terug (4 bytes vormen twee volledige DBCS-tekens).

=LINKSB("kantoor";3) geeft "kan" terug (3 niet-DBCS-tekens die elk uit 1 byte bestaan).

## RECHTS

Geeft het laatste teken of tekens terug van een tekst.

#### Syntaxis

RECHTS("Tekst" [; Getal])

Tekst is de tekst waarvan het rechter gedeelte moet worden bepaald.

Aantal (optioneel) is het aantal tekens uit het rechtergedeelte van de tekst. Als deze parameter niet is gedefinieerd, wordt één teken geretourneerd.

#### Voorbeeld

=RECHTS("Sun";2) geeft un terug.

## RECHTSB

Geeft het laatste teken of tekens van een tekst met dubbel-byte tekenreeksen (DBCS).

Deze functie is beschikbaar sinds LibreOffice 4.2.

#### Syntaxis

RECHTSB("Tekst" [; Getal])

Tekst is de tekst waarvan het rechter gedeelte moet worden bepaald.

Aantal_bytes (optioneel) specificeert het aantal tekens dat u door IGHTB wilt laten extraheren, gebaseerd op bytes. Als deze parameter niet is gedefinieerd, wordt één byte geretourneerd.

#### Voorbeeld

RECHTSB("中国";1) geeft " " terug (1 byte is slechts een half DBCS teken en daarom wordt een spatie in de plaats teruggegeven).

RECHTSB("中国";2) geeft "国" terug (2 bytes vormen een volledig DBCS teken).

RECHTSB("中国";3) geeft " 国" terug (3 bytes zijn een half DBCS teken en een heel DBCS teken; het eerste halve teken resulteert in een spatie).

RECHTSB("中国";4) geeft "中国" terug (4 bytes zijn twee complete DBCS tekens).

RECHTSB("kantoor";3)Geeft "too" terug (3 niet-DBCS tekens van elk 1 byte).

## T

Deze functie geeft de doeltekst terug, of een blanco tekenreeks als het doel geen tekst is.

#### Syntaxis

T(Waarde)

Als Waarde een tekst-tekenreeks is of verwijst naar een tekst-tekenreeks, geeft T die tekst-tekenreeks terug, anders wordt een blanco tekst-tekenreeks teruggegeven.

#### Voorbeeld

=T(12345) geeft een lege tekenreeks terug.

=T("12345") geeft de tekenreeks 12345 terug.

## TEKEN

Converteert een getal naar een teken in overeenstemming met de huidige codetabel. Het getal kan een geheel getal van twee of drie cijfers zijn.

Codes groter dan 127 kunnen afhankelijk zijn van de tekensets op uw systeem (bijvoorbeeld iso-8859-1, iso-8859-2, Windows-1252, Windows-1250) en zouden toch niet overgedragen kunnen worden.

#### Syntaxis

TEKEN(Getal)

Getal is een getal tussen 1 en 255 dat de codewaarde voor een teken vertegenwoordigd.

#### Voorbeeld

=TEKEN(100) geeft het teken d terug.

="abc" & TEKEN(10) & "def" voegt een teken voor een nieuwe regel in de tekenreeks in.

## TEKST

Converteert een waarde naar tekst in een bepaalde opmaak.

#### Syntaxis

TEKST(Waarde; Notatie)

Waarde is de waarde (numeriek of tekstueel) die moet worden geconverteerd.

Notatie is de tekst die de opmaak definieert. Gebruik scheidingstekens voor decimalen en duizendtallen volgens de taal die in de celopmaak ingesteld is.

#### Voorbeeld

=TEKST(12,34567;"###,##") geeft de tekst 12,35 terug

=TEKST(12,34567;"000,00") geeft de tekst 012,35 terug

=TEKST("xyz";"=== @ ===") geeft de tekst === xyz === terug.

Zie ook Getalopmaakcodes: aangepaste opmaakcodes die door de gebruiker gedefinieerd zijn.

## TEKST.SAMENVOEGEN

Combineert verschillende tekenreeksen tot één tekenreeks.

#### Syntaxis

TEKST.SAMENVOEGEN(Tekst1 [; Tekst2 [; … [; Tekst255]]])

Tekst1[; Tekst2][; … ;[Tekst255]] zijn tekenreeksen of verwijzingen naar cellen die tekenreeksen bevatten.

#### Voorbeeld

=TEKST.SAMENVOEGEN("Goede ";"morgen ";"mevr. ";"Onbekend") geeft terug: Goede morgen mevr. Onbekend.

## UNICODE

Geeft de numerieke code voor het eerste Unicode-teken in een tekenreeks.

#### Syntaxis

UNICODE("Tekst")

#### Voorbeeld

=UNICODE("©") geeft het Unicode-getal 169 terug voor het teken Copyright.

Zie ook de functie UNITEKEN().

## UNITEKEN

Wijzigt een codegetal in een Unicode-teken of -letter.

#### Syntaxis

UNITEKEN(getal)

#### Voorbeeld

=UNITEKEN(169) geeft het Copyright karakter ©.

Zie ook de functie UNICODE().

## VAST

Retourneert een getal als tekst met een opgegeven aantal decimalen en optionele scheidingstekens voor duizendtallen.

#### Syntaxis

VAST(Getal; [Decimalen = 2 [; GeenScheidingstekenDuizendtallen = ONWAAR]])

Getal is afgerond op Decimalen (na het scheidingsteken voor decimalen) en het resultaat is opgemaakt als tekst, met gebruik vanlocale-specifieke instellingen.

Decimalen (optioneel) verwijst naar het aantal weer te geven decimalen. Als Decimalen negatief is, dan wordt Getal afgerond met het aantal (Decimalen), naar links vanaf de decimale punt. Als Decimalen een breuk is, wordt het afgekapt en negeert eigenlijk wat het dichtstbijzijnde gehele getal is.

GeenScheidingstekenDuizendtallen (optioneel) bepaalt of het scheidingsteken voor duizendtallen wordt gebruikt. Als het WAAR is of niet nul, dan worden groepsscheidingstekens weggelaten uit de resulterende tekenreeks. Als de parameter gelijk is aan 0 of helemaal ontbreekt, worden de scheidingstekens voor duizendtallen van uw huidige lokale instellingen weergegeven.

#### Voorbeeld

=VAST(1234567,89;3) geeft 1.234.567,890 terug als een tekst tekenreeks.

=VAST(123456.789;;WAAR) Geeft 123456.79 terug als tekst.

=VAST(12345.6789;-2) geeft 12,300 terug als tekst.

=VAST(12134567.89;-3;1) geeft 12135000 terug als tekst.

=VAST(12345.789;3/4) geeft 12,346 terug als tekst.

=VAST(12345.789;8/5) geeft 12,345.8 terug als tekst.

## VERVANGEN

Vervangt een gedeelte van een tekenreeks door een andere tekenreeks. Deze functie kan gebruikt worden om zowel tekens als getallen te vervangen (die automatisch naar tekst geconverteerd worden). Het resultaat van de functie wordt altijd als tekst weergegeven. Als u verdere berekeningen wilt uitvoeren met een getal dat vervangen is door tekst, moet u het weer naar een getal converteren met behulp van de functie WAARDE.

Tekst met getallen moet tussen aanhalingstekens staan als u niet wilt dat deze als een getal geïnterpreteerd en automatisch naar tekst geconverteerd wordt.

#### Syntaxis

VERVANGEN("Tekst"; Positie; Lengte; "NieuweTekst")

Tekst is de tekst waarvan een deel vervangen zal worden.

Positie verwijst naar de positie in de tekst waar de vervanging zal beginnen.

Lengte is het aantal tekens in Tekst die moeten worden vervangen.

NieuweTekst verwijst naar de tekst die Tekst vervangt.

#### Voorbeeld

=VERVANGEN("1234567";1;1;"444") geeft "444234567" terug. Eén teken op positie 1 wordt vervangen door de complete NieuweTekst.

## VERVANGING

Vervangt oude tekst met nieuwe tekst in een tekenreeks.

#### Syntaxis

VERVANGING(Tekst; ZoekTekst; NieuweTekst [;AantalKeren])

Tekst is de tekst waarin tekstsegmenten moeten worden verwisseld.

Zoektekst is het tekstsegment dat moet worden vervangen (een aantal keren).

NieuweTekst is de tekst waardoor het tekstsegment wordt vervangen.

AantalKeren (optioneel) geeft aan welke gevonden instantie van de zoektekst moet worden vervangen. Als deze parameter word weggelaten wordt de zoektekst overal vervangen.

#### Voorbeeld

=VERVANGING("123123123";"3";"abc") geeft 12abc12abc12abc terug.

=VERVANGING("123123123";"3";"abc";2) geeft 12312abc123 terug.

## VIND.ALLES

Geeft de positie van een een tekenreeks binnen een andere tekenreeks. U kunt ook definiëren waar het zoeken moet beginnen. De zoekterm kan een getal of een reeks tekens zijn. De zoekopdracht is hoofdlettergevoelig.

#### Syntaxis

VINDEN(ZoekTekst;Tekst[; Positie])

Zoektekst verwijst naar de tekst die moet worden gevonden.

Tekst is de tekst waar het zoeken wordt uitgevoerd.

Positie (optioneel) is de positie in de tekst waar het zoeken begint.

#### Voorbeeld

=VIND.ALLES(76;998877665544) geeft 6 terug.

## VIND.SPEC

Geeft de positie van een tekstsegment binnen een tekenreeks. U kunt het begin van de zoekactie als een optie instellen. De zoektekst kan een getal zijn of een reeks tekens. De zoekopdracht is niet hoofdlettergevoelig. Als de tekst niet gevonden wordt, wordt de foutcode 519 (#WAARDE) gegenereerd.

De zoekopdracht ondersteunt jokertekens of reguliere expressies. Als reguliere expressies zijn ingeschakeld, kunt u "all.*" invoeren, bijvoorbeeld om de eerste locatie van "all" te vinden, gevolgd door willekeurige tekens. Als u wilt zoeken naar een tekst die ook een reguliere expressie is, moet u elk metateken of operator van een reguliere expressie laten voorafgaan door een "\"-teken, of de tekst in \Q...\E insluiten. U kunt de automatische evaluatie van jokertekens of reguliere expressies in- en uitschakelen in LibreOffice - Voorkeuren Extra - Opties - LibreOffice Calc - Berekenen .

Wanneer u functies gebruikt waarbij een of meer argumenten tekenreeksen voor zoekcriteria zijn, die een reguliere expressie vertegenwoordigen, is de eerste poging om de tekenreekscriteria om te zetten naar getallen. ".0" wordt bijvoorbeeld omgezet naar 0,0 enzovoort. Als dit lukt, is de overeenkomst geen overeenkomst met een reguliere expressie, maar een numerieke overeenkomst. Als u echter overschakelt naar een landinstelling waar het decimaalteken niet de punt is, werkt de conversie van reguliere expressies. Om de uitvoering van de reguliere expressie af te dwingen in plaats van een numerieke expressie, gebruikt u een expressie die niet verkeerd kan worden gelezen als numeriek, zoals ". [0]" of ". \ 0" of "(? I) .0".

#### Syntaxis

ZOEKEN("Tekst zoeken"; "Tekst" [; Positie])

Zoektekst is de tekst waarnaar moet worden gezocht.

Tekst is de tekst waar het zoeken wordt uitgevoerd.

Positie (optioneel) is de positie in de tekst waar het zoeken moet beginnen.

#### Voorbeeld

=VIND.SPEC(54;998877665544) geeft 10 terug.

## WISSEN.CONTROL

Alle niet-afdrukbare tekens worden uit de tekenreeks verwijderd.

#### Syntaxis

WISSEN.CONTROL("Tekst")

Tekst verwijst naar de tekst vanaf waar alle niet-afdrukbare tekens moeten worden verwijderd.

#### Voorbeeld

=LENGTE(WISSEN.CONTROL(CHAR(7) & "LibreOffice Calc" & CHAR(8))) geeft 16 terug, wat aantoont dat de WISSEN.CONTROL-functie de niet-afdrukbare Unicode U+0007 ("BEL") verwijdert en U+0008 ("BS") tekens aan het begin en einde van de invoer. WISSEN.CONTROL verwijdert geen spaties.

Verwante onderwerpen

Functies per categorie