Contenu
Index 🔎︎

# Fonctions de classeur

Cette section contient une description des fonctions du Classeur ainsi qu'un exemple.

Pour accéder à cette commande...

Insertion - Fonction - Catégorie Classeur

## TYPE.ERREUR

Renvoie un nombre représentant un type d'erreur spécifique ou la valeur d'erreur #N/A s'il n'y a pas d'erreur.

## ADRESSE

Renvoie une adresse de cellule (référence) en tant que texte, en fonction des numéros de ligne et de colonne spécifiés. Vous pouvez déterminer si l'adresse doit être interprétée en tant qu'adresse absolue (par exemple $A$1), ou en tant qu'adresse relative (par exemple A1) ou sous forme mixte (A$1 ou $A1). Vous pouvez également spécifier le nom de la feuille.

Pour des raisons d'interopérabilité, les fonctions ADRESSE et INDIRECT prennent en charge un paramètre facultatif afin de spécifier si la notation d'adresse L1C1 doit être utilisée à la place de la notation A1 habituelle.

Pour ADRESSE, le paramètre est inséré comme le quatrième paramètre, renvoyant le paramètre facultatif de nom de feuille à la cinquième position.

Pour INDIRECT, le paramètre est ajouté comme le second paramètre.

Pour les deux fonctions, si l'argument est inséré avec la valeur 0, alors la notation L1C1 est utilisée. Si l'argument n'est pas donné ou a une valeur autre que 0, alors la notation A1 est utilisée.

Dans le cas de la notation L1C1, ADRESSE renvoie les chaînes d'adresse en utilisant le point d'exclamation '!' comme séparateur de noms de feuilles, et INDIRECT attend le point d'exclamation comme séparateur de noms de feuilles. Les deux fonctions utilisent toujours le point '.' séparateur de noms de feuilles avec la notation A1.

À l'ouverture de documents au format ODF 1.0/1.1, les fonctions ADRESSE qui affichent un nom de feuille comme quatrième paramètre renverront ce nom de feuille pour qu'il devienne le cinquième paramètre. Un nouveau quatrième paramètre ayant la valeur 1 sera inséré.

Lors du stockage d'un document au format ODF 1.0/1.1, si des fonctions ADRESSE ont un quatrième paramètre, ce paramètre sera supprimé.

N'enregistrez pas un classeur dans l'ancien format ODF 1.0/1.1 si le nouveau quatrième paramètre de la fonction ADRESSE a été utilisé avec une valeur de 0.

La fonction INDIRECT est enregistrée sans conversion au format ODF 1.0/1.1. Si le second paramètre était présent, une version plus ancienne de Calc renverra une erreur pour cette fonction.

#### Syntaxe

ADRESSE(ligne;colonne[;ABS[;A1[;"Feuille"]]])

ligne représente le numéro de ligne de la référence de la cellule

colonne représente le numéro de colonne de la référence de la cellule (le numéro, pas la lettre)

ABS détermine le type de référence :

1 : absolue ($A$1)

2 : le type de référence de ligne est absolue ; la référence de colonne relative (A$1)

3 : ligne (relative), colonne (absolue) ($A1)

4 : relative (A1)

A1 (facultatif) - si paramétré sur 0, la notation L1C1 est utilisée. Si ce paramètre est absent ou paramétré sur une autre valeur que 0, la notation A1 est utilisée.

Feuille représente le nom de la feuille. Il doit être placé entre des guillemets doubles.

### Exemple :

=ADRESSE(1;1;2;;"Feuille2") renvoie : Feuille2.A$1

Si la formule au-dessus est dans la cellule B2 de la feuille active et que la cellule A1 de la feuille 2 contient la valeur -6, vous pouvez référer indirectement à la cellule référencée en utilisant la fonction en B2 en saisissant =ABS(INDIRECT(B2)). Le résultat est la valeur absolue de la cellule référencée spécifiée en B2, qui dans ce cas est 6.

## CHOISIR

Utilise un index qui renvoie la valeur à partir d'une liste de 30 valeurs.

#### Syntaxe

CHOISIR(index;valeur1[;valeur2[;...[;valeur30]]])

index est une référence ou un nombre entre 1 et 30 indiquant quelle valeur doit être prise dans la liste.

valeur1;valeur2;...;valeur30 est la liste des valeurs saisies comme référence à une cellule ou comme valeurs individuelles.

#### Exemple

=CHOISIR(A1;B1;B2;B3;"Aujourd'hui";"Hier";"Demain"), par exemple, renvoie le contenu de la cellule B2 pour A1 = 2; pour A1 = 4, la fonction renvoie le texte "Aujourd'hui".

## COLONNE

Renvoie le numéro de colonne d'une référence à une cellule. Si la référence est une cellule, le numéro de colonne de la cellule est renvoyé. Si le paramètre est une zone de cellule, les numéros de colonne correspondants sont renvoyés dans une matrice à ligne unique si la formule est saisie en tant que formule de matrice. Si la fonction COLONNE n'est pas utilisée avec un paramètre de référence de zone pour une formule de matrice, seul le numéro de colonne de la première cellule de la zone est déterminé.

#### Syntaxe

COLONNE([référence])

référence est la référence à une plage de cellules dont les numéros de colonnes doivent être déterminés. L'argument peut également correspondre à une cellule unique.

Si aucune référence n'est spécifiée, le numéro de colonne déterminé est celui de la cellule dans laquelle est spécifiée la formule. LibreOffice Calc définit automatiquement la référence à la cellule active.

#### Exemple

=COLONNE(A1) égale 1. Colonne A est la première colonne de la table.

=COLONNE(C3:E3) égale 3. La colonne C est la troisième colonne de la table.

