Contents
Index 🔎︎

# ការ​ប្រើ​អថេរ

ដូច​ខាង​ក្រោម​ពណ៌នា​អំពី​មូលដ្ឋាន​នៃ​ការ​ប្រើ​អថេរ​ក្នុង LibreOffice Basic ។

## ការ​សន្មត​ឈ្មោះ សម្រាប់​ឈ្មោះ​អថេរ

ឈ្មោះ​អថេរ​អាច​មាន​តួ​អក្សរ​ច្រើន​បំផុត ២៥៥ តួ ។ តួ​អក្សរ​ទី​មួយ​នៃ​ឈ្មោះ​អថេរ ត្រូវ​តែ ជា​អក្សរ​ពី A-Z ឬ a-z ។ លេខ​ក៏​អាច​ត្រូវ​បាន​ប្រើ​ក្នុង​ឈ្មោះ​អថេរ ប៉ុន្តែ​សញ្ញា​វណ្ណយុត្ត និង​តួ​អក្សរ​ពិសេស​មិន​ត្រូវ​​បាន​​អនុញ្ញាត​​ទេ លើក​លែង​តែ​តួ​អក្សរ ("_") ។ ក្នុង LibreOffice Basic ឈ្មោះ​អថេរ​មិន​ប្រកាន់​អក្សរ​តូច​ធំ​ទេ ។ ឈ្មោះ​អថេរ​អាច​មាន​ដក​ឃ្លា ប៉ុន្តែ​ត្រូវ​តែ​ដាក់​សញ្ញា "[ ]" នៅ​ជុំ​វិញ ប្រសិន​បើ​ពួក​វា​មាន ។

ឧទាហរណ៍​អំពី​ឈ្មោះ​អថេរ ៖

        MyNumber=5      'Correct'
        MyNumber5=15    'Correct'
        MyNumber_5=20   'Correct'
        My Number=20    'Not valid, variable with space must be enclosed in square brackets'
        [My Number]=12  'Correct'
        DéjàVu=25       'Not valid, special characters are not allowed'
        5MyNumber=12    'Not valid, variable may not begin with a number'
        Number,Mine=12  'Not valid, punctuation marks are not allowed'

## ការ​ប្រកាស​អថេរ

ក្នុង LibreOffice Basic អ្នក​មិន​ចាំបាច់​ប្រកាស​អថេរ​ជាក់លាក់ ។ ការ​ប្រកាស​អថេរ​មួយ​អាច​ត្រូវ​បាន​ធ្វើ​ដោយ​ប្រើ Dim ។ អ្នក​អាច​ប្រកាស​អថេរ​ច្រើន​ជាង​មួយ​នៅ​ពេល​តែ​មួយ ដោយ​បំបែក​ដោយ​សញ្ញា (,) ។ ដើម្បី​កំណត់​ប្រភេទ​អថេរ ប្រើ​សញ្ញា​ប្រភេទ​ប្រកាស​បន្ទាប់​ពី​ឈ្មោះ ឬ​ពាក្យ​គន្លឹះ​ដែល​សមរម្យ​ក៏​បាន ។

ឧទាហរណ៍​សម្រាប់​ការ​ប្រកាស​អថេរ ៖

        Dim a$               'Declares the variable "a" as a String'
        Dim a As String      'Declares the variable "a" as a String'
        Dim a$, b As Integer 'Declares one variable as a String and one as an Integer'
        Dim c As Boolean     'Declares c as a Boolean variable that can be TRUE or FALSE'

នៅ​ពេល​អ្នក​បាន​ប្រកាស​អថេរ​មួយ​ជា​ប្រភេទ​ពិត​ប្រាកដ​មួយ អ្នក​មិន​អាច​ប្រកាស​អថេរ​ដោយ​ប្រើ​ឈ្មោះ​ដូច​គ្នា​ម្តង​ទៀត​ជា​ប្រភេទ​ផ្សេង​បាន​ទេ !

