Contenido

# Funciones financieras, parte uno

Esta categoría contiene las funciones matemáticas de finanzas de LibreOffice Calc.

## AMORTIZ.LIN

Calcula el importe de la depreciación en un período de liquidación en forma de amortización lineal. Si el activo fijo se adquiere durante el período de liquidación, se tiene en cuenta el importe proporcional de la depreciación.

#### Sintaxis

AMORTIZ.LIN(Costo; Fecha de compra; Primer periodo; Valor residual; Periodo; Tasa [; Base])

Costo significa el costo de adquisición.

FechaDeCompra es la fecha de la adquisición.

PrimerPeriodo es la fecha de vencimiento del primer periodo de liquidación.

Salvamento es el valor de salvamento del activo de capital al final de la vida de amortización.

Periodo es el periodo de liquidación a considerar.

Tasa es la tasa de amortización.

La base (opcional) se elige de entre una lista de opciones e indica como se calculará el año.

Base | Cálculo
--- | ---
0 u omitido | Método de EE. UU. (NASD), 12 meses de 30 días cada uno
1 | cantidad exacta de días del mes, cantidad exacta de días del año
2 | cantidad exacta de días del mes, para un año se toman 360 días.
3 | cantidad exacta de días del mes, para un año se toman 365 días
4 | Método de Europa, 12 meses de 30 días cada uno

#### Ejemplo

Se obtuvo un activo el 2020-02-01 a un costo de 2000 unidades monetarias. La fecha de finalización del primer período de liquidación fue el 2020-12-31. El valor residual del activo al final de su vida liquidable será de 10 unidades monetarias. La tasa de depreciación es de 0,1 (10%) y el ejercicio se calcula utilizando el método estadounidense (Base 0). Suponiendo una devaluación lineal, ¿Cuál es el importe de la devaluación en el cuarto período de devaluación?

=AMORTIZ.LIN(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0.1; 0) devuelve una cantidad de devolución de 200 unidades monetarias.

Debe tener en cuenta que Microsoft Excel no admite Basis 2. Por tanto, si utiliza Basis 2 y exporta su documento al formato XLSX, cuando lo abra en Excel se producirá un error.

## AMORTIZ.PROGRE

Calcula el importe de la depreciación en un período de liquidación en forma de amortización degresiva. A diferencia de AMORTIZ.LIN, en esta función se utiliza un coeficiente de depreciación independiente de la vida útil depreciable.

#### Sintaxis

AMORTIZ.PROGRE(Costo; Fecha de compra; Primer periodo; Valor residual; Periodo; Tasa [; Base])

Costo son los costos de adquisición.

FechaDeCompra es la fecha de la adquisición.

PrimerPeriodo es la fecha de vencimiento del primer periodo de liquidación.

Salvamento es el valor de salvamento del activo de capital al final de la vida de amortización.

Periodo es el periodo de liquidación a considerar.

Tasa es la tasa de amortización.

La base (opcional) se elige de entre una lista de opciones e indica como se calculará el año.

Base | Cálculo
--- | ---
0 u omitido | Método de EE. UU. (NASD), 12 meses de 30 días cada uno
1 | cantidad exacta de días del mes, cantidad exacta de días del año
2 | cantidad exacta de días del mes, para un año se toman 360 días.
3 | cantidad exacta de días del mes, para un año se toman 365 días
4 | Método de Europa, 12 meses de 30 días cada uno

#### Ejemplo

Se adquirió un activo el 1 de febrero de 2020 a un coste de 2000 unidades monetarias. La fecha de finalización del primer período de liquidación fue el 31 de diciembre de 2020. El valor residual del activo al final de su vida amortizable será de 10 unidades monetarias. La tasa de depreciación es de 0,1 (10 %) y el ejercicio se calcula utilizando el método estadounidense (base 0). Suponiendo una depreciación decreciente, ¿cuál es el importe de la depreciación en el cuarto período de amortización?

=AMORTIZ.PROGRE(2000; "2020-02-01"; "2020-12-31"; 10; 4; 0,1; 0) devuelve una cantidad de amortización de 163 unidades monetarias.

