Sisukord
Register 🔎︎

# Rahandusfunktsioonid 1. osa

See kategooria sisaldab LibreOffice Calc'i rahandusalaseid funktsioone.

## ACCRINT

Tagastab väärtpaberi tekkepõhise intressi perioodiliste maksete korral.

#### Süntaks

ACCRINT(Issue; FirstInterest; Settlement; Rate; [Par]; Frequency [; Basis])

Emissioon on väärtpaberi emissioonikuupäev.

Esimene intress on väärtpaberi esimese intressi kuupäev.

Arvelduspäev on kuupäev, millal arvutatakse kuni selle kuupäevani kogunenud intress.

Intress on aastaintressi nominaalmäär (kupongi intressimäär).

Par (optional) is the par value of the security. If omitted, a default value of 1000 is used.

We recommend that you always specify the value that you require for ACCRINT’s Par argument, rather than allowing Calc to apply an arbitrary default. This will make your formula easier to understand and easier to maintain.

Sagedus on intressimaksete arv aastas (1, 2 või 4).

Alus on üks eeldefineeritud võimalustest ja määrab, kuidas aastat arvestatakse.

Alus | Arvutamine
0 or missing | USA meetod (NASD): 12 kuud, igaühes 30 päeva
1 | Täpne päevade arv kuudes ja täpne päevade arv aastas
2 | Täpne päevade arv kuudes, aastas 360 päeva
3 | Täpne päevade arv kuudes, aastas 365 päeva
4 | Euroopa meetod: 12 kuud, igaühes 30 päeva

#### Näide

Väärtpaber väljastatakse 28.02.2001. Esimese intressi kuupäevaks on määratud 31.08.2001. Arvelduspäev on 01.05.2001. Intress on 0,1 ehk 10% ja nimiväärtus on 1000 rahaühikut. Intressi makstakse kord poolaasta jooksul (sagedus on 2). Aluseks võetakse USA meetod (0). Kui palju intressi on kogunenud?

=ACCRINT("28.02.2001";"31.08.2001";"01.05.2001";0,1;1000;2;0) annab vastuseks 16,94444.

## ACCRINTM

Arvutab väärtpaberi tekkepõhise intressi arvestades, et kogu summa väärtpaberi eest on makstud arvelduspäeval.

#### Süntaks

ACCRINTM(Issue; Settlement; Rate [; Par [; Basis]])

Emissioon on väärtpaberi emissioonikuupäev.

Arvelduspäev on kuupäev, millal arvutatakse kuni selle kuupäevani kogunenud intress.

Intress on aastaintressi nominaalmäär (kupongi intressimäär).

Par (optional) is the par value of the security. If omitted, a default value of 1000 is used.

We recommend that you always specify the value that you require for ACCRINTM’s Par argument, rather than allowing Calc to apply an arbitrary default. This will make your formula easier to understand and easier to maintain.

Alus on üks eeldefineeritud võimalustest ja määrab, kuidas aastat arvestatakse.

Alus | Arvutamine
0 or missing | USA meetod (NASD): 12 kuud, igaühes 30 päeva
1 | Täpne päevade arv kuudes ja täpne päevade arv aastas
2 | Täpne päevade arv kuudes, aastas 360 päeva
3 | Täpne päevade arv kuudes, aastas 365 päeva
4 | Euroopa meetod: 12 kuud, igaühes 30 päeva

#### Näide

Väärtpaber on väljastatud 01.04.2001. Tähtajaks on määratud 15.06.2001. Intress on 0,1 ehk 10% ja nimiväärtus on 1000 rahaühikut. Päeva-/aastaarvutuse aluseks on päevane bilanss (3). Kui palju intressi on kogunenud?

=ACCRINTM("01.04.2001";"15.06.2001";0,1;1000;3) annab vastuseks 20,54795.

## AMORDEGRC

Arvutab põhivahendi amortisatsiooni perioodi kohta kahaneva amortisatsioonina. Vastupidiselt funktsioonile AMORLINC on käesoleva funktsiooni juures amortisatsioonikoefitsent elueast sõltumatu.