=COLONNE(D3:G10) renvoie 4 parce que la colonne D est la quatrième colonne de la table et la fonction COLONNE n'est pas utilisée comme une formule matricielle (dans ce cas, la première valeur de la matrice est toujours utilisée comme résultat).

{=COLONNE(B2:B7)} et =COLONNE(B2:B7)renvoient toutes deux 2 parce que la référence contient seulement la colonne B comme seconde colonne de la table. Parce que les zones à une seule colonne n'ont qu'un numéro de colonne, il n'y a pas de différence que la formule soit ou non utilisée dans une formule matricielle.

=COLONNE() renvoie 3 si la formule a été saisie dans la colonne C.

{=COLONNE(Lapin)} renvoie la seule ligne de matrice (3, 4) si "Lapin" est la zone nommée (C1:D3).

## COLONNES

Renvoie le nombre de colonnes dans la référence donnée.

#### Syntaxe

COLONNES(matrice)

matrice est la référence à une plage de cellules dont le nombre total de colonnes doit être trouvé. L'argument peut aussi être une seule cellule.

#### Exemple

=COLONNES(B5) renvoie 1 parce qu'une seule cellule contient une colonne.

=COLONNES(A1:C5) égale 3. La référence comprise entre trois colonnes.

=COLONNES(Lapin) renvoie 2 si Lapin est la plage nommée (C1:D3).

## DDE

Renvoie le résultat d'un lien DDE. Si le contenu de la plage ou de la section liée est modifié, la valeur renvoyée change également. Vous devez charger à nouveau la feuille de calcul ou choisir Édition - Liens pour visualiser les liens mis à jour. Les liens multi-plateforme ne sont pas autorisés, par exemple entre une installation LibreOffice fonctionnant sur une machine équipée de Windows et un document créé sur Linux.

#### Syntaxe

DDE("serveur";"fichier";"plage"[;mode])

serveur est le nom d'une application de serveur ; dans le cas des applications LibreOffice, il s'agit de "soffice".

fichier est le nom du fichier avec le chemin complet.

plage est la zone contenant les données à évaluer.

mode est un paramètre facultatif définissant la méthode par laquelle le serveur DDE convertit ses données en nombres.

Mode | Effet
0 ou vide | Format numérique à partir du style de cellule "Par défaut"
1 | Les données sont toujours interprétées sur la base du format standard pour l'anglais US
2 | Les données sont appliquées comme du texte, sans conversion en nombres

#### Exemple

=DDE("soffice";"c:\office\document\données1.ods";"feuille1.A1") lit le contenu de la cellule A1 de la feuille 1 du classeur LibreOffice Calc données1.ods.

=DDE("soffice";"c:\office\document\devinette.odt";"Devinette du jour") renvoie une devinette dans la cellule contenant cette formule. Vous devez d'abord saisir une ligne dans le document devinette.odt contenant le texte de la devinette et la définir comme la première ligne d'une section nommée Devinette du jour (dans LibreOffice Writer sous Insertion - Section). Si la devinette est modifiée (et enregistrée) dans le document LibreOffice Writer, la devinette est mise à jour dans toutes les cellules LibreOffice Calc dans lesquelles ce lien DDE est défini.

## DECALER

Renvoie la valeur correspondant à un décalage de cellule d'un certain nombre de lignes et de colonnes à partir d'un point de référence donné.

Cette fonction est toujours recalculée à chaque fois qu'un recalcul se produit

#### Syntaxe

DECALER(référence;lignes;colonnes[;hauteur[;largeur]])

référence est la référence à partir de laquelle la fonction recherche la nouvelle référence.

lignes est le nombre de lignes par lequel la référence a été corrigée au-dessus (valeur négative) ou en-dessous. Utilisez 0 pour rester dans la même ligne.

colonnes est le nombre de colonnes par lequel la références a été corrigée vers la gauche (valeur négative) ou vers la droite. Utilisez 0 pour rester dans la même colonne.

hauteur (facultatif) est la hauteur verticale pour une zone qui débute à la nouvelle position de la référence.

largeur (facultatif) est la largeur horizontale pour une zone qui débute à la nouvelle position de la référence.

Les arguments lignes et colonnes ne doivent pas mener à zéro ou à un début négatif de colonne ou de ligne.

Les argument hauteur et largeur ne doivent pas mener à zéro ou à un compte négatif de colonnes ou de lignes.

Dans les fonctions LibreOffice Calc, les paramètres marqués comme "facultatifs" peuvent être ignorés lorsqu'ils ne sont pas suivis d'autres paramètres. Par exemple, dans une fonction comportant quatre paramètres, où les deux derniers paramètres sont marqués comme "facultatifs", le paramètre 4 ou les paramètres 3 et 4 peuvent être ignorés, mais le paramètre 3 seul ne peut être ignoré.

#### Exemple

=DECALER(A1;2;2) renvoie la valeur de la cellule C3 (A1 déplacé de deux lignes et deux colonnes vers le bas). Si C3 contient la valeur 100 cette fonction renvoie la valeur 100.

=DECALER(B2:C3;1;1) renvoie une référence à B2:C3 déplacée vers le bas d'une ligne et d'une colonne vers la droite (C3:D4).

=DECALER(B2:C3;-1;-1) renvoie une référence à B2:C3 déplacée vers le haut d'une ligne et d'une colonne vers la gauche (A1:B2).

=DECALER(B2:C3;0;0;3;4) renvoie une référence à B2:C3 redimensionnée de 3 lignes et 4 colonnes (B2:E4).

=DECALER(B2:C3;1;0;3;4) renvoie une référence à B2:C3 déplacée vers le bas d'une ligne redimensionnée de 3 lignes et 4 colonnes (B3:E5).