Debe tener en cuenta que Microsoft Excel no admite Basis 2. Por tanto, si utiliza Basis 2 y exporta su documento al formato XLSX, cuando lo abra en Excel se producirá un error.

## CANTIDAD.RECIBIDA

Calcula la cantidad recibida que se paga por un valor a interés fijo en un momento determinado.

#### Sintaxis

CANTIDAD.RECIBIDA(Liquidación; Vencimiento; Inversión; Descuento [; Base])

Liquidación es la fecha de compra de la garantía.

Vencimiento es la fecha cuando la garantía vence (expira).

Inversión es el valor de la compra.

Descuento es el porcentaje de descuento en la adquisición de la garantía.

La base (opcional) se elige de entre una lista de opciones e indica como se calculará el año.

Base | Cálculo
--- | ---
0 u omitido | Método de EE. UU. (NASD), 12 meses de 30 días cada uno
1 | cantidad exacta de días del mes, cantidad exacta de días del año
2 | cantidad exacta de días del mes, para un año se toman 360 días.
3 | cantidad exacta de días del mes, para un año se toman 365 días
4 | Método de Europa, 12 meses de 30 días cada uno

#### Ejemplo

Fecha de liquidación: 15 de febrero de 1999, fecha de vencimiento: 15 de mayo de 1999, cantidad de inversión: 1000 unidades monetarias, Tasa de descuento: 5,75 por ciento, Bases: Balance_diario/360 = 2.

La cantidad de liquidación en la fecha de vencimiento se calcula de esta forma:

=CANTIDAD.RECIBIDA ("1999-02-15";"1999-05-15";1000;0.0575;2) devuelve 1.014,420266.

## DB

Devuelve la depreciación de un activo en un período determinado mediante el método de amortización de saldo decreciente.

Utilice este modo de amortización para obtener, al contrario que con el modo lineal, un valor de amortización mayor al inicio de la amortización. Con cada período de amortización, dicho valor se reduce en las amortizaciones ya deducidas del valor de compra.

#### Sintaxis

DB(Costo; Recuperación; Vida; Periodo [; Mes])

Costo es el costo inicial de un activo.

Salvamento es el valor de un activo al final de la amortización.

Vida define el período durante el cual se amortiza un activo.

Período es la duración de cada período. La duración debe indicarse en la misma unidad de tiempo que el periodo de amortización.

Mes (opcional) indica la cantidad de meses para el primer año de amortización. Si no se indica nada, se usa el valor 12 como predeterminado.

#### Ejemplo

Un equipo de computo tiene un costo inicial de 25.000 unidades monetarias debe liquidarse en un periodo de tres años. El valor residual es de 1.000 unidades monetarias. El primer período de liquidación es 6 meses. ¿Cuál es la liquidación de saldo fijo-declina del equipo de computo en el segundo período, que es un año completo a partir del final del primer semestre?

=DB(25000; 1000; 3; 2; 6) devuelve 11,037.95 unidades monetarias.

## DDB

Devuelve la depreciación de un activo en un período específico según el método aritmético degresivo.

Esta forma de depreciación es la adecuada si precisa un valor más alto de depreciación inicial, a diferencia de la depreciación lineal. El valor de depreciación disminuye con cada período; suele utilizarse en aquellos activos que pierden más valor poco después de su adquisición (por ejemplo, automóviles o equipos informáticos). Tenga en cuenta que el valor contable nunca llegará a cero con este tipo de cálculo.

#### Sintaxis

DDB(Costo; Recuperación; Vida; Periodo [; Factor])

Costo fija el costo inicial de un activo.

Salvamento fija el valor de un activo al final de su vida.

Vida es el número de períodos (por ejemplo, años o meses) que definen la duración del uso del activo.

Período define el período para el que debe calcularse el valor.

Factor (opcional) es el factor por el que disminuye la amortización. Si no se indica un valor, el factor predeterminado es 2.

#### Ejemplo

Un equipo informático con un precio de compra de 75 000 unidades monetarias debe amortizarse mensualmente durante 5 años. El valor residual debe ser 1 unidad monetaria. El factor es 2.