#### Süntaks

AMORDEGRC(Cost; DatePurchased; FirstPeriod; Salvage; Period; Rate [; Basis])

Maksumus on soetusmaksumus.

Soetamiskuupäev on põhivahendi soetamiskuupäev.

Esimene periood on esimese arveldusperioodi lõppkuupäev.

Jääkväärtus on põhivahendi jääkväärtus amortiseeritava eluea lõpul.

Periood on arvutuses vaadeldav arveldusperiood.

Määr on amortisatsioonimäär.

Alus on üks eeldefineeritud võimalustest ja määrab, kuidas aastat arvestatakse.

Alus | Arvutamine
0 or missing | USA meetod (NASD): 12 kuud, igaühes 30 päeva
1 | Täpne päevade arv kuudes ja täpne päevade arv aastas
2 | Täpne päevade arv kuudes, aastas 360 päeva
3 | Täpne päevade arv kuudes, aastas 365 päeva
4 | Euroopa meetod: 12 kuud, igaühes 30 päeva

#### Näide

An asset was acquired on 2020-02-01 at a cost of 2000 currency units. The end date of the first settlement period was 2020-12-31. The salvage value of the asset at the end of its depreciable life will be 10 currency units. The rate of depreciation is 0.1 (10%) and the year is calculated using the US method (Basis 0). Assuming degressive depreciation, what is the amount of depreciation in the fourth depreciation period?

=AMORDEGRC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0.1; 0) returns a depreciation amount of 163 currency units.

Beware that Basis 2 is not supported by Microsoft Excel. Hence, if you use Basis 2 and export your document to XLSX format, it will return an error when opened in Excel.

## AMORLINC

Arvutab põhivahendi amortisatsiooni arvestusperioodi kohta lineaarse amortisatsioonina. Kui põhivahend on soetatud arvestusperioodi jooksul, siis leitakse amortisatsiooni võrdeline osa.

#### Süntaks

AMORLINC(Cost; DatePurchased; FirstPeriod; Salvage; Period; Rate [; Basis])

Maksumus on soetusmaksumus.

Soetamiskuupäev on põhivahendi soetamiskuupäev.

Esimene periood on esimese arveldusperioodi lõppkuupäev.

Jääkväärtus on põhivahendi jääkväärtus amortiseeritava eluea lõpul.

Periood on arvutuses vaadeldav arveldusperiood.

Määr on amortisatsioonimäär.

Alus on üks eeldefineeritud võimalustest ja määrab, kuidas aastat arvestatakse.

Alus | Arvutamine
0 or missing | USA meetod (NASD): 12 kuud, igaühes 30 päeva
1 | Täpne päevade arv kuudes ja täpne päevade arv aastas
2 | Täpne päevade arv kuudes, aastas 360 päeva
3 | Täpne päevade arv kuudes, aastas 365 päeva
4 | Euroopa meetod: 12 kuud, igaühes 30 päeva

#### Näide

An asset was acquired on 2020-02-01 at a cost of 2000 currency units. The end date of the first settlement period was 2020-12-31. The salvage value of the asset at the end of its depreciable life will be 10 currency units. The rate of depreciation is 0.1 (10%) and the year is calculated using the US method (Basis 0). Assuming linear depreciation, what is the amount of depreciation in the fourth depreciation period?

=AMORLINC(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0.1; 0) returns a depreciation amount of 200 currency units.

Beware that Basis 2 is not supported by Microsoft Excel. Hence, if you use Basis 2 and export your document to XLSX format, it will return an error when opened in Excel.

## DB

Tagastab põhivahendi amortisatsiooni määratud perioodi kohta, kasutades topeltkahaneva bilansi meetodit.

Seda amortisatsiooni vormi kasutatakse, kui amortiseerumise alguses soovitakse arvutada kõrgemat amortisatsiooni (vastandina lineaarsele amortisatsioonile). Amortiseeruvat väärtust vähendatakse iga perioodi järel juba arvestatud amortisatsiooni võrra.

#### Süntaks

DB(Cost; Salvage; Life; Period [; Month])

Maksumus on põhivahendi soetusmaksumus.

