Contenuto

# Funzione MEDIA.SE

Restituisce la media aritmetica di tutte le celle all'interno di un intervallo che soddisfi una determinata condizione. La funzione MEDIA.SE somma tutti i risultati che corrispondono al test logico e divide per la quantità dei valori selezionati.

La funzione è disponibile da LibreOffice 4.0.

### Sintassi

=MEDIA.SE(intervallo; criterio [; intervallo_media ])

Intervallo – argomento obbligatorio. Può essere una matrice, il nome di un'area indicata, la dicitura di una colonna o di una riga che contiene numeri per l'esecuzione della media oppure numeri o testo per la condizione.

Criterio1: un criterio è un'espressione testuale calcolata a partire dal riferimento, formula, numero o testo di una singola cella. Viene usato per i confronti con i contenuti della cella.

Un riferimento a una cella vuota viene interpretato come valore numerico 0.

Un'espressione che corrisponde può essere:

- Un numero o un valore logico. Un contenuto di cella individuato è uguale al numero o al valore logico.

- Un valore preceduto da un segno di comparazione (<, <=, =, >, >=, <>).

  L'=, se il valore è vuoto individua le celle vuote.

  Nel caso di <>, se il valore è vuoto individua le celle non vuote.

  Nel caso di <>, se il valore non è vuoto, individua qualsiasi contenuto delle celle ad eccezione del valore, incluse le celle vuote.

  Nota: "=0" non individua celle vuote.

  Nel caso di = e <>, se il valore non è vuoto e non può essere interpretato come di tipo Numero o uno dei suoi sottotipi e la proprietà I criteri di ricerca = e <> devono riferirsi a celle intere è attivata, il confronto viene eseguito con l'intero contenuto delle celle; mentre se è disattivata il confronto viene eseguito con qualsiasi sottoparte del campo che corrisponde ai criteri di ricerca. Nel caso di = e <> si applica se il valore non è vuoto e non può essere interpretato come di tipo Numero o uno dei suoi sottotipi.

- Valore Altro testo. Se la proprietà I criteri di ricerca = e <> devono riferirsi a celle intere è vera, il confronto è eseguito con l'intero contenuto delle celle; se è falsa il confronto viene eseguito con qualsiasi sottoparte del campo che corrisponde ai criteri. L'espressione può contenere testo, numeri, espressioni regolari o caratteri jolly, se questi ultimi sono abilitati nelle opzioni di calcolo.

La ricerca supporta i caratteri jolly o le espressioni regolari. Se queste ultime sono attivate, è possibile inserire "all.*" per trovare, ad esempio, la prima posizione di "all" seguito da qualsiasi carattere. Se si intende ricercare un testo che sia anche un'espressione regolare, è necessario far precedere sempre il metacarattere o l'operatore dell'espressione dal carattere "\", oppure racchiudere il testo tra \Q...\E. È possibile attivare o disattivare l'analisi dei caratteri jolly o delle espressioni regolari in LibreOffice - Preferenze Strumenti - Opzioni - LibreOffice Calc - Calcola.

Quando si utilizzano funzioni in cui uno o più argomenti sono stringhe di criteri di ricerca che rappresentano un'espressione regolare, innanzitutto si cerca di convertire i criteri della stringa in numeri. Per esempio, ".0" sarà convertito in 0.0 e così via. In caso di esito positivo, la corrispondenza non sarà quella di un'espressione regolare ma una corrispondenza numerica. Tuttavia, quando si passa a un'impostazione regionale in cui il separatore decimale non è il punto, tale passaggio fa funzionare la conversione in espressione regolare. Per forzare la valutazione dell'espressione regolare, anziché di quella numerica, utilizzare un'espressione che non possa essere erroneamente interpretata come numerica, per es., ".[0]", ".\0" oppure "(?i).0".

intervallo_media – argomento opzionale. È un intervallo di valori per il calcolo della media.

Se intervallo_media non è specificato, Intervallo viene utilizzato per entrambi il calcolo della media e la ricerca in base alla condizione. Se intervallo_media è specificato, Intervallo viene utilizzato solo per il test della condizione, mentre intervallo_media viene utilizzato per il calcolo della media.

Se all'interno di un intervallo di valori per il calcolo della media, una cella fosse vuota o contenesse del testo, la funzione AVERAGEIF ignorerebbe tale cella.
Se l'intero intervallo fosse vuoto, contenesse solo testo o tutti i valori al suo interno non soddisfassero la condizione (o qualsiasi loro combinazione), la funzione restituirebbe l'errore #DIV/0!.

### Esempi

Considerate la tabella seguente

| A | B | C
1 | Nome prodotto | Sales | Revenue
2 | matita | 20 | 65
3 | penna | 35 | 85
4 | notebook | 20 | 190
5 | libro | 17 | 180
6 | astuccio | non | non