When you declare multiple variables in a single line of code you need to specify the type of each variable. If the type of a variable is not explicitly specified, then Basic will assume that the variable is of the Variant type.

      ' Both variables "a" and "b" are of the Integer type
      Dim a As Integer, b As Integer
      ' Variable "c" is a Variant and "d" is an Integer
      Dim c, d As Integer
      ' A variable can also be explicitly declared as a Variant
      Dim e As Variant, f As Double

The Variant type is a special data type that can store any kind of value. To learn more, refer to the section The Variant type below.

### បង្ខំ​​​ឲ្យ​​មាន​ការ​ប្រកាស​អថេរ

ដើម្បី​បង្ខំ​ការ​ប្រកាស​អថេរ ប្រើ​ពាក្យ​បញ្ជា​ដូច​ខាង​ក្រោម ៖

    Option Explicit

សេចក្តី​ថ្លែង​ការណ៍​Option Explicit ត្រូវ​តែ​ជា​បន្ទាត់​ទី​មួយ​ក្នុង​ម៉ូឌុល នៅ​មុន SUB ទី​មួយ ។ ជា​ទូទៅ មាន​តែ​អារេ​ប៉ុណ្ណោះ​ដែល​ត្រូវ​ការ​ប្រកាស​ជាក់លាក់ ។ អថេរ​ផ្សេង​ទៀត​ទាំងអស់ ត្រូវ​បាន​ប្រកាស​ដោយ​យោង​ទៅ​តួ​អក្សរ​ប្រភេទ​ប្រកាស ឬប្រសិន​បើ​ត្រូវ​បាន​លុប​ចោល​ វា​ជា​ប្រភេទ​លំនាំដើម Single ។

## ប្រភេទ​អថេរ

LibreOffice Basic គាំទ្រ​អថេរ​បួន​ប្រភេទ ៖

- អថេរ ជា​លេខ អាច​ផ្ទុក​តម្លៃ​លេខ ។ អថេរ​ខ្លះ​ត្រូវ​បាន​ប្រើ​ដើម្បី​រក្សាទុក​ចំនួន​ធំ ឬ​តូច និង​ផ្សេង​ទៀត​ត្រូវ​បាន​ប្រើ សម្រាប់​ចំនួន​ទសភាគ ឬ​ប្រភាគ ។

- String អថេរ​ដែល​មាន​ខ្សែ​តួ​អក្សរ ។

- អថេរ ប៊ូលីន មាន​តម្លៃ​ពិត​ ឬ​មិន​ពិត​ ។

- វត្ថុ​ អថេរ​អាច​រក្សាទុក​វត្ថុ​ប្រភេទ​ខុស​ៗ​គ្នា ដូចជា​តារាង និង​ឯកសារ​ក្នុង​​ឯកសារ​​មួយ ។

### អថេរ​ចំនួន​គត់

អថេរ​​ចំនួន​គត់​ស្ថិត​នៅ​ចន្លោះ​ពី -32768 ដល់ 32767 ។ ប្រសិន​បើ​អ្នក​ផ្តល់​តម្លៃ​ទសភាគ​ទៅ​អថេរ​ចំនួន​គត់​មួយ ខ្ទង់​ទសភាគ​ត្រូវ​បាន​បង្គត់​ទៅ​ចំនួន​គត់​បន្ទាប់ ។ អថេរ​ចំនួន​គត់​ត្រូវ​បាន​គណនា​យ៉ាង​លឿន​ក្នុង​បែបបទ និង​សម​ស្រប​សម្រាប់​អថេរ​រាប់​ក្នុង​រង្វិល​ជុំ ។ អថេរ​ចំនួន​គត់​​ត្រូវ​ការ​អង្គ​ចងចាំ​តែ ២ បៃ​ប៉ុណ្ណោះ ។ "%" គឺ​ជា​តួ​អក្សរ​ប្រភេទ​ការ​ប្រកាស ។

    Dim Variable%
    Dim Variable As Integer

### អថេរ​ចំនួន​គត់​ធំ