=DDB(75000;1;60;12;2) = 1721,81 unidades monetarias. Por lo tanto, la amortización degresiva en plazos dobles en el mes doce tras la compra es de 1721,81 unidades monetarias.

## DURACION

Calcula la duración, en años, de un valor de interés fijo.

#### Sintaxis

DURACION(Liquidación; Vencimiento; Cupón; Rendimiento; Frecuencia [; Base])

Liquidación es la fecha de compra de la garantía.

Vencimiento es la fecha cuando la garantía vence (expira).

Vale es la tasa anual de interés del vale (tasa nominal de interés)

Rendimeinto es la ganancia anual de la garantía.

Frecuencia es la cantidad de pagos de interés al año (1, 2 o 4).

La base (opcional) se elige de entre una lista de opciones e indica como se calculará el año.

Base | Cálculo
--- | ---
0 u omitido | Método de EE. UU. (NASD), 12 meses de 30 días cada uno
1 | cantidad exacta de días del mes, cantidad exacta de días del año
2 | cantidad exacta de días del mes, para un año se toman 360 días.
3 | cantidad exacta de días del mes, para un año se toman 365 días
4 | Método de Europa, 12 meses de 30 días cada uno

#### Ejemplo

Un valor se compra el 01-01-2001; la fecha de vencimiento es el 01-01-2006. El interés nominal asciende al 8 %. La rentabilidad es del 9 %. El interés se paga semestralmente (la frecuencia es 2). ¿Cuál es la duración al realizar un cálculo (base 3) diario?

=DURACION("2001-01-01";"2006-01-01";0.08;0.09;2;3) devuelve 4,2 años.

## INT.ACUM

Calcula el interés acumulado de un valor en el caso de pagos periódicos de intereses.

#### Sintaxis

INT.ACUM(Informe; Primer interés; Liquidación; Tasa; [Par]; Frecuencia [; Base])

Emisión (obligatorio) es la fecha de emisión de la garantía.

PrimerInterés (obligatorio) es la fecha del primer interés de la garantía.

Liquidación (obligatorio) es la fecha en que se deben calcular los intereses devengados hasta ese momento.

Tasa (obligatorio) es la tasa nominal anual de interés (tasa de interés del vale)

Paridad (opcional) es el valor a la par del título. Si se omite, se emplea un valor predeterminado de 1000.

Recomendamos que siempre especifique el valor que necesita para el argumento Paridad de INT.ACUM, en lugar de permitir que Calc aplique un valor predeterminado arbitrario. Esto hará que su fórmula sea más fácil de entender y de mantener.

Frecuencia (obligatorio) es la cantidad de pagos de interés al año (1, 2 o 4).

La base (opcional) se elige de entre una lista de opciones e indica como se calculará el año.

Base | Cálculo
--- | ---
0 u omitido | Método de EE. UU. (NASD), 12 meses de 30 días cada uno
1 | cantidad exacta de días del mes, cantidad exacta de días del año
2 | cantidad exacta de días del mes, para un año se toman 360 días.
3 | cantidad exacta de días del mes, para un año se toman 365 días
4 | Método de Europa, 12 meses de 30 días cada uno

#### Ejemplo

Se emite un título el 28-02-2001. El primer interés se establece para el 31-08-2001. La fecha de liquidación es el 01-05-2001. El interés es del 0,1 % o del 10 %, y el valor nominal es de 1000 unidades monetarias. El interés se paga semestralmente (la frecuencia es 2). La base es el método estadounidense (0). ¿Qué interés se ha acumulado?

=INT.ACUM("2001-02-28";"2001-08-31";"2001-05-01";0.1;1000;2;0) devuelve 16,94444.

## INT.ACUM.V

Calcula el interés acumulado de un valor en el caso de un pago único en la fecha de liquidación.

#### Sintaxis

INT.ACUM.V(Informe; Liquidación; Tasa [; Par [; Base]])

Emisión (obligatorio) es la fecha de emisión de la garantía.

Liquidación (obligatorio) es la fecha en que se deben calcular los intereses devengados hasta ese momento.

Tasa (obligatorio) es la tasa nominal anual de interés (tasa de interés del vale)

