Contents

# សញ្ញា​ប្រមាណ​វិធី​ក្នុ LibreOffice Calc

អ្នក​អាច​ប្រើ​សញ្ញា​ប្រមាណ​វិធី​ខាង​ក្រោម​ក្នុង LibreOffice Calc ៖

## សញ្ញា​ប្រមាណ​វិធី​នព្វន្ត

សញ្ញា​ប្រមាណ​វិធី​ទាំង​នេះ​ត្រឡប់​លទ្ធផល​​ជា​លេខ ។

សញ្ញា​​ប្រមាណ​វិធី | ឈ្មោះ | Example
--- | --- | ---
+ | វិធី​បូក | 1+1
- | វិធី​ដក | 2-1
- | អវិជ្ជមាន​កម្ម | -5
* | វិធី​គុណ | 2*2
/ | វិធី​ចែក | 9/3
% | ភាគរយ | 15%
^ | និទស្សន្តកម្ម | 3^2

Prefix "-" (negation) has a higher precedence than "^" (exponentiation). For example -3^2 equals 9, which is the square of a negative number.

B^X may or may not report a #NUM! error when B is negative and X is not an integer. The expression =B^X is calculated the same way as =POWER(B;X).

## សញ្ញា​ប្រមាណ​វិធី​ប្រៀបធៀប

សញ្ញា​ប្រមាណ​វិធី​ទាំង​នេះ​ត្រឡប់​ទាំង ពិត ឬ​មិន​ពិត ។

សញ្ញា​​ប្រមាណ​វិធី | ឈ្មោះ | Example
--- | --- | ---
= | ស្មើ | A1=B1
> | ធំ​ជាង | A1>B1
< | តូច​ជាង | A1<B1
>= | ធំជាង ឬ​ស្មើ | A1>=B1
<= | តូច​ជាង ឬ​ ស្មើ | A1<=B1
<> | មិន​ស្មើ | A1<>B1

## សញ្ញា​ប្រមាណ​វិធី​អត្ថបទ

សញ្ញា​ប្រមាណ​វិធី​ផ្សំ​អត្ថបទ​ដាច់​ពី​គ្នា ទៅ​ជា​អត្ថបទ​មួយ ។

សញ្ញា​​ប្រមាណ​វិធី | ឈ្មោះ | Example
--- | --- | ---
& | text concatenation | "Sun" & "day" គឺ "Sunday"

## សញ្ញា​ប្រមាណវិធី​សេចក្តី​យោង

ប្រតិបត្តិការ​ទាំងនេះ​ត្រឡប់​ជួរ​ក្រឡា​សូន្យ ក្រឡា​មួយ ឬ​ច្រើន ។

ជួរ​មាន​អាទិភាព​ខ្ពស់​បំផុត បន្ទាប់​មក​ប្រសព្វ និង​ព្យាយាម​ប្រជុំ​ចុងក្រោយ ។

សញ្ញា​​ប្រមាណ​វិធី | ឈ្មោះ | Example
--- | --- | ---
: | ជួរ | A1:C108, A:D or 3:13
! | ការ​ប្រសព្វ | SUM(A1:B6!B5:C12) គណនា​ផល​បូក​នៃ​ក្រឡា​ទាំងអស់​ក្នុង​ចំណុច​ប្រសព្វ ក្នុង​ឧទាហរណ៍​នេះ លទ្ធផល​បាន​មក​ពី​ផលបូក​នៃ​ក្រឡា ​B5 និង B6 ។

~

កាត់ឲ្យ​ខ្លី ឬ​ប្រជុំ

Takes two references and returns a reference list, which is a concatenation of the left reference followed by the right reference. Double entries are referenced twice.

=COUNT(A1:B2~B2:C3) counts values of A1:B2 and B2:C3. Note that the cell B2 is counted twice.

=INDEX(A1:B2~C1:D2;2;1;2) selects cell C2, that is, the first cell of the second row, first column, of the second range (C1:D2) of the range list.

A reference list is not allowed inside an array expression.

## Operator precedence

Associativity and precedence of operators, from highest to lowest precedence.

Associativity | Operator(s) | Comments
--- | --- | ---
left | : | Range.
left | ! | Reference intersection (A1:C4!B1:B5 is B1:B4).
left | ~ | Reference union.
right | +,- | Prefix unary operators. For example, -5 or -A1. Note that these have a different precedence than add and subtract.
left | % | Postfix unary operator % (divide by 100). Note that this is legal with expressions, for example, B1%.
left | ^ | Power (2^3 is 8).
left | *,/ | Multiply, divide.
left | +,- | Binary operations add, subtract. Note that unary (prefix) + and - have a different precedence.
left | & | Binary operation string concatenation. Note that "&" shall be escaped when included in an XML document.
left | =, <>, <, <=, >, >= | Comparison operators equal to, not equal to, less than, less than or equal to, greater than, greater than or equal to.

Prefix "-" has a higher precedence than "^", "^" is left-associative, and reference intersection has a higher precedence than reference union.

Prefix "+" and "-" are defined to be right-associative. However, note that typical applications which implement at most the operators defined in this specification (as specified) may implement them as left-associative, because the calculated results will be identical.

Precedence can be overridden by using parentheses, so "=2+3*4" computes to 14 but "=(2+3)*4" computes 20.

ប្រធានបទ​ទាក់ទង

OpenDocument v1.3 part 4, Formula Operators

Please support us!