អថេរ​ចំនួន​គត់​ធំ​ស្ថិត​នៅ​ចន្លោះ​ពី -2147483648 ដល់ 2147483647 ។ ប្រសិន​បើ​អ្នក​ផ្តល់​តម្លៃ​ទសភាគ​ទៅ​អថេរ​ចំនួន​គត់​ធំ ខ្ទង់​ទសភាគ​ត្រូវ​បាន​បង្គត់​ទៅ​ចំនួន​គត់​បន្ទាប់ ។ អថេរ​ចំនួន​គត់​ធំ​ត្រូវ​បាន​គណនា​យ៉ាង​លឿន​ក្នុង​បែបបទ និង​សម​ស្រប​សម្រាប់​អថេរ​រាប់​ក្នុង​រង្វិល​ជុំ សម្រាប់​តម្លៃ​ធំ​ៗ ។ អថេរ​ចំនួន​គត់​ធំ​ទាមទារ​អង្គ​ចងចាំ ៤ បៃ ។ "&" គឺ​ជា​តួ​អក្សរ​ប្រភេទ​ការ​ប្រកាស ។

    Dim Variable&
    Dim Variable As Long

### អថេរ​គោលដប់

អថេរ​គោលដប់​អាច​យក​លេខ​វិជ្ជមាន អវិជ្ជមាន ឬ​សូន្យ ។ ភាព​ត្រឹមត្រូវ​គឺ​មាន​រហូត​ដល់ ២៩ តួលេខ ។

អ្នក​អាច​ប្រើ​សញ្ញា (+) ឬ (-) ជា​បុព្វបទ​សម្រាប់​លេខ​គោលដប់ (ដោយ​មាន ឬ​គ្មាន​ចន្លោះ) ។

ប្រសិន​បើ​លេខ​គោលដប់​ត្រូវ​បាន​កំណត់​ជាអថេរ​ចំនួន​គត់ LibreOffice Basic បង្គត់​ចំនួន​ចុះ ឬ​ឡើង ។

### អថេរ​តែ​មួយ

Single variables can take positive or negative values ranging from 3.402823 x 10E38 to 1.401298 x 10E-45. Single variables are floating-point variables, in which the decimal precision decreases as the non-decimal part of the number increases. Single variables are suitable for mathematical calculations of average precision. Calculations require more time than for Integer variables, but are faster than calculations with Double variables. A Single variable requires 4 bytes of memory. The type-declaration character is "!".

    Dim Variable!
    Dim Variable As Single

### អថេរ​ទ្វេ

Double variables can take positive or negative values ranging from 1.79769313486232 x 10E308 to 4.94065645841247 x 10E-324. Double variables are floating-point variables, in which the decimal precision decreases as the non-decimal part of the number increases. Double variables are suitable for precise calculations. Calculations require more time than for Single variables. A Double variable requires 8 bytes of memory. The type-declaration character is "#".

    Dim Variable#
    Dim Variable As Double

### អថេរ​រូបិយប័ណ្ណ

អថេរ​រូបិយប័ណ្ណ​ត្រូវ​បាន​រក្សា​ទុក​ខាង​ក្នុង​ជា​ចំនួន ៦៤ ប៊ីត (៨ បៃ) និង​បាន​​បង្ហាញ​ជា​ចំនួន​ទសភាគ​ថេរ​មួយ​ដែល​មាន​ខ្ទង់​មិន​មែន​ទសភាគ ១៥ ខ្ទង់ និង​ខ្ទង់​ទសភាគ ៤ ខ្ទង់ ។ តម្លៃ​ស្ថិត​នៅ​ចន្លោះ​ពី -922337203685477.5808 ដល់ +922337203685477.5807 ។ អថេរ​រូបិយប័ណ្ណ​ត្រូវ​បាន​ប្រើ​ដើម្បី​គណនា​តម្លៃ​រូបិយប័ណ្ណ​ដែល​មាន​ចំនួន​ខ្ទង់​ទសភាគ​ខ្ពស់ ។ តួ​អក្សរ​ប្រភេទ​ការ​ប្រកាស​គឺ "@" ។

    Dim Variable@
    Dim Variable As Currency