Jääkväärtus on põhivahendi väärtus pärast tema eluea lõppu.

Eluiga on periood või ajavahemik, mille jooksul põhivahend amortiseerub.

Periood on iga perioodi pikkus. Pikkus (kestus) tuleb sisestada amortisatsiooniperioodiga samas kuupäevaühikus.

Kuu (pole kohustuslik) tähistab kuude arvu amortisatsiooni esimeses aastas. Kui seda väärtust pole määratud, kasutatakse vaikimisi väärtust 12.

#### Näide

A computer system with an initial cost of 25,000 currency units is to be depreciated over a three-year period. The salvage value is to be 1,000 currency units. The first period of depreciation comprises 6 months. What is the fixed-declining balance depreciation of the computer system in the second period, which is a full year starting from the end of the first six-month period?

=DB(25000; 1000; 3; 2; 6) returns 11,037.95 currency units.

## DDB

Tagastab põhivahendi amortisatsiooni määratud perioodi kohta, kasutades lineaarse kahanemise meetodit.

Seda amortisatsiooni vormi kasutatakse, kui vajatakse suuremat amortisatsiooni põhivahendi eluea alguses. Kulum muutub iga perioodiga väiksemaks ja see juhtub tavaliselt esemetega, mis kaotavad oma väärtusest suure osa kohe pärast ostmist (sõidukid, arvutid). Pane tähele, et sellise arvutusviisi juures ei muutu põhivahendi jääkväärtus kunagi nulliks.

#### Süntaks

DDB(Cost; Salvage; Life; Period [; Factor])

Maksumus on põhivahendi soetusmaksumus.

Jääkväärtus fikseerib põhivahendi väärtuse eluea lõpul.

Eluiga on perioodide (nt aastate või kuude) arv, mis määrab, kui kaua põhivahendit kasutatakse.

Periood määrab perioodi, mille jooksul väärtust arvutatakse.

Faktor (pole kohustuslik) on tegur, mille võrra amortisatsioon väheneb. Kui väärtust pole sisestatud, on faktor vaikimisi 2.

#### Näide

Arvutikomplekt ostuhinnaga 75000 rahaühikut amortiseerub kuukaupa 5 aasta jooksul. Väärtus eluea lõpus on 1 rahaühik. Faktor on 2.

=DDB(75000;1;60;12;2) = 1721,81 rahaühikut. Seetõttu on topeltkahanev amortisatsioon kaheteistkümnendal kuul pärast ostu 1721,81 rahaühikut.

## DISC

Arvutab väärtpaberi diskontomäära protsentides.

#### Süntaks

DISC(Settlement; Maturity; Price; Redemption [; Basis])

Arvelduspäev on väärtpaberi soetamise kuupäev.

Tähtaeg on väärtpaberi aegumise kuupäev.

Hindon väärtpaberi hind 100 nimiväärtuse rahaühiku kohta.

Tagatis on väärtpaberi tagatisväärtus 100 nimiväärtuse rahaühiku kohta.

Alus on üks eeldefineeritud võimalustest ja määrab, kuidas aastat arvestatakse.

Alus | Arvutamine
0 or missing | USA meetod (NASD): 12 kuud, igaühes 30 päeva
1 | Täpne päevade arv kuudes ja täpne päevade arv aastas
2 | Täpne päevade arv kuudes, aastas 360 päeva
3 | Täpne päevade arv kuudes, aastas 365 päeva
4 | Euroopa meetod: 12 kuud, igaühes 30 päeva

#### Näide

Väärtpaber on ostetud 25.01.2001; tähtaeg on 15.11.2001. Hind (ostuhind) on 97, tagatisväärtus on 100. Milline on arveldusväärtus (diskonto), kui arvutamisel on aluseks päevane bilanss (alus 3)?

=DISC("25.01.2001";"15.11.2001";97;100;3) annab vastuseks ligikaudu 0,0372 ehk 3,72 protsenti.

## DURATION

Arvutab kindla intressiga väärtpaberi kestuse aastates.

#### Süntaks