In tutti gli esempi riportati sotto, gli intervalli per il calcolo contengono la riga #6, che viene ignorata poiché contiene testo.

#### Uso semplice

=MEDIA.SE(B2:B6;"<35")

Calcola la media per i valori dell'intervallo B2:B6, minori di 35. Restituisce 19, perché la seconda riga non è inclusa nel calcolo.

=MEDIA.SE(B2:B6;"<"&MAX(B2:B6))

Calcola la media per i valori dello stesso intervallo minori del valore massimo dello stesso intervallo. Restituisce 19, perché il valore maggiore (la seconda riga) non è incluso nel calcolo.

=MEDIA.SE(B2:B6;">"&PICCOLO(B2:B6;1))

Calcola la media per i valori dello stesso intervallo maggiori del primo valore più piccolo dello stesso intervallo. Restituisce 25, perché il primo valore più piccolo (la quarta riga) non è incluso nel calcolo.

#### Uso di intervallo_media

=MEDIA.SE(B2:B6;"<35";C2:C6)

La funzione ricerca quali valori sono minori di 35 all'interno dell'intervallo B2:B6, e calcola la media dei valori corrispondenti dall'intervallo C2:C6. Restituisce 145, perché la seconda riga non è inclusa nel calcolo.

=MEDIA.SE(B2:B6;">"&MIN(B2:B6);C2:C6)

La funzione ricerca quali valori dall'intervallo B2:B6 sono maggiori del valore minimo all'interno dell'intervallo B2:B6, e calcola la media dei valori corrispondenti dall'intervallo C2:C6. Restituisce 113,3, perché la quarta riga (in cui è presente il valore minimo all'interno dell'intervallo B2:B6) non è inclusa nel calcolo.

=MEDIA.SE(B2:B6;"<"&GRANDE(B2:B6;2);C2:C6)

La funzione ricerca quali valori dall'intervallo B2:B6 sono minori del secondo valore maggiore all'interno dell'intervallo B2:B6, e calcola la media dei valori corrispondenti dall'intervallo C2:C6. Restituisce 180, perché solo la quarta riga è inclusa nel calcolo.

#### Uso delle espressioni regolari

=MEDIA.SE(A2:A6;"pen";B2:B6)

La funzione ricerca quali celle dall'intervallo A2:A6 contengono la parola “pen”, e calcola la media dei valori corrispondenti dall'intervallo B2:B6. Restituisce 35, perché solo la seconda riga è inclusa nel calcolo. La ricerca è eseguita nell'intervallo A2:A6, ma vengono restituiti solo i valori dall'intervallo B2:B6.

=MEDIA.SE(A2:A6;"pen.*";B2:B6)

La funzione ricerca quali celle dall'intervallo A2:A6 iniziano con “pen”, e terminano con un qualsiasi altro numero di altri caratteri, e calcola la media dei valori corrispondenti dall'intervallo B2:B6. Restituisce 27,5, perché al momento solo “pencil” soddisfa la condizione, e sia la prima sia la seconda riga sono incluse nel calcolo.

=MEDIA.SE(A2:A6;".*book.*";B2:B6)

La funzione ricerca quali celle dall'intervallo A2:A6 iniziano con “book”, e iniziano e terminano con un qualsiasi altro numero di altri caratteri, e calcola la media dei valori corrispondenti dall'intervallo B2:B6. Restituisce 18,5, perché solo la terza e la quarta riga sono incluse nel calcolo.

#### Fare riferimento a una cella come criterio

Per cambiare in modo facile un criterio, potete specificarlo in una cella separata, utilizzando un riferimento alla cella all'interno della condizione della funzione MEDIA.SE.

=MEDIA.SE(A2:A6;".*"&E2&".*";B2:B6)

La funzione ricerca quali celle dall'intervallo A2:A6 contengono una combinazione di caratteri specificati in E2, che iniziano e terminano con un qualsiasi altro numero di altri caratteri, e calcola la media dei valori corrispondenti dall'intervallo B2:B6. Se E2 = book, la funzione restituisce 18,5.

=MEDIA.SE(B2:B6;"<"&E2;C2:C6)

La funzione ricerca quali celle dall'intervallo B2:A6 sono minori del valore specificato in E2, e calcola la media dei valori corrispondenti dall'intervallo C2:C6. Se E2 = 35, la funzione restituisce 145.

#### Informazioni tecniche

Questa funzione fa parte dell'Open Document Format for Office Applications (OpenDocument), versione standard 1.2 (ISO/IEC 26300:2-2015).

Argomenti correlati

Pagina wiki relativa a MEDIA.SE (in inglese).

MEDIA, MEDIA.VALORI, MEDIA.DEV

CONTA.PIÙ.SE, MIN.PIÙ.SE, MAX.PIÙ.SE, MEDIA.PIÙ.SE, SOMMA.PIÙ.SE

Elenco delle espressioni regolari

Sostienici!