Περιεχόμενα

# Συνάρτηση CreateUnoService

Δημιουργεί μια υπηρεσία Uno με το ProcessServiceManager.

### Σύνταξη:

         CreateUnoService(serviceName As String) As Object

### Τύπος επιστροφής:

Object

### Παράμετροι:

Όνομα | Τύπος | Περιγραφή
--- | --- | ---
serviceName | String | The service name. Για έναν κατάλογο με τις διαθέσιμες υπηρεσίες, επισκεφτείτε τη σελίδα αναφοράς com::sun::star Module reference page.

### Παράδειγμα:

Το παρακάτω παράδειγμα δημιουργεί τη συνάρτηση FileExists που χρησιμοποιεί την υπηρεσία com.sun.star.ucb.SimpleFileAccess για να ελέγξει εάν μια δεδομένη διαδρομή είναι ένα υπάρχον αρχείο.

        Function FileExists(sPath as String) As Boolean
            Dim svcSFA As Object
            Set svcSFA = CreateUnoService("com.sun.star.ucb.SimpleFileAccess")
            Dim bExists As Boolean : bExists = svcSFA.exists(sPath)
            Dim bIsFolder As Boolean : bIsFolder = svcSFA.IsFolder(sPath)
            FileExists = bExists And Not bIsFolder
        End Function ' FileExists

Οι υπηρεσίες UNO διαθέτουν εκτενή ηλεκτρονική τεκμηρίωση στον ιστότοπο api.libreoffice.org. Επισκεφτείτε τη σελίδα SimpleFileAccess Service για να μάθετε περισσότερα σχετικά με τις μεθόδους αναφοράς υπηρεσία που χρησιμοποιούνται στο παραπάνω παράδειγμα.

### Παράδειγμα:

The following code uses the service com.sun.star.ui.dialogs.FilePicker to show an open file dialog:

    Sub Main
       fName = FileOpenDialog ("Παρακαλώ επιλέξτε ένα αρχείο")
       print "επιλεγμένο αρχείο: "+fName
    End Sub

    Function FileOpenDialog(title As String) As String
       res = com.sun.star.ui.dialogs.ExecutableDialogResults
       filepicker = CreateUnoService("com.sun.star.ui.dialogs.FilePicker")
       With filepicker
          .Title = title
          .MultiSelectionMode = True
          .appendFilter("Calc docs","*.ods;*.csv;*.123")
          .appendFilter("Writer or Base docs","*.odt;*.odb")
          .appendFilter("All files","*.*")
           If res.OK = .execute() Then
              files = .getSelectedFiles()
              FileOpenDialog=files(0)
           EndIf
       End With
    End Function ' FileOpenDialog

Σχετικά θέματα

CreateUnoServiceWithArguments Συνάρτηση

Αντικείμενα, συναρτήσεις και υπηρεσίες UNO

Χρήση συναρτήσεων Calc σε μακροεντολές

Παρακαλούμε, υποστηρίξτε μας!