DURATION(Settlement; Maturity; Coupon; Yield; Frequency [; Basis])

Arvelduspäev on väärtpaberi soetamise kuupäev.

Tähtaeg on väärtpaberi aegumise kuupäev.

Kupongimäär on kupongi aastaintressimäär (intressi nominaalmäär).

Tulusus on väärtpaberi aastane tulusus.

Sagedus on intressimaksete arv aastas (1, 2 või 4).

Alus on üks eeldefineeritud võimalustest ja määrab, kuidas aastat arvestatakse.

Alus | Arvutamine
0 or missing | USA meetod (NASD): 12 kuud, igaühes 30 päeva
1 | Täpne päevade arv kuudes ja täpne päevade arv aastas
2 | Täpne päevade arv kuudes, aastas 360 päeva
3 | Täpne päevade arv kuudes, aastas 365 päeva
4 | Euroopa meetod: 12 kuud, igaühes 30 päeva

#### Näide

Väärtpaber soetati 01.01.2001, tähtaeg on 01.01.2006. Intressi kupongimäär on 8%. Tulusus on 9,0%. Intresse makstakse kord poolaasta jooksul (sagedus on 2). Kui pikk on kestus, kui intressi arvutamisel on aluseks päevane bilanss (alus on 3)?

=DURATION("2001-01-01";"2006-01-01";0.08;0.09;2;3) returns 4.2 years.

## EFFECT

Tagastab tegeliku aastaintressi määra vastavalt intressimäära nimiväärtusele.

Intressimäära nimiväärtus arvestab intressi summat arvutusperioodi lõpus. Tegelik intressimäär suureneb koos tehtud maksete arvuga. Teiset sõnadega, intressi makstakse sageli osamaksete kaupa (kord kuus või kvartalis) enne arvutusperioodi lõppu.

#### Süntaks

EFFECT(Nom; P)

Nom on intressimäära nimiväärtus.

P on intressimaksete arv aastas.

#### Näide

Kui aastaintressi määra nimiväärtus on 9.75% ja intressi arvutatakse neli korda aastas, mis on siis tegelik intressimäär (kehtiv intressimäär)?

=EFFECT(9.75%;4) = 10.11% The annual effective rate is therefore 10.11%.

## EFFECT_ADD

Tagastab tegeliku aastaintressi määra vastavalt intressimäära nimiväärtusele ja intressimaksete arvule aastas.

The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.

#### Süntaks

EFFECT_ADD(nominaalintress; perioode)

Nominaalintress on aastaintressi nominaalväärtus.

Perioode on intressimaksete arv aastas.

#### Näide

Leiame tegeliku aastaintressi määra, kui intressimäära nimiväärtus on 5.25% ja makseid teostatakse kord kvartalis.

=EFFECT_ADD(0,0525;4) tagastab 0,053543 ehk 5,3543%.

## IRR

Arvutab investeeringu sisemise tulumäära. Väärtused tähistavad regulaarsete intervallidega käibeid, vähemalt üks väärtus peab olema negatiivne (väljaminek) ja vähemalt üks väärtus peab olema positiivne (sissetulek).

If the payments take place at irregular intervals, use the XIRR function.

#### Süntaks

IRR(Values [; Guess])

Väärtused tähistavad väärtusi sisaldavat massiivi.

Hinnang (pole kohustuslik) on hinnanguline väärtus. Investeeringu sisemise tulumäära arvutamiseks kasutatakse iteratiivset meetodit. Kui sisestada saab üksnes paar väärtust, tuleks iteratsiooni lubamiseks sisestada ka esialgne hinnang.

This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.

#### Näide

Eeldusel, et lahtrid sisaldavad väärtusi A1=-10000, A2=3500, A3=7600 ja A4=1000, tagastab valem =IRR(A1:A4) tulemuse 11,33%.

Because of the iterative method used, it is possible for IRR to fail and return Error 523, with "Error: Calculation does not converge" in the status bar. In that case, try another value for Guess.

## ISPMT

Arvutab intressimäära konstantsete osamaksete korral.

#### Süntaks

ISPMT(määr; periood; kokku_perioode; investeering)