Paridad (opcional) es el valor a la par del título. Si se omite, se emplea un valor predeterminado de 1000.

Recomendamos que siempre especifique el valor que necesita para el argumento Par de INT.ACUM.V, en lugar de permitir que Calc aplique un valor predeterminado arbitrario. Esto hará que su fórmula sea más fácil de entender y de mantener.

La base (opcional) se elige de entre una lista de opciones e indica como se calculará el año.

Base | Cálculo
--- | ---
0 u omitido | Método de EE. UU. (NASD), 12 meses de 30 días cada uno
1 | cantidad exacta de días del mes, cantidad exacta de días del año
2 | cantidad exacta de días del mes, para un año se toman 360 días.
3 | cantidad exacta de días del mes, para un año se toman 365 días
4 | Método de Europa, 12 meses de 30 días cada uno

#### Ejemplo

Se emite un título el 01-04-2001. La fecha de vencimiento se establece para el 15-06-2001. El interés es del 0,1 % o 10 % y el valor nominal es de 1000 unidades monetarias. La base del cálculo diario/anual es el saldo diario (3). ¿Qué interés se ha acumulado?

=INT.ACUM.V("2001-04-01";"2001-06-15";0.1;1000;3) devuelve 20,54795.

.

## INT.EFECTIVO

Calcula el interés efectivo anual respecto a una tasa de interés nominal.

Como la tasa de interés nominal se basa en un vencimiento de intereses al final del período de cálculo y en cambio, por lo general, los intereses se abonan mensual o trimestralmente, incluso en otros períodos anteriores al final del período de cálculo (es decir, se pagan por adelantado), los intereses efectivos se incrementan con el número de pagos parciales de intereses.

#### Sintaxis

INT.EFECTIVO(Nom; P)

Nom es el interés nominal.

P es la cantidad de periodos de pago de intereses por año.

#### Ejemplo

Si los intereses nominales anuales son del 9,75 % y se han previsto cuatro períodos de cálculo de intereses, ¿cuál es la tasa de interés real (intereses efectivos)?

=INT.EFECTIVO(9,75%;4) = 10,11 %. La tasa de interés efectiva es, por tanto, de 10,11 %.

## INT.EFECTIVO_ADD

Calcula la tasa efectiva de interés anual a partir de la tasa de interés nominal y el número de pagos de intereses por año.

Las funciones cuyos nombres acaban en _ADD o _EXCEL2003 devuelven los mismos resultados que las funciones correspondientes de Microsoft Excel 2003 sin el sufijo. Utilice las funciones sin sufijo para obtener resultados basados en estándares internacionales.

#### Sintaxis

INT.EFECTIVO_ADD(TasaNominal; NPorA)

TasaNominal es la tasa nominal anual de interés.

NPorA es el número de pagos de intereses por año.

#### Ejemplo

¿Cuál es el interés efectivo con un interés nominal del 5,25 % y un pago trimestral?

=INT.EFECTIVO_ADD(0,0525;4) devuelve 0,053543 o 5,3543 %.

## INT.PAGO.DIR

Calcula el nivel de interés en el caso de cuotas de amortización invariables.

#### Sintaxis

INT.PAGO.DIR(Tasa; Periodo; TotalPeriodos; Inversión)

Tasa establece la tasa periódica de interés.

Período es el número de cuotas para el cálculo de intereses.

PeríodosTotales es la cantidad total de periodos de liquidación.

Inversión es la cantidad invertida.

#### Ejemplo

Para un crédito de 120 000 unidades monetarias, un período de dos años y cuotas mensuales con una tasa de interés anual del 12 %, se necesita conocer el nivel de interés al cabo de 1,5 años.

=INT.PAGO.DIR(1%;18;24;120000) = -300 unidades monetarias. El interés mensual después de 1,5 años, alcanza las 300 unidades monetarias.

## SYD

Calcula la tasa de depreciación de aritmética decreciente.

Utilice esta función para calcular el importe de amortización de un período determinado durante el período de amortización completo de un objeto. La amortización digital reduce el importe de amortización de un período a otro en un importe fijo.

