Edukiak

# SUMIFS

Barruti anitzetan irizpide anitz betetzen dituzten gelaxketako balioen batuketa ematen du.

Funtzio hau LibreOffice 4.0 bertsiotik dago erabilgarri.

### Sintaxia

SUMIFS(FuntzioBarrutia; Barrutia1; Irizpidea1[; Barrutia2; Irizpidea2][; … ; [Barrutia127; Irizpidea127]])

FuntzioBarrutia – derrigorrezko argumentua. Gelaxka-barruti bat, izendun barruti baten izen bat, edo zutabe edo errenkada baten etiketa bat da, batuketa kalkulatzeko erabiliko diren balioak dituena.

Barrutia1: Derrigorrezko argumentua. Gelaxken barruti bat, izendun barruti baten izena edo zutabe edo errenkada baten etiketa da. Irizpidea barruti horri aplikatuko zaio.

Criterion1: A criterion is a text expression computed from a single cell Reference, Formula, Number or Text. It is used in comparisons with cell contents.

Gelaxka huts baten erreferentzia 0 zenbakitzat hartzen da.

Bat datorren adierazpen bat honakoa izan daiteke:

- A number or logical value. A matching cell content equals the number or logical value.

- A value beginning with a comparator (<, <=, =, >, >=, <>).

  For =, if the value is empty it matches empty cells.

  For <>, if the value is empty it matches non-empty cells.

  For <>, if the value is not empty it matches any cell content except the value, including empty cells.

  Oharra: "=0" balioak ez du bat egiten gelaxka hutsekin.

  For = and <>, if the value is not empty and can not be interpreted as a number type or one of its subtypes and the property Search criteria = and <> must apply to whole cells is checked, comparison is against the entire cell contents, if unchecked, comparison is against any subpart of the field that matches the criteria. For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes applies.

- Other Text value. If the property Search criteria = and <> must apply to whole cells is true, the comparison is against the entire cell contents, if false, comparison is against any subpart of the field that matches the criteria. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

Barrutia2 – Aukerakoa. Barrutia2 eta hurrengoek Barrutia1 parametroaren esanahi bera dute.

Irizpidea2: Aukerakoa. Parametro hau eta ondoren datozenak 'Irizpidea' parametroaren berdinak dira.

Bilaketan komodinak eta adierazpen erregularrak onartzen dira. Adierazpen erregularrak gaitzen badira, "egun.*" sartu daiteke, adibidez, hasieran "egun" duen lehen hitza aurkitzeko. Adierazpen erregularra den testu bat aurkitu nahi izanez gero, erabili "\" karaktere bat horietako edozeinen aurrean edo inguratu testua \Q...\E karaktereekin. Komodinen eta adierazpen erregularren ebaluazio automatikoa aktibatu edo desaktibatu daiteke LibreOffice - Hobespenak Tresnak - Aukerak - LibreOffice Calc - Kalkulatu aukeran.

Adierazpen erregular bat ordezkatzen duten bilaketa-irizpideko kateak diren argumentu bat edo gehiago dituzten funtzioak erabiltzean, lehen aldian kate-irizpide horiek zenbaki bihurtzeko saialdia egingo da. Adibidez, ".0" katea 0.0 bihurtuko da, eta abar. Ongi bihurtzen bada, bat etortzea ez da izango adierazpen erregularreko bat etortzea, baizik eta zenbakizko bat etortzea. Hala ere, dezimalen bereizlea puntua ez den eskualde-ezarpen batean, adierazpen erregularraren bihurketak funtzionatu egingo du. Zenbakizko adierazpen bat sortu ordez adierazpen erregularraren ebaluazioa behartzeko, erabili zenbakitzat hartu ezin daitezkeen adierazpenak, adibidez ".[0]" edo ".\0" edo "(?i).0".

FuntzioBarrutia eta Barrutia1,Barrutia2... parametroek tamaina bera izan behar dute, bestela funtzioak 'err:502 - Baliogabeko argumentua' errorea itzuliko du.

Irizpideen arteko erlazio logikoa AND logiko modura definitu daiteke. Alegia, emandako irizpide guztiak betetzen badira (eta soilik horrela bada), hartuko da kontuan kalkuluan emandako FuntzioBarrutia parametroari dagokion balio bat.

Funtzioak 255 argumentu arte izan ditzake; alegia, 127 irizpide-barruti eta irizpide zehaztu daitezke funtziorako.

Gelaxka batek TRUE (Egiazkoa) badu, 1 baliotzat hartzen du; FALSE (Gezurra) badu, 0 (zero) baliotzat.

### Adibideak

Begiratu honako taula

| A | B | C
1 | Produktuaren izena | Sales | Revenue
2 | arkatza | 20 | 65
3 | luma | 35 | 85
4 | koadernoa | 20 | 190
5 | liburua | 17 | 180
6 | pencil-case | not | not

Beheko adibide guztietan batuketa kalkulatzeko barrutiek #6 errenkada dute, baina hura ez ikusi egingo da testua duelako.

#### Erabilera sinplea

=SUMIFS(B2:B6;B2:B6;">=20")

B2:B6 barrutian 20 balioaren berdina edo handiagoak diren balioen batuketa kalkulatzen du. 75 ematen du, bosgarren errenkadak ez duelako irizpidea betetzen.

=SUMIFS(C2:C6;B2:B6;">=20";C2:C6;">70")

C2:C6 barrutian 70 baino handiagoak diren eta B2:B6 barrutian 20 balioaren berdinak edo handiagoak duten gelaxkei dagozkien balioen batuketa kalkulatzen du. 275 ematen du, bigarren eta bosgarren errenkadek ez dutelako gutxienez irizpide bat betetzen.

#### Adierazpen erregularrak eta habiaratutako funtzioak erabiltzea

=SUMIFS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

C2:C6 barrutian B2:B6 barrutiko balio guztiei dagozkien balioak, minimoa eta maximoa salbu, batzen ditu. 255 ematen du, hirugarren eta bosgarren errenkadek ez dutelako gutxienez irizpide bat betetzen.

=SUMIFS(C2:C6;A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

C2:C6 barrutiko balioen batuketa kalkulatzen du, "pen" katearekin hasten diren A2:A6 barrutiko gelaxkekin eta B2:B6 barrutiko gelaxka guztiekin (maximoa salbu) bat datozen balioak soilik hartuta. 65 ematen du, bigarren errenkadak soilik betetzen dituelako irizpide guztiak.

#### Irizpidetzat gelaxka baten erreferentzia erabiltzea

Irizpide bat erraz aldatu behar baduzu, beste gelaxka batean zehaztu dezakezu eta gelaxka horren erreferentzia bat erabili SUMIFS funtzioaren baldintzan. Adibidez, goiko funtzioa beste modu honetan idatzi daiteke:

=SUMIFS(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

E2 = pen bada, funtzioak 65 ematen du, gelaxkarako esteka bere edukiarekin ordezkatuko delako.

#### Informazio teknikoa

Funtzio hori Open Document Format for Office Applications (OpenDocument) estandarraren 1.2 bertsioan (ISO/IEC 26300:2-2015) dago onartuta.

Erlazionatutako gaiak

SUMIFS wiki page.

SUM, SUMIF

COUNTIFS, MINIFS, MAXIFS, AVERAGEIFS, SUMIFS

Adierazpen erregularren zerrenda

Emaguzu laguntza!