### Literals for integers

Numbers can be encoded using octal and hexadecimal forms.

      xi = &o13 '    8 + 3
      ci = &h65 ' 6*16 + 5
      MAX_Integer =  &o77777 '  32767 = &h7FFF
      MIN_Integer = &o100000 ' -32768 = &h8000
      MAX_Long = &h7fffffff '  2147483647 = &o17777777777
      MIN_Long = &h80000000 ' -2147483648 = &o20000000000

### អថេរ​ខ្សែ​អក្សរ

String variables can hold character strings with up to 2,147,483,648 characters. Each character is stored as the corresponding Unicode value. String variables are suitable for word processing within programs and for temporary storage of any non-printable character up to a maximum length of 2 Gbytes. The memory required for storing string variables depends on the number of characters in the variable. The type-declaration character is "$".

In BASIC String functions, the first character of the string has index 1.

    Dim Variable$
    Dim Variable As String

### អថេរ​ប៊ូលីន

អថេរ​ប៊ូលីន​ទុក​តែ​តម្លៃ​មួយ​នៃ​តម្លៃ​ពីរ ៖ ពិត ឬ​មិនពិត ។ លេខ ០ វាយតម្លៃ​ជា មិនពិត គ្រប់​តម្លៃ​ផ្សេង​ទៀត​វាយតម្លៃ​ជា ពិត ។

    Dim Variable As Boolean

### អថេរ​កាល​បរិច្ឆេទ

អថេរ​កាល​បរិច្ឆេទ​អាច​មាន​តែ​តម្លៃ​កាល​បរិច្ឆេទ និង​ពេល​វេលា​ដែល​រក្សា​ទុក​ក្នុង​ទ្រង់ទ្រាយ​ខាង​ក្នុង ។ តម្លៃ​ដែល​បាន​ផ្តល់​ទៅ​អថេរ​កាល​បរិច្ឆេទ​ជាមួយ Dateserial, Datevalue, Timeserial ឬTimevalue ត្រូវ​បាន​បម្លែង​ដោយ​ស្វ័យ​ប្រវត្តិ​ទៅ​ជា​ទ្រង់ទ្រាយ​ខាង​ក្នុង ។ អថេរ​កាល​បរិច្ឆេទ​ត្រូវ​បាន​បម្លែង​ជា​លេខ​ធម្មតា​ដោយ​ប្រើ​អនុគមន៍ Day, Month, Year ឬHour, Minute, Second ។ ទ្រង់ទ្រាយ​ខាង​ក្នុង​អាច​ធ្វើ​ឲ្យ​ប្រើ​បាន​ការ​ប្រៀបធៀប​នៃ​តម្លៃ​កាល​បរិច្ឆេទ​/​ពេល​វេលា ដោយ​គណនា​ភាព​ខុស​គ្នា​រវាង​ចំនួន​ពីរ ។ អថេរ​ទាំង​នេះ​អាច​ត្រូវ​បាន​ប្រកាស​តែ​ជាមួយ​ពាក្យ​គន្លឹះ Date ប៉ុណ្ណោះ ។

    Dim Variable As Date

### Literals for Dates

Date literals allow to specify unambiguous date variables that are independent from the current language. Literals are enclosed between hash signs #. Possible formats are:

- #yyyy-mm-dd#

- #mm/dd/yyyy#

      zeroDay = #12/30/1899#
      dob = #2010-09-28#

## The Variant type

Variables declared as Variant can handle any data type. This means that the actual data type is defined during runtime as a value is assigned to the variable.

There are three main ways to create a Variant variable, as shown below:

      Dim varA            ' The type is not specified, hence the variable is a Variant
      Dim varB as Variant ' The variable is explicitly declared as a Variant
      varC = "abc"        ' Previously undeclared variables are treated as Variants