=SOMME(DECALER(A1;2;2;5;6)) détermine le total de la zone qui démarre en cellule C3 et a une hauteur de 5 lignes et une largeur de 6 colonnes (zone = C3:H7).

Si Largeur ou Hauteur sont donnés, la fonction DECALER revoie une référence de plage de cellules. Si Référence est une référence de cellule unique et que Largeur et Hauteur sont omis, une référence de cellule unique est renvoyée.

## EQUIV

Renvoie la position relative d'un élément dans une matrice correspondant à une valeur spécifiée. La fonction renvoie la position de la valeur trouvée en tant que nombre dans la recherche de la matrice.

#### Syntaxe

EQUIV(recherche;matrice_critère_recherche[;type])

recherche est la valeur qui doit être recherchée pour une ligne seule ou une colonne seule de la matrice.

matrice_cherchée est la référence recherchée. Une matrice recherchée peut être une ligne ou une colonne seule, ou une partie d'une ligne ou d'une colonne seule.

type peut prendre la valeur 1, 0 ou -1. Si Type = 1 ou si ce paramètre facultatif est manquant, il est supposé que la première colonne de la matrice de recherche est triée par ordre croissant. Si Type = -1, il est supposé que la colonne est triée par ordre décroissant. Cela correspond à la même fonction dans Microsoft Excel.

Si type = 0 seules les correspondances exactes sont trouvées. Si le critère de recherche est trouvé plus d'une fois, la fonction renvoie l'index de la première valeur correspondance. Vous pouvez rechercher des expressions régulières ou des caractères génériques (si activés dans les options de calcul) uniquement si type =0.

Si Type = 1 ou si le troisième paramètre est manquant, l'index de la dernière valeur inférieure ou égale au critère de recherche est renvoyé. Pour Type = -1, l'index de la dernière valeur supérieure ou égale est renvoyé.

La recherche prend en charge les caractères génériques ou les expressions régulières . Lorsque les expressions régulières sont activées, vous pouvez saisir "tous. *", Par exemple pour trouver le premier emplacement de "tous" suivi de n'importe quel caractère. Si vous souhaitez rechercher un texte qui est également une expression régulière, vous devez soit précéder chaque caractère d'un caractère "\", soit placer le texte dans \Q ...\E. Vous pouvez activer ou désactiver l'évaluation automatique des caractères génériques ou des expressions régulières dans LibreOffice - Préférences Outils - Options - LibreOffice Calc - Calculer .

Lorsque vous utilisez des fonctions où un ou plusieurs arguments sont des chaînes de critères de recherche qui représentent une expression régulière, la première tentative consiste à convertir les critères de chaîne en nombres. Par exemple, ".0" se convertira en 0.0 et ainsi de suite. En cas de succès, la correspondance ne sera pas une correspondance d'expression régulière mais une correspondance numérique. Cependant, lorsque vous passez à un environnement local où le séparateur décimal n'est pas le point, la conversion d'expression régulière fonctionne. Pour forcer l'évaluation de l'expression régulière au lieu d'une expression numérique, utilisez une expression qui ne peut pas être mal interprétée comme numérique, telle que ". [0]" ou ".\0" ou "(?I) .0".

#### Exemple

=EQUIV(200;D1:D100) recherche la valeur 200 dans la zone D1:D100 qui est stockée dans la colonne D. Aussitôt que la valeur est atteinte, le numéro de la ligne dans laquelle elle a été trouvée est renvoyé. Si une valeur supérieure est trouvée pendant la recherche dans la colonne, le numéro de la ligne précédente est renvoyé.

## EXTRAIRE.DONNEES.PILOTE

La fonction EXTRAIRE.DONNEES.PILOTE renvoie une valeur de résultat d'une table dynamique. La valeur est adressée en utilisant des noms de champ et d'élément, elle reste donc valide si la mise en page de la table dynamique est modifiée.

#### Syntaxe

Deux définitions de syntaxe différentes peuvent être utilisées :

EXTRAIRE.DONNEES.PILOTE(champ_cible;table croisée[;champ1; élément1][;...[champ126;élément126]])

ou

EXTRAIRE.DONNEES.PILOTE(table dynamique;contraintes)

La seconde syntaxe est supposée si deux paramètres exactement sont donnés, dans lesquels le premier paramètre est une cellule ou une référence de plage de cellule. La première syntaxe est supposée dans tous les autres cas. L'assistant de fonctions montre la première syntaxe.

### Première syntaxe

champ_cible est une chaîne qui sélectionne l'un des champs de données de la table dynamique. La chaîne peut être le nom de la colonne source, ou le nom de champ de données comme affiché dans la table (comme "Somme-Ventes").

table dynamique est une référence à une cellule ou plage de cellules qui est positionnée à l'intérieur d'une table dynamique ou contient une table dynamque. Si la plage de cellules contient plusieurs tables dynamique, la table qui a été créée en dernier est utilisée.

Si aucune paire Champ n/ Élément n n'est donnée, le grand total est renvoyé. Sinon, chaque paire ajoute la contrainte que le résultat doit être satisfait. Champ n est le nom d'un champ de la table dynamique. Élément n est le nom d'un élément de ce champ.

Si la table dynamique contient une valeur de résultat unique qui répond à toutes les contraintes, ou un résultat de sous-total qui résume toutes les valeurs correspondantes, ce résultat est renvoyé. S'il n'y a pas de résultat correspondant, ou plusieurs résultats sans sous-total pour eux, une erreur est renvoyée. Ces conditions s'appliquent aux résultats qui sont inclus dans la table dynamique.