Intressimäär on perioodide intressimäär.

Periood on osamaksete perioodide arv intressimäära arvutamisel.

Kokku_perioode on osamaksete perioodide koguarv.

Investeering on investeeringu summa.

#### Näide

Tahetakse teada, kui suur oleks 120000 rahaühiku suuruse laenu, mille tähtaeg on 2 aastat, aastane intressimäär 12% ja maksed toimuvad kord kuus, intress 1,5 aasta pärast.

=ISPMT(1%;18;24;120000) = -300 rahaühikut. Igakuine intress pärast 1,5 aastat on 300 rahaühikut.

## PV

Tagastab regulaarsete maksete saamiseks tehtud investeeringu nüüdisväärtuse.

See funktsioon arvutab, kui palju raha on kindla intressi korral vaja investeerida praegu, et saada annuiteedina teatud summa mingi arvu perioodide jooksul. Võimalik on ette anda ka summa, mis peab olemas olema perioodi lõpul. Tingimustes saab määrata, kas väljamaksed tehakse perioodi alguses või lõpus.

Sisesta väärtused arvude, avaldiste või viidetena. Näiteks kui intressi makstakse aastas 8%, kuid sa soovid aasta asemel kasutada perioodina kuud, sisesta 8%/12 kohale Intress ja LibreOffice Calc arvutab automaatselt õige intressimäära.

#### Süntaks

PV(Rate; NPer; Pmt [; FV [; Type]])

Intress määrab intressimäära perioodi kohta.

NPer on perioodide koguarv, mille jooksul makseid sooritatakse (makseperiood).

Pmt on perioodis tehtava regulaarse makse suurus.

FV (pole kohustuslik) määrab tulevikuväärtuse, mis jääb järele pärast viimase makse tegemist.

Tüüp (pole kohustuslik) tähistab maksete tähtaega. Tüüp = 1 tähendab, et makse tuleb teha perioodi alguses; tüüp = 0 (vaikeväärtus) tähistab perioodi lõppu jäävat tähtaega.

LibreOffice Calci funktsioonides võib argumendi, mis on märgitud kui "mittekohustuslik", jätta ära ainult siis, kui talle ei järgne enam teisi argumente. Näiteks, kui nelja argumendiga funktsiooni kaks viimast argumenti omavad märget "mittekohustuslik", võib ära jätta argumendi 4 või argumendid 3 ja 4, kuid mitte argumenti 3 üksinda.

#### Näide

Milline on investeeringu nüüdisväärtus, kui iga kuu makstakse välja 500 rahaühikut ja aastaintress on 8%? Makseperiood on 48 kuud ja lõpuks peab järele jääma 20 000 rahaühikut.

=PV(8%/12;48;500;20000) = -35 019,37 rahaühikut. Nimetatud tingimuste korral tuleb täna sisse maksta 35 019,37 rahaühikut, kui soovid 48 kuu jooksul saada 500 rahaühikut kuus ja tagada, et perioodi lõpuks jääks alles 20 000 rahaühikut. Ristkontroll näitab, et 48 x 500 rahaühikut + 20 000 rahaühikut = 44 000 rahaühikut. Selle summa ja algselt sisse makstud 35 000 rahaühiku vahe tähistab makstud intressi.

Kui sisestada valemisse väärtuste asemel viited lahtritele, siis võib läbi mängida piiramatu hulga "siis kui" stsenaariume. Pane tähele, et viited konstantidele tuleb määrata absoluutviidetena. Seda tüüpi arvutuste näited on toodud amortisatsiooni arvutamise funktsioonide all.

## RECEIVED

Arvutab saadava summa, mis makstakse kindla intressiga väärtpaberi eest määratud ajal.

#### Süntaks

RECEIVED(Settlement; Maturity; Investment; Discount [; Basis])

Arvelduspäev on väärtpaberi soetamise kuupäev.

Tähtaeg on väärtpaberi aegumise kuupäev.

Hind on ostusumma.

Diskonto on diskontomäär protsentides väärtpaberi soetamisel.

Alus on üks eeldefineeritud võimalustest ja määrab, kuidas aastat arvestatakse.

