Edukiak
Indizea 🔎︎

# COUNTIFS

Barruti anitzetan irizpidea betetzen duten gelaxken kopurua ematen du.

Funtzio hau LibreOffice 4.0 bertsiotik dago erabilgarri.

#### Sintaxia

COUNTIFS(Barrutia; Irizpidea[; Barrutia2; Irizpidea2][; ... ; [Barrutia127; Irizpidea127]])

Barrutia1: Derrigorrezko argumentua. Gelaxken barruti bat, izendun barruti baten izena edo zutabe edo errenkada baten etiketa da. Irizpidea barruti horri aplikatuko zaio.

Irizpidea: Irizpide bat gelaxka bakarreko erreferentzia, zenbaki edo testu bat da. Gelaxka-edukiekin konparazioak egiteko erabiltzen da.

Gelaxka huts baten erreferentzia 0 zenbakitzat hartzen da.

Bat datorren adierazpen bat honakoa izan daiteke:

- Zenbaki bat edo balio logiko bat. Bat datorren gelaxka-edukia zenbaki edo balio logiko horren berdina izango da.

- Konparatzaile batekin (<, <=, =, >, >=, <>) hasten den balio bat.

  = ikurrarekin, balioa hutsik badago, gelaxka hutsekin bat egingo du.

  <> ikurrarekin, balioa hutsik badago, hutsik ez dauden gelaxkekin bat egingo du.

  <> ikurrarekin, balioa ez badago hutsik, edozein gelaxka-edukirekin bat egingo du, gelaxka hutsak barne, balio horrekin salbu.

  Oharra: "=0" balioak ez du bat egiten gelaxka hutsekin.

  = eta <> eragileetarako, balioa hutsik ez badago eta zenbaki mota gisa edo horren azpimota gisa interpretatu ezin bada eta = eta <> bilaketa-irizpideak gelaxka osoei aplikatu behar zaizkie propietatea markatuta badago, konparazioa gelaxka-eduki osoekin egingo da. Markatuta ez badago, konparazioa irizpideekin bat datorren eremu-zatiarekin egingo da.

- Beste testu-balio batzuk. = eta <> bilaketa-irizpideak gelaxka osoei aplikatu behar zaizkie propietatea egia bada, konparazioa gelaxka-eduki osoekin egingo da. Faltsua bada, konparazioa irizpideekin bat datorren eremu-zatiarekin egingo da. Adierazpenak testua, zenbakiak adierazpen erregularrak zein komodinak (kalkulu-aukeretan gaituta badaude) eduki ditzake.

Barrutia2 – Aukerakoa. Barrutia2 eta hurrengoek Barrutia1 parametroaren esanahi bera dute.

Irizpidea2: Aukerakoa. Parametro hau eta ondoren datozenak 'Irizpidea' parametroaren berdinak dira.

Bilaketak komodinak edo adierazpen erregularrak onartzen ditu. Adierazpen erregularrak gaituta badaude, "den.*" sartu daiteke, adibidez, edozein karaktere kopururekin jarraitutako "den" katearen lehen agerraldia bilatzeko. Adierazpen erregularra den testuren bat bilatu nahi bada, karaktere bakoitzari "\" karakterea jarri behar zaio aurretik, edo testua \Q...\E karaktereen artean sartu behar da. Komodinen edo adierazpen erregularren ebaluazio automatikoa aktibatzeko/desaktibatzeko, erabili LibreOffice - Hobespenak Tresnak - Aukerak - LibreOffice Calc - Kalkulatu.

Adierazpen erregular bat ordezkatzen duten bilaketa-irizpideko kateak diren argumentu bat edo gehiago dituzten funtzioak erabiltzean, lehen aldian kate-irizpide horiek zenbaki bihurtzeko saialdia egingo da. Adibidez, ".0" katea 0.0 bihurtuko da, eta abar. Ongi bihurtzen bada, bat etortzea ez da izango adierazpen erregularreko bat etortzea, baizik eta zenbakizko bat etortzea. Hala ere, dezimalen bereizlea puntua ez den eskualde-ezarpen batean, adierazpen erregularraren bihurketak funtzionatu egingo du. Zenbakizko adierazpen bat sortu ordez adierazpen erregularraren ebaluazioa behartzeko, erabili zenbakitzat hartu ezin daitezkeen adierazpenak, adibidez ".[0]" edo ".\0" edo "(?i).0".