Si la source de données contient des entrées qui sont cachées par des paramètres de la table dynamique, ils sont ignorés. L'ordre des paires Champ/Élément est significatif. Les noms du champ et de l'élément ne sont pas sensibles à la casse.

Si aucune contrainte pour de filtre n'est donnée, la valeur de champ sélectionnée est implicitement utilisée. Si une contrainte de filtre est donnée, elle doit correspondre à la valeur de champ sélectionnée, sinon une erreur est renvoyée. Les filtres sont les champs en haut à gauche d'une table dynamique, peuplés en utilisant la zone "Filtres" de la boîte de dialogue de mise en page d'une table dynamique. Pour chaque filtre, un élément (valeur) peut être sélectionné, ce qui signifie que seul cet élément est inclus dans le calcul.

Les valeurs de sous-total de la table dynamique sont utilisées uniquement si elles utilisent la fonction "auto" (excepté lorsque spécifié dans la contrainte, voir Seconde syntaxe ci-dessous)."

### Seconde syntaxe

table dynamique a la même signification que dans la première syntaxe.

contraintes est une liste séparée par des espaces. Les entrées peuvent contenir des guillemets (guillemets simples). Toute la chaîne doit être entre guillemets (guillemets doubles), à moins de référencer la chaîne à partir d'une autre cellule.

Une des entrées peut être le nom de champ de données. Le nom de champ de données peut être ignoré si la table dynamique contient un champ de données unique, sinon il doit être présent.

Chacune des autres entrées spécifie une contrainte de la forme Champ[Élément] (avec le caractère littéral [ et ]) ou seulement Élément si le nom de l'élément est unique à travers tous les champs qui sont utilisés dans la table dynamique.

Un nom de fonction peut être ajouté de la forme Champ[élément;fonction] qui entraînera la contrainte de faire correspondre seulement les valeurs de sous-total qui utilisent cette fonction. Les noms possibles de la fonction sont Somme, Nombre, Moyenne, Max, Min, Produit, Nombre (seulement), BDECARTYPE (échantillon), BDECARTYPEP (population), VAR (échantillon) et VARP (population), la casse n'est pas sensible.

## FEUILLE

Renvoie le nombre de feuilles d'une référence ou d'une chaîne représentant le nom d'une feuille. Si aucun paramètre n'est spécifié, le résultat est le numéro de la feuille de calcul dans laquelle figure la formule.

#### Syntaxe

FEUILLE([référence])

référence est facultatif et constitue la référence à une cellule, à une zone ou à une chaîne de nom de feuille.

#### Exemple

=FEUILLE(Feuille2.A1) renvoie 2 si Feuille2 est la seconde feuille du document classeur.

=FEUILLE("Feuille3") renvoie 3 si Feuille3 est la troisième feuille du classeur.

## FEUILLES

Détermine le nombre de feuilles dans une référence. Si vous ne saisissez aucun de ces paramètres, le résultat correspondra au nombre de feuilles du document actif.

#### Syntaxe

FEUILLES([référence])

référence est la référence à une feuille ou à une zone. Ce paramètre est facultatif.

#### Exemple

=FEUILLES(Feuille1.A1:Feuille3.G12) renvoie 3 si feuille1, feuille2 et feuille3 existent dans la séquence indiquée.

## INDEX

INDEX renvoie une sous plage, spécifiée par le numéro de colonne et de ligne, ou un index de plage facultatif. En fonction du contexte, INDEX renvoie une référence ou du contenu.

#### Syntaxe

INDEX(référence[;ligne[;colonne[;plage]]])

Référence est une référence, saisie soit directement ou en spécifiant le nom d'une plage. Si la référence consiste en des plages multiples, vous devez mettre la référence ou le nom de la plage entre parenthèses.

Ligne (facultatif) représente l'index de la ligne de la plage de référence pour laquelle une valeur est renvoyée. Dans le cas de zéro (pas de ligne spécifique) toutes les lignes référencées sont renvoyées.

Colonne (facultatif) représente l'index de la colonne de la plage de références pour laquelle une valeur est renvoyée. Dans le cas de zéro (pas de colonne spécifique) toutes les colonnes référencées sont renvoyées.

Plage (facultatif) représente l'index de la sous plage si elle réfère à une plage multiple.

#### Exemple

=INDEX(Prix;4;1) renvoie la valeur de la ligne 4 et de la colonne 1 de plage de base de données définie dans Données - Définir comme Prix.

=INDEX(SommeX;4;1) renvoie la valeur de la plage SommeX dans la ligne 4 et la colonne 1 comme définie dans Feuille - Plages nommées et expressions - Définir.

=INDEX(A1:B6;1) renvoie une référence à la première ligne de A1:B6.

=INDEX(A1:B6;0;1) renvoie une référence à la première colonne de A1:B6.

=INDEX((multi);4;1) indique la valeur contenue dans la ligne 4 et la colonne 1 de la plage (multiple) que vous avez nommée sous Feuille - Plages nommées et expressions - Définir comme multi. La plage multiple peut être constituée de plusieurs plages rectangulaires, chacune d'une ligne 4 et d'une colonne 1. Si vous souhaitez maintenant appeler le second bloc de cette plage multiple saisissez le nombre 2 comme paramètre de plage.

=INDEX(A1:B6;1;1) indique la valeur en haut à gauche de la plage A1:B6.

=INDEX((multi);0;0;2) renvoie une référence à la seconde plage d'une plage multiple.

## INDIRECT

Renvoie la référence spécifiée par une chaîne de texte. Cette fonction peut également renvoyer la zone d'une chaîne correspondante.

Cette fonction est toujours recalculée à chaque fois qu'un recalcul se produit

Pour des raisons d'interopérabilité, les fonctions ADRESSE et INDIRECT prennent en charge un paramètre facultatif afin de spécifier si la notation d'adresse L1C1 doit être utilisée à la place de la notation A1 habituelle.