Alus | Arvutamine
0 or missing | USA meetod (NASD): 12 kuud, igaühes 30 päeva
1 | Täpne päevade arv kuudes ja täpne päevade arv aastas
2 | Täpne päevade arv kuudes, aastas 360 päeva
3 | Täpne päevade arv kuudes, aastas 365 päeva
4 | Euroopa meetod: 12 kuud, igaühes 30 päeva

#### Näide

Arvelduspäev: 15. veebruar 1999, tähtaeg: 15. mai 1999, ostusumma: 1000 rahaühikut, diskontomäär: 5,75 protsenti, alus: päevane bilanss/360 = 2.

Tähtajal saadav summa arvutatakse järgnevalt:

=RECEIVED("15.02.1999";"15.05.1999";1000;0,0575;2) annab vastuseks 1014,420266.

## SYD

Tagastab lineaarselt kahaneva amortisatsioonimäära.

Selle funktsiooni abil arvutakse objekti eluea ühe perioodi jooksul arvestatavat amortisatsiooni. Lineaarselt kahaneva amortisatsiooni puhul väheneb amortisatsiooni summa iga perioodi jooksul kindla väärtuse võrra.

#### Süntaks

SYD(maksumus; jääkväärtus; eluiga; periood)

Maksumus on põhivahendi soetusmaksumus.

Jääkväärtus on põhivahendi väärtus pärast amortisatsiooni.

Eluiga on aeg, mille jooksul põhivahend amortiseerub.

Periood määrab perioodi, mille jooksul amortisatsiooni arvutatakse.

#### Näide

Videosüsteem, mis maksis 50000 rahaühikut, amortiseerub aastakaupa 5 aasta jooksul. Jääkväärtuseks jääb 10000 rahaühikut. Leiame esimese aasta amortisatsiooni.

=SYD(50000;10000;5;1)=13 333,33 rahaühikut. Esimese aasta amortisatsioonisumma on 13 333,33 rahaühikut.

Parema ülevaate saamiseks amortisatsiooni suurusest perioodide lõikes on kasulik koostada amortisatsiooni tabel. Erinevate LibreOffice Calci valemite sisestamisel üksteise järele näeme, milline amortisatsiooni arvutamise viis on kõige mõistlikum. Sisestame tabelisse järgnevad kirjed:

| A | B | C | D | E
1 | Soetusmaksumus | Jääkväärtus | Kasulik eluiga | Periood | Amort. SYD
2 | 50 000 rahaühikut | 10 000 rahaühikut | 5 | 1 | 13 333,33 rahaühikut
3 |  |  |  | 2 | 10 666,67 rahaühikut
4 |  |  |  | 3 | 8000,00 rahaühikut
5 |  |  |  | 4 | 5333,33 rahaühikut
6 |  |  |  | 5 | 2666,67 rahaühikut
7 |  |  |  | u6 | 0,00 rahaühikut
8 |  |  |  | 7 |
9 |  |  |  | 8 |
10 |  |  |  | 9 |
11 |  |  |  | 10 |
12 |  |  |  |  |
13 | >0 |  |  | Kokku | 40 000,00 rahaühikut

Valem lahtris E2 on järgmine:

=SYD($A$2;$B$2;$C$2;D2)

Valem kogu veerus E on ühesugune lahtrini E11 (vali E2 ja lohista hiirega lahtri alumist parempoolset nurka kuni lahtrini E11).

Lahter E13 sisaldab valemit amortisatsioonide summa kontrolliks. Valemis kasutatakse funktsiooni SUMIF, kuna negatiivseid väärtusi vahemikus E8:E11 ei tohi arvestada. Tingimus >0 on lahtris A13. Lahtris E13 on järgnev valem:

=SUMIF(E2:E11;A13)

Nüüd on võimalik näha amortisatsiooni 10 aasta jooksul, jääkväärtuse 1 rahaühik korral või erineva soetusmaksumuse puhul ja nii edasi.

Rahandusfunktsioonid, 2. osa

Rahandusfunktsioonid, 3. osa

Functions by Category