Barrutia, Barrutia2, ... eta Irizpidea, Irizpidea2, ... parametroek tamaina bera izan behar dute, bestela funtzioak 'err:502 - Baliogabeko argumentua' errorea itzuliko du.

Irizpideen arteko erlazio logikoa AND logiko modura definitu daiteke. Alegia, emandako irizpide guztiak betetzen badira (eta soilik horrela bada), hartuko da kontuan kalkuluan emandako FuntzioBarrutia parametroari dagokion balio bat.

Funtzioak 255 argumentu arte izan ditzake; alegia, 127 irizpide-barruti eta irizpide zehaztu daitezke funtziorako.

Gelaxka batek TRUE (Egiazkoa) badu, 1 baliotzat hartzen du; FALSE (Gezurra) badu, 0 (zero) baliotzat.

Funtzio hori Open Document Format for Office Applications (OpenDocument) estandarraren 1.2 bertsioan (ISO/IEC 26300:2-2015) dago onartuta.

#### Adibidea

Begiratu honako taula

| A | B | C
1 | Produktuaren izena | Salmentak | Diru-sarrerak
2 | arkatza | 20 | 65
3 | luma | 35 | 85
4 | koadernoa | 20 | 190
5 | liburua | 17 | 180
6 | arkatz-kutxa | ez | ez

Beheko adibide guztietan batuketa kalkulatzeko barrutiek #6 errenkada dute, baina hura ez ikusi egingo da testua duelako.

#### Erabilera sinplea

=COUNTIFS(B2:B6;">=20")

B2:B6 barrutian 20 balioaren berdina edo handiagoak diren balioak dituzten errenkaden kopuruazenbatzen du. 3 ematen du, bosgarren eta seigarren errenkadak ez dutelako irizpidea betetzen.

=COUNTIFS(B2:B6;">=20";C2:C6;">70")

Aldi berean C2:C6 barrutian 70 baino handiagoak diren balioak eta B2:B6 barrutian 20 baino handiagoak edo berdinak diren balioak dituzten errenkaden kopurua zenbatzen du. 2 ematen du, bigarren, bosgarren eta seigarren errenkadek ez dutelako betetzen gutxienez irizpide bat.

#### Adierazpen erregularrak eta habiaratutako funtzioak erabiltzea

Adibideok behar den moduan funtzionatu dezaten, ziurtatu Gaitu adierazpen erregularrak formuletan hautatuta dagoela LibreOffice - Hobespenak Tresnak - Aukerak - LibreOffice Calc - Kalkulatu aukeran.

=COUNTIFS(B2:B6;"[:alpha:]*")

B2:B6 barrutian alfabetoko ikurrak soilik dituzten errenkaden kopurua zenbatzen du. 1 ematen du, seigarren errenkadak soilik betetzen duelako irizpidea.

=COUNTIFS(B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

B2:B6 barrutiko errenkada kopurua zenbatzen du, barrutiko balio minimoa eta maximoa duten errenkadak kanpoan utzita. 2 ematen du, hirugarren, bosgarren eta seigarren errenkadek ez dutelako gutxienez irizpide bat betetzen.

=COUNTIFS(A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

A2:A6 barrutian "pen" katearekin hasten diren gelaxka guztiei, bai eta B2:B6 barrutiko gelaxka guztiei ere (maximoa salbu), dagozkien errenkada kopurua zenbatzen du. 1 ematen du, bigarren errenkadak soilik betetzen dituelako irizpide guztiak.

#### Irizpidetzat gelaxka baten erreferentzia erabiltzea

Irizpide bat erraz aldatu nahi baduzu, beste gelaxka batean zehaztu dezakezu eta gelaxka horren erreferentzia bat erabili COUNTIFS funtzioaren baldintzan. Adibidez, goiko funtzioa beste modu honetan idatzi daiteke:

=COUNTIFS(A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

E2 = pen bada, funtzioak 1 ematen du, gelaxkarako esteka bere edukiarekin ordezkatuko delako eta aurreko funtzioak bezala funtzionatuko duelako.

Erlazionatutako gaiak

COUNT, COUNTIF, COUNTBLANK, COUNTA

COUNTIFS, MINIFS, MAXIFS, AVERAGEIFS, SUMIFS

Adierazpen erregularren zerrenda