#### Sintaxis

SYD(Costo; Valor de salvamento; Vida; Periodo)

Costo es el costo inicial de un activo.

Salvamento es el valor de un activo tras la amortización.

Vida es el periodo que fija el intervalo de tiempo durante el cual un activo se amortiza.

Período define el período para el que debe calcularse la amortización.

#### Ejemplo

Un equipo de vídeo con un precio de compra de 50 000 unidades monetarias debe depreciarse anualmente durante 5 años. El valor de rescate debe ser de 10 000 unidades monetarias. Determine la amortización correspondiente al primer año.

=SYD(50000;10000;5;1)=13.333,33 unidades monetarias. El monto de la amortización para el primer año es de 13.333,33 unidades monetarias.

Es recomendable definir una tabla de amortización para ver fácilmente todas las tasas de amortización por período. Si introduce una tras otra las diferentes fórmulas de cálculo de amortización de LibreOffice Calc, se muestra también la forma de amortización más ventajosa en cada caso. Cree una tabla del modo siguiente:

| A | B | C | D | E
1 | Costo inicial | Valor de salvamento | Vida útil | Intervalo de tiempo | Amortiz. SYD
2 | 50 000 unidades monetarias | 10 000 unidades monetarias | 5 | 1 | 13.333,33 unidades monetarias
3 |  |  |  | 2 | 10.666,67 unidades monetarias
4 |  |  |  | 3 | 8000,00 unidades monetarias
5 |  |  |  | 4 | 5.333,33 unidades monetarias
6 |  |  |  | 5 | 2.666,67 unidades monetarias
7 |  |  |  | 6 | 0,00 unidades monetarias
8 |  |  |  | 7 |
9 |  |  |  | 8 |
10 |  |  |  | 9 |
11 |  |  |  | 10 |
12 |  |  |  |  |
13 | 0 |  |  | Total | 40 000,00 unidades monetarias

La fórmula de E2 es la siguiente:

=SYD($A$2;$B$2;$C$2;D2)

Esta fórmula se duplica en la columna E hasta la celda E10 (seleccionar E2 y arrastrar la esquina inferior derecha hacia abajo con el ratón).

En la celda E13 se encuentra la fórmula que suma todos los importes de la amortización para su comprobación. Se sirve de la función SUMAR.SI porque los valores negativos en E8:E11 no deben tenerse en cuenta. La condición >0 se encuentra en la celda A13. La fórmula de E13 es la siguiente:

=SUMAR.SI(E2:E11;A13)

A continuación podrá ver la amortización a 10 años, consultarla con un valor de salvamento de 1 unidad monetaria, introducir otros precios de compra, etc.

## TASA.DESC

Calcula la provisión (descuento) de un valor en forma de porcentaje.

#### Sintaxis

TASA.DESC(Liquidación; Vencimiento; Precio; Rembolso [; Base])

Liquidación es la fecha de compra de la garantía.

Vencimiento es la fecha cuando la garantía vence (expira).

Precio es el precio de la garantía por cada 100 unidades monetarias de valor nominal.

Rescate es el valor de rescate de la garantía por cada 100 unidades monetarias de valor nominal.

La base (opcional) se elige de entre una lista de opciones e indica como se calculará el año.

Base | Cálculo
--- | ---
0 u omitido | Método de EE. UU. (NASD), 12 meses de 30 días cada uno
1 | cantidad exacta de días del mes, cantidad exacta de días del año
2 | cantidad exacta de días del mes, para un año se toman 360 días.
3 | cantidad exacta de días del mes, para un año se toman 365 días
4 | Método de Europa, 12 meses de 30 días cada uno

#### Ejemplo

Se compra un valor el 25-01-2001; la fecha de vencimiento es el 15-11-2001. El precio (precio de compra) es 97, el valor de rendimiento es 100. Con el cálculo diario (base 3) ¿cuál es la liquidación (descuento)?

=TASA.DESC("2001-01-25";"2001-11-15";97;100;3) devuelve alrededor de 0,0372 o 3,72 %.

## TIR