Pour ADRESSE, le paramètre est inséré comme le quatrième paramètre, renvoyant le paramètre facultatif de nom de feuille à la cinquième position.

Pour INDIRECT, le paramètre est ajouté comme le second paramètre.

Pour les deux fonctions, si l'argument est inséré avec la valeur 0, alors la notation L1C1 est utilisée. Si l'argument n'est pas donné ou a une valeur autre que 0, alors la notation A1 est utilisée.

Dans le cas de la notation L1C1, ADRESSE renvoie les chaînes d'adresse en utilisant le point d'exclamation '!' comme séparateur de noms de feuilles, et INDIRECT attend le point d'exclamation comme séparateur de noms de feuilles. Les deux fonctions utilisent toujours le point '.' séparateur de noms de feuilles avec la notation A1.

À l'ouverture de documents au format ODF 1.0/1.1, les fonctions ADRESSE qui affichent un nom de feuille comme quatrième paramètre renverront ce nom de feuille pour qu'il devienne le cinquième paramètre. Un nouveau quatrième paramètre ayant la valeur 1 sera inséré.

Lors du stockage d'un document au format ODF 1.0/1.1, si des fonctions ADRESSE ont un quatrième paramètre, ce paramètre sera supprimé.

N'enregistrez pas un classeur dans l'ancien format ODF 1.0/1.1 si le nouveau quatrième paramètre de la fonction ADRESSE a été utilisé avec une valeur de 0.

La fonction INDIRECT est enregistrée sans conversion au format ODF 1.0/1.1. Si le second paramètre était présent, une version plus ancienne de Calc renverra une erreur pour cette fonction.

#### Syntaxe

INDIRECT(réf[;A1])

réf représente la référence à une cellule ou à une zone (dans un formulaire de texte) dont le contenu doit être renvoyé.

A1 (facultatif) - si paramétré sur 0, la notation L1C1 est utilisée. Si ce paramètre est absent ou paramétré sur une autre valeur que 0, la notation A1 est utilisée.

Si vous ouvrez un classeur Excel qui utilise des adresses indirectes calculées à partir de fonctions de chaîne, les adresses des feuilles ne seront pas traduites automatiquement. Par exemple, l'adresse Excel dans INDIRECT("[nomfichier]nomfeuille!"&B1) n'est pas convertie en une adresse Calc dans INDIRECT("nomfichier#feuille."&B1).

#### Exemple

=INDIRECT(A1) égale 100 si A1 contient C108 comme référence et la cellule C108 contient la valeur100.

=SOMME(INDIRECT("a1:" & ADRESSE(1;3))) totalise les cellules dans la zone A1 jusqu'à la cellule dont l'adresse est définie par la ligne 1 et la colonne 3. Cela signifie que la zone A1:C1 est totalisée.

## LIEN.HYPERTEXTE

Lorsque vous cliquez sur une cellule qui contient la fonction LIEN.HYPERTEXTE, le lien hypertexte s'ouvre.

Si vous utilisez le paramètre facultatif texte_cellule, la formule localise l'URL et affiche le texte ou le nombre.

Vous pouvez ouvrir une cellule contenant un hyperlien en utilisant le clavier. Pour ce faire, sélectionnez la cellule, appuyez sur F2 pour activer le mode d'édition, déplacez le curseur devant l'hyperlien, appuyez sur Maj+F10, puis choisissez Ouvrir l'hyperlien.

#### Syntaxe

HYPERLIEN("URL"[;"texte_cellule"])

URL spécifie la cible du lien. Le paramètre facultatif texte_cellule est le texte qui est affiché dans la cellule et le résultat de la fonction. Si le paramètre texte_cellule n'est pas spécifié, l'URL est affiché dans le texte de la cellule et dans le résultat de la fonction.

Le chiffre 0 est renvoyé pour les cellules vides et les éléments de matrice.

#### Exemple

=LIEN.HYPERTEXTE("http://www.exemple.org") affiche le texte "http://www.exemple.org" dans la cellule et et exécute le lien hypertexte lorsqu'il est cliqué.

=LIEN.HYPERTEXTE("http://www.exemple.org";"Cliquez ici") affiche le texte "cliquez ici" dans la cellule exécute le lien hypertexte http://www.exemple.org lorsqu'il est cliqué.

=LIEN.HYPERTEXTE("http://www.exemple.org";12345) affiche le nombre 12345 et exécute le lien hypertexte http://www.exemple.org lorsqu'il est cliqué.

=LIEN.HYPERTEXTE($B4) où la cellule B4 contient http://www.exemple.org. La fonction ajoute http://www.exemple.org à l'URL de la cellule contenant le lien et renvoie le même texte qui est utilisé comme résultat de la formule.

=LIEN.HYPERTEXTE("http://www.";"Cliquer sur") & "exemple.org" affiche le texte Cliquer sur exemple.org dans la cellule et exécute le lien hypertexte http://www.exemple.org lorsque cliqué.

=LIEN.HYPERTEXTE("#Feuille1.A1";"Aller en haut") affiche le texte Aller en haut et saute à la cellule Feuille1.A1 dans le document.

=LIEN.HYPERTEXTE("file:///C:/writer.odt#Spécification";"Aller au repère de texte Writer") affiche le texte Aller au repère de texte Writer, charge le document texte spécifié et atteint le repère de texte "Spécification".

=HYPERLINK("file:///C:/Documents/";"Ouvrir le dossier des documents") affiche le texte "Ouvrir le dossier des documents" et affiche le contenu du dossier en utilisant le gestionnaire de fichiers standards du système d'exploitation.

## LIGNE