The example below uses the TypeName function to show how the type of a Variant variable changes upon assignment.

      Dim myVar As Variant
      MsgBox TypeName(myVar) ' Empty
      myVar = "Hello!"
      MsgBox TypeName(myVar) ' String
      myVar = 10
      MsgBox TypeName(myVar) ' Integer

A Variant variable is initialized with the Empty special data type. You can use the IsEmpty function to test if a variable is an Empty Variant.

You can also use the keyword Any to declare a variable as a Variant. However, Any is deprecated and is available for backward compatibility.

Arguments with type Variant or Any passed in function calls are not checked for their types.

      Dim myVar As Any ' Variable "myVar" is a Variant

## តម្លៃ​​អថេរ​ដំបូង​

នៅ​ពេល​អថេរ​ត្រូវ​បាន​ប្រកាស វា​ត្រូវ​បាន​កំណត់​ដោយ​ស្វ័យ​ប្រវត្តិ​ទៅ​ជា​តម្លៃ "Null" ។ ចំណាំ​​ការ​​​សន្មត​​​ដូច​ខាង​ក្រោម ៖​

អថេរ ជា​លេខ ត្រូវ​បាន​ផ្តល់​តម្លៃ "0" ដោយ​ស្វ័យ​ប្រវត្តិ នៅ​ពេល​ពួក​វា​ត្រូវ​បាន​ប្រកាស ។

អថេរ​កាល​បរិច្ឆេទ ត្រូវ​បាន​ផ្តល់​តម្លៃ​ខាង​ក្នុង​គឺ 0 ដែល​សមមូល​ទៅ​នឹង​ការ​បម្លែង​តម្លៃ​ជា "0" ជាមួយ​អនុគមន៍ Day, Month, Year ឬ Hour, Minute, Second ។

អថេរ String ត្រូវ​បាន​ផ្តល់​តម្លៃ​ខ្សែ​អក្សរ​ទទេ ("") នៅ​ពេល​ពួក​វា​ត្រូវ​បាន​ប្រកាស ។

## អារេ

LibreOffice Basic ស្គាល់​អារេ​មួយ ឬ​ច្រើន​វិមាត្រ ដែល​កំណត់​ដោយ​​ប្រភេទ​អថេរ​បាន​បញ្ជាក់​​ ។ អារេ​គឺ​សមរម្យ សម្រាប់​កែ​សម្រួល​បញ្ជី និង​តារាង​ក្នុង​កម្មវិធី ។ ធាតុ​នីមួយ​ៗ​នៃ​អារេ អាច​ត្រូវ​បាន​ផ្តល់​ទីតាំង​តាម​រយៈ​សន្ទស្សន៍​ជា​លេខ ។

អារេ ត្រូវ​តែ ប្រកាស​ដោយ​ប្រើ Dim ។ មាន​វិធី​ជា​ច្រើន ដើម្បី​កំណត់​ជួរ​សន្ទស្សន៍​នៃ​អារេ​មួយ ៖

        Dim Text$(20)       '21 elements numbered from 0 to 20'
        Dim Text$(5,4)      '30 elements (a matrix of 6 x 5 elements)'
        Dim Text$(5 To 25)  '21 elements numbered from 5 to 25'
        Dim Text$(-15 To 5) '21 elements (including 0), numbered from -15 to 5'

ជួរ​សន្ទស្សន៍​អាច​រួមបញ្ចូល​នូវ​ចំនួន​វិជ្ជមាន ក៏​ដូចជា​ចំនួន​អវិជ្ជមាន ។

## ថេរ

Constants មាន​តម្លៃ​ថេរ ។ ពួក​វា​ត្រូវ​បាន​កំណត់​តែ​ម្តង​ប៉ុណ្ណោះ​ក្នុង​កម្មវិធី និង​មិន​អាច​កំណត់​ម្តង​ទៀត​នៅ​ពេល​ក្រោយ ៖

    Const ConstName=Expression

ប្រធានបទ​ទាក់ទង

Basic Constants

Dim Statement