Calcula la tasa interna de retorno de una inversión. Los valores representan el efectivo a intervalos regulares: al menos un valor debe ser negativo (pagos) y al menos un valor debe ser positivo (ingreso).

Si los pagos ocurren en intervalos irregulares, utilice la función TIR.NO.PER.

#### Sintaxis

TIR(Valores [; Estimación])

Valores representa a una matriz que contiene los valores.

Estimación (opcional) es el valor estimado. Se usa un método iterativo para calcular la tasa interna de retorno. Si solamente se pueden proporcionar algunos valores, se deben proporcionar valores estimados iniciales para permitir la iteración.

Esta función ignora cualquier texto o celda vacía dentro de un intervalo de datos. Si sospecha que los resultados de esta función son erróneos, busque texto en los intervalos de datos. Para resaltar el contenido del texto en un intervalo de datos, utilice la funcionalidad de resalte de valores.

#### Ejemplo

Bajo el supuesto de que los contenidos de las celdas sean: A1=-10000, A2=3500, A3=7600 y A4=1000, la fórmula =TIR(A1:A4) da un resultado de 11,33 %.

Debido al método de cálculo iterativo empleado, es posible que TIR falle y devuelva el error 523 y el mensaje «Error: el cálculo no converge» en la barra de estado. En este caso, pruebe con otro valor en Estimación.

## VA

Calcula el valor efectivo resultante de una inversión fruto de una serie de pagos regulares.

Utilice esta función para calcular la suma de dinero que debe invertir hoy a un interés fijo para recibir pagos regulares (anualidades) durante un determinado número de períodos. Opcionalmente, también es posible definir el importe que debe quedar disponible al final de estos períodos. Se puede especificar también si el importe que debe satisfacerse se abona respectivamente al inicio o al final de un período.

Indique los valores en forma de números, expresiones o referencias. Si, por ejemplo, percibe intereses anuales del 8 % pero desea definir como período el mes, digite 8%/12 en el campo Tasa y LibreOffice Calc calculará automáticamente el factor correcto.

#### Sintaxis

VA (Tasa; NPer; Pago [; VF [; Tipo]])

Tasa es la tasa de interés por período.

NPer es la cantidad total de periodos de pagos (periodo de pago).

Pago es el pago regular realizado en cada periodo.

VF (opcional) define el valor futuro que queda tras el pago de la última cuota.

Tipo (opcional) es la fecha de vencimiento para los pagos. Tipo = 1 significa que el vencimiento tiene lugar al inicio del período, mientras que Tipo = 0 (el valor predeterminado) indica que el vencimiento se produce al final del período.

En las funciones de LibreOffice Calc, los parámetros marcados como «opcionales» pueden omitirse siempre y cuando no haya ningún parámetro inmediatamente después. Por ejemplo, en una función de cuatro parámetros cuyos dos últimos están marcados como «opcionales», puede omitirse el parámetro 4 o los parámetros 3 y 4; sin embargo, no se puede omitir solamente el parámetro 3.

#### Ejemplo

¿Cuál es el valor efectivo de una inversión si se abonan 500 unidades monetarias al mes y la tasa de interés anual es del 8 %? Siendo el período de pago de 48 meses y el valor final de 20 000 unidades monetarias:

=VA(8%/12;48;500;20000) = −35 019,37 unidades monetarias. En las condiciones especificadas, se tienen que depositar 35 019,37 unidades monetarias el día de hoy, si se desea recibir 500 unidades monetarias mensualmente por 48 meses, quedando 20 000 unidades pendientes al final. La verificación cruzada indica que 48 × 500 unidades monetarias + 20 000 unidades monetarias = 44 000 unidades monetarias. La diferencia entre este monto y las 35 000 unidades depositadas representa el interés pagado.

Si en lugar de introducir valores directamente lo hace en forma de referencia en la fórmula, puede efectuar cálculos estimativos del tipo «si/entonces». Recuerde definir las referencias a las constantes como referencias absolutas. En las funciones de amortización se encuentran ejemplos de este tipo de aplicación.

Funciones financieras, parte dos

Funciones financieras, parte tres

Funciones por categoría

¡Necesitamos su ayuda!