Renvoie le numéro de ligne d'une référence à une cellule. Si la référence est une cellule, le numéro de ligne de la cellule est renvoyé. Si la référence est une plage de cellules, les numéros de ligne correspondants sont renvoyés dans une matrice à colonne unique si la formule est saisie en tant que formule de matrice. Si la fonction LIGNE contenant une référence à une plage n'est pas utilisée dans une formule de matrice, seul le numéro de ligne de la première cellule de la plage est renvoyé.

#### Syntaxe

LIGNE([référence])

référence est une cellule, une zone ou le nom d'une zone.

Si aucune référence n'est indiquée, le numéro de ligne déterminé est celui de la cellule dans laquelle est spécifiée la formule. LibreOffice Calc définit automatiquement la référence à la cellule active.

#### Exemple

=LIGNE(B3) renvoie 3 parce que la référence réfère à la troisième ligne de la table.

{=LIGNE(D5:D8)} renvoie la matrice d'une colonne seule (5, 6, 7, 8) parce que la référence spécifiée contient 5 lignes par 8.

=LIGNE(D5:D8) renvoie 5 parce que la fonction LIGNE n'est pas utilisée comme formule matricielle et seul le numéro de la première ligne de la référence est renvoyé.

{=LIGNE(A1:E1)} et =LIGNE(A1:E1) renvoient toutes deux 1 parce que la référence contient uniquement la ligne 1 comme première colonne dans la table (parce que seules les zones à une ligne unique ont un numéro de ligne, cela ne fait pas de différence que la formule soit utilisée comme formule matricielle ou non).

=LIGNE() renvoie 3 si la formule a été saisie dans la ligne 3.

{=LIGNE(Lapin)} renvoie la matrice d'une seule ligne (1, 2, 3) si "Lapin" est la zone nommée (C1:D3).

## LIGNES

Renvoie le nombre de lignes dans une référence ou dans une matrice.

#### Syntaxe

LIGNES(matrice)

matrice est la référence ou la zone nommée dont le nombre total de lignes doit être déterminé.

#### Exemple

=LIGNES(B5) renvoie 1 parce qu'une seule cellule contient seulement une ligne.

=LIGNES(A10:B12) renvoie 3.

=LIGNES(Lapin) renvoie 3 si "Lapin" est la zone nommée (C1:D3).

## RECHERCHE

Renvoie le contenu d'une cellule aussi bien pour une plage d'une colonne seule ou d'une ligne seule. Facultativement, la valeur assignée (du même index) est renvoyée dans une colonne et une ligne différente. À l'opposé de RECHERCHEV et RECHERCHEH, les vecteurs de recherche et de résultat peuvent être à des positions différentes ; ils n'ont pas à être adjacents. De plus, le vecteur de recherche pour RECHERCHE doit être trié en ordre croissant, sinon la recherche ne renvoie aucun résultat exploitable.

Si la fonction RECHERCHE ne trouve pas le critère de recherche, elle renvoie la valeur la plus grande (inférieure ou égale au critère de recherche) trouvée dans le vecteur de recherche.

La recherche prend en charge les caractères génériques ou les expressions régulières . Lorsque les expressions régulières sont activées, vous pouvez saisir "tous. *", Par exemple pour trouver le premier emplacement de "tous" suivi de n'importe quel caractère. Si vous souhaitez rechercher un texte qui est également une expression régulière, vous devez soit précéder chaque caractère d'un caractère "\", soit placer le texte dans \Q ...\E. Vous pouvez activer ou désactiver l'évaluation automatique des caractères génériques ou des expressions régulières dans LibreOffice - Préférences Outils - Options - LibreOffice Calc - Calculer .

Lorsque vous utilisez des fonctions où un ou plusieurs arguments sont des chaînes de critères de recherche qui représentent une expression régulière, la première tentative consiste à convertir les critères de chaîne en nombres. Par exemple, ".0" se convertira en 0.0 et ainsi de suite. En cas de succès, la correspondance ne sera pas une correspondance d'expression régulière mais une correspondance numérique. Cependant, lorsque vous passez à un environnement local où le séparateur décimal n'est pas le point, la conversion d'expression régulière fonctionne. Pour forcer l'évaluation de l'expression régulière au lieu d'une expression numérique, utilisez une expression qui ne peut pas être mal interprétée comme numérique, telle que ". [0]" ou ".\0" ou "(?I) .0".

#### Syntaxe

RECHERCHE(critère_recherche;vecteur_recherche[;vecteur_résultat])

critère_recherche est la valeur de n'importe quel type à rechercher ; saisie soit directement soit comme une référence.

vecteur_cherché est la zone d'une ligne seule ou d'une colonne seule à rechercher.

vecteur_résultat est une autre plage d'une ligne seule ou d'une colonne seule d'où le résultat de la fonction est pris. Le résultat est la cellule du vecteur de résultat avec le même index que l'instance trouvée dans le vecteur de recherche.

Traitement des cellules vides

#### Exemple

=RECHERCHE(A1;D1:D100;F1:F100) recherche la cellule correspondante dans la plage D1:D100 pour le nombre saisi en A1. Pour l'instance trouvée, l'index est déterminé, par exemple, la douzième cellule dans la plage. Puis, le contenu de la douzième cellule est renvoyé comme la valeur de la fonction (dans le vecteur de résultat).

## RECHERCHEH

Effectue la recherche d'une valeur et d'une référence aux cellules situées sous la zone sélectionnée. Cette fonction vérifie si la première ligne d'une matrice comporte une valeur spécifique. La fonction renvoie alors la valeur dans une ligne de la matrice, nommée dans la même colonne de l'index.

La recherche prend en charge les caractères génériques ou les expressions régulières . Lorsque les expressions régulières sont activées, vous pouvez saisir "tous. *", Par exemple pour trouver le premier emplacement de "tous" suivi de n'importe quel caractère. Si vous souhaitez rechercher un texte qui est également une expression régulière, vous devez soit précéder chaque caractère d'un caractère "\", soit placer le texte dans \Q ...\E. Vous pouvez activer ou désactiver l'évaluation automatique des caractères génériques ou des expressions régulières dans LibreOffice - Préférences Outils - Options - LibreOffice Calc - Calculer .

Lorsque vous utilisez des fonctions où un ou plusieurs arguments sont des chaînes de critères de recherche qui représentent une expression régulière, la première tentative consiste à convertir les critères de chaîne en nombres. Par exemple, ".0" se convertira en 0.0 et ainsi de suite. En cas de succès, la correspondance ne sera pas une correspondance d'expression régulière mais une correspondance numérique. Cependant, lorsque vous passez à un environnement local où le séparateur décimal n'est pas le point, la conversion d'expression régulière fonctionne. Pour forcer l'évaluation de l'expression régulière au lieu d'une expression numérique, utilisez une expression qui ne peut pas être mal interprétée comme numérique, telle que ". [0]" ou ".\0" ou "(?I) .0".

#### Syntaxe

=RERCHERCHEH(recherche;matrice;index;[plage_recherche_triée])

Pour une explication des paramètres, voir : RECHERCHEV (les colonnes et les lignes sont échangées)

Traitement des cellules vides

#### Exemple

Supposons que nous ayons construit une petite table de base de données occupant la plage de cellules A1:DO4 et contenant des informations de base sur 118 éléments chimiques. La première colonne contient les en-têtes de ligne " Élément ", " Symbole ", " Numéro atomique " et " Masse atomique relative ". Les colonnes suivantes contiennent les informations pertinentes pour chacun des éléments, classées de gauche à droite par numéro atomique. Par exemple, les cellules B1:B4 contiennent "Hydrogène", "H", "1" et "1,008", tandis que les cellules DO1:DO4 contiennent "Oganesson", "Og", "118" et "294".

| A | B | C | D | ... | DO
1 | Élément | Hydrogène | Hélium | Lithium | ... | Oganesson
2 | Symbole | H | He | Li | ... | Og
3 | Numéro atomique | 1 | 2 | 3 | ... | 118
4 | Masse atomique relative | 1.008 | 4.0026 | 6.94 | ... | 294

=RECHERCHEH("plomb"; $A$1:$DO$4;2;0) renvoie"Pb", le symbole du plomb.

=RECHERCHEH("Or"; $A$1:$DO$4;3;0) renvoie 79, le numéro atomique de l'or.

=RECHERCHEH("Carbone"; $A$1:$DO$4;4;0) renvoie 12,011, la masse atomique relative du carbone.

## RECHERCHEV

Recherche verticale avec référence aux cellules adjacentes à droite. Cette fonction vérifie si une valeur spécifique est contenue dans la première colonne d'une table. La fonction retourne alors la valeur dans la même ligne de la colonne nommée par Index. Si le paramètre Trié est omis ou défini sur VRAI ou un, il est supposé que les données sont triées par ordre croissant. Dans ce cas, si la Recherche exacte n'est pas trouvée, la dernière valeur inférieure au critère sera renvoyée. Si Trié est défini sur FAUX ou sur zéro, une correspondance exacte doit être trouvée, sinon l'erreur Erreur : valeur non disponible sera le résultat. Ainsi, avec une valeur de zéro, les données n'ont pas besoin d'être triées par ordre croissant.

La recherche prend en charge les caractères génériques ou les expressions régulières . Lorsque les expressions régulières sont activées, vous pouvez saisir "tous. *", Par exemple pour trouver le premier emplacement de "tous" suivi de n'importe quel caractère. Si vous souhaitez rechercher un texte qui est également une expression régulière, vous devez soit précéder chaque caractère d'un caractère "\", soit placer le texte dans \Q ...\E. Vous pouvez activer ou désactiver l'évaluation automatique des caractères génériques ou des expressions régulières dans LibreOffice - Préférences Outils - Options - LibreOffice Calc - Calculer .

Lorsque vous utilisez des fonctions où un ou plusieurs arguments sont des chaînes de critères de recherche qui représentent une expression régulière, la première tentative consiste à convertir les critères de chaîne en nombres. Par exemple, ".0" se convertira en 0.0 et ainsi de suite. En cas de succès, la correspondance ne sera pas une correspondance d'expression régulière mais une correspondance numérique. Cependant, lorsque vous passez à un environnement local où le séparateur décimal n'est pas le point, la conversion d'expression régulière fonctionne. Pour forcer l'évaluation de l'expression régulière au lieu d'une expression numérique, utilisez une expression qui ne peut pas être mal interprétée comme numérique, telle que ". [0]" ou ".\0" ou "(?I) .0".

#### Syntaxe

=RERCHERCHEV(critère_recherche;matrice;index;[plage_recherche_triée])

critère_recherche est la valeur de n'importe quel type recherchée dans la première colonne d'une matrice.

Matrice est la référence, qui doit contenir au moins autant de colonnes que le nombre passé dans l'argument Index.

index est le numéro de la colonne dans la matrice qui contient les valeurs devant être renvoyées. La première colonne a le numéro 1.

