Contenuto
Indice 🔎︎

# Funzione CreateUnoService

Crea un'istanza di un servizio Uno con il ProcessServiceManager.

### Sintassi:

oServizio = CreateUnoService(nome servizio UNO)

Per un elenco di tutti i servizi disponibili visitate la pagina della guida di riferimento del Modulo com::sun::star.

### Esempio:

L'esempio seguente crea la funzione FileExists che usa il servizio com.sun.star.ucb.SimpleFileAccess per controllare se il percorso indicato corrisponde a un file esistente.

        Function FileExists(sPath as String) as Boolean
            Dim svcSFA as Object
            Set svcSFA = CreateUnoService("com.sun.star.ucb.SimpleFileAccess")
            Dim bExists as Boolean : bExists = svcSFA.exists(sPath)
            Dim bIsFolder as Boolean : bIsFolder = svcSFA.IsFolder(sPath)
            FileExists = bExists And Not bIsFolder
        End Function

I servizi UNO sono dotati di un'estesa documentazione online sul sito api.libreoffice.org. Visitate la pagina della guida di riferimento del Servizio SimpleFileAccess per saperne di più sui metodi forniti dal servizio usato nell'esempio precedente.

### Esempio:

Il codice seguente usa il servizio com.sun.star.ui.dialogs.FilePicker per visualizzare una finestra di dialogo per l'apertura dei file:

    Sub Main
        fName = FileOpenDialog ("Selezionate un file")
        Print "file scelto: "+fName
    End Sub

    Function FileOpenDialog(title As String) As String
        res = com.sun.star.ui.dialogs.ExecutableDialogResults
        filepicker = createUnoService("com.sun.star.ui.dialogs.FilePicker")
        filepicker.Title = title
        If res.OK = filepicker.execute() Then
            files = filepicker.getSelectedFiles()
            FileOpenDialog=files(0)
        EndIf
    End Function

Argomenti correlati

Utilizzo delle funzioni di Calc nelle macro