recherche_plage_triée est un paramètre facultatif qui indique si la première colonne du tableau contient des limites de plage au lieu de valeurs simples. Dans ce mode, la recherche renvoie la valeur de la ligne avec la première colonne ayant une valeur égale ou inférieure à critère_recherche. Par exemple, elle pourrait contenir les dates auxquelles une certaine valeur fiscale a été modifiée, et ainsi les valeurs représentent les dates de début d'une période où une valeur fiscale spécifique était effective. Ainsi, rechercher une date absente dans la première colonne du tableau, mais comprise entre certaines dates limites existantes, donnerait la plus basse d'entre elles, permettant de découvrir les données étant effectives à la date recherchée. Saisissez la valeur booléenne FAUX ou zéro si la première colonne n'est pas une liste de limites de plage. Lorsque ce paramètre est VRAI ou non renseigné, la première colonne du tableau doit être triée par ordre croissant. Les colonnes triées peuvent être recherchées beaucoup plus rapidement et la fonction renvoie toujours une valeur, même si la valeur de recherche ne correspond pas exactement, si elle est supérieure à la valeur la plus basse de la liste triée. Dans les listes non triées, la valeur de recherche doit correspondre exactement. Sinon, la fonction renverra #N/A avec le message : Erreur : valeur non disponible.

Traitement des cellules vides

#### Exemple

Vous voulez saisir le numéro d'un plat du menu dans la cellule A1 et le nom du plat doit apparaître comme un texte dans la cellule immédiatement voisine (B1). L'assignation Numéro au Nom est contenue dans la matrice D1:E100. D1 contient 100, E1 contient le nom Soupe de légumes et ainsi pour 100 éléments du menu. Les nombres en colonnes D sont triés en ordre croissant ainsi, le paramètre facultatif trié n'est pas nécessaire.

Saisissez la formule suivante dans B1 :

=RECHERCHEV(A1;D1:E100;2)

Dès que vous saisissez un numéro dans A1, le texte correspondant, figurant dans la deuxième colonne de la référence D1:E100, apparaît dans B1. Si vous spécifiez un numéro qui n'existe pas, c'est le texte du numéro inférieur le plus proche qui s'affiche. Pour éviter cela, insérez FAUX comme dernier paramètre de la formule : la saisie d'un numéro inexistant entraînera alors un message d'erreur.

## STYLE

Applique un style à la cellule contenant la formule. Au bout d'une durée définie, un autre style peut être appliqué. Cette fonction renvoie toujours la valeur 0 ; vous pouvez ainsi l'ajouter à une autre fonction sans en modifier la valeur. En l'associant à la fonction ACTUELLE, vous pouvez appliquer une couleur à une cellule en fonction de sa valeur. Exemple : =...+STYLE(SI(ACTUELLE()>3;"rouge";"vert")) applique le style "rouge" à la cellule si sa valeur est supérieure à 3 ; sinon, c'est le style "vert" qui est appliqué. Les deux styles de cellule doivent être définis au préalable.

#### Syntaxe

STYLE("style"[;temps[;"style_2"]])

style est le nom d'un style de cellule assigné à la cellule. Les noms de style doivent être saisis entre guillemets.

temps (facultatif) correspond à une période indiquée en secondes. Si ce paramètre fait défaut, le style est conservé.

style2 est le nom facultatif d'un style de cellule assigné à la cellule après qu'un certain temps soit écoulé. Si le paramètre est manquant le style "Standard" est supposé.

Dans les fonctions LibreOffice Calc, les paramètres marqués comme "facultatifs" peuvent être ignorés lorsqu'ils ne sont pas suivis d'autres paramètres. Par exemple, dans une fonction comportant quatre paramètres, où les deux derniers paramètres sont marqués comme "facultatifs", le paramètre 4 ou les paramètres 3 et 4 peuvent être ignorés, mais le paramètre 3 seul ne peut être ignoré.

#### Exemple

=STYLE("Invisible";60;"Par défaut") formate la cellule en transparent pendant 60 secondes après que le document ait été recalculé ou chargé, puis le format Par défaut est assigné. Les deux formatages de cellules doivent être définis auparavant.

Dans la mesure où STYLE() renvoie une valeur de zéro, cette valeur retournée est annexée à une chaîne. Ceci peut être évité en utilisant T() comme dans l'exemple suivant

="Texte"&T(STYLE("monStyle"))

Voir également ACTUELLE() pour un autre exemple.

## TYPE.ERREUR

Renvoie le nombre correspondant à une valeur d'erreur survenue dans une autre cellule. Grâce à ce nombre, vous pourrez générer le texte d'un message d'erreur.

En cas d'erreur, la fonction renvoie une valeur logique ou numérique.

La barre d'état affiche le code d'erreur LibreOffice prédéfini si vous cliquez sur la cellule comportant l'erreur.

#### Syntaxe

TYPE.ERREUR(référence)

référence est la référence à une cellule comportant une indication d'erreur.

#### Exemple

Si la cellule A1 affiche Err:518, la fonction =TYPE.ERREUR(A1) renvoie le nombre 518.

## ZONES

Renvoie le nombre de plages individuelles appartenant à une plage multiple. Une plage peut contenir des cellules contiguës ou individuelles.

La fonction attend un argument unique. Si vous définissez des plages multiples, vous devez les entourer de parenthèses supplémentaires. Les plages multiples peuvent être saisies en utilisant un point-virgule (;) comme séparateur, mais il sera converti automatiquement en opérateur tilde (~). Le tilde est utilisé pour joindre les plages.

#### Syntaxe

ZONES(référence)

Référence représente la référence à une cellule ou à une plage de cellules.

#### Exemple

=ZONES((A1:B3;F2;G1)) renvoie 3, car c'est la référence à trois cellules et/ou zones. Après la saisie, la formule est convertie en =ZONES((A1:B3~F2~G1)).

=ZONES(Toutes) renvoie 1 si vous avez défini une zone nommée Toutes sous Données - Définir une plage.

Rubriques connexes

Fonctions par catégories