Περιεχόμενα

# SUMIF

Προσδιορίζει ποιες τιμές σε μια περιοχή κελιών πληρούν ένα καθορισμένο κριτήριο και, στη συνέχεια, επιστρέφει το άθροισμα των τιμών που ταιριάζουν. Εναλλακτικά, η συνάρτηση μπορεί να καθορίσει ποιες τιμές σε μια περιοχή κελιών πληρούν ένα κριτήριο και, στη συνέχεια, να επιστρέψει το άθροισμα των τιμών στα αντίστοιχα κελιά σε μια δεύτερη περιοχή κελιών.

Η SUMIF μπορεί να εφαρμόσει μόνο ένα κριτήριο σε μια περιοχή. Χρησιμοποιήστε SUMIFS εάν χρειάζεται να εφαρμόσετε πολλά κριτήρια.

#### Σύνταξη

SUMIF(Περιοχή; Κριτήρια [;ΠεριοχήΆθροισης])

Περιοχή: Η περιοχή των κελιών στα οποία εφαρμόζεται το κριτήριο.

Η SUMIF υποστηρίζει τον τελεστή συνένωσης αναφοράς (~) μόνο στην παράμετρο Περιοχή και μόνο εάν δεν δίνεται η προαιρετική παράμετρος ΠεριοχήΑθροίσματος.

Κριτήριο1: Ένα κριτήριο είναι μια έκφραση κειμένου που υπολογίζεται από ένα μόνο κελί αναφοράς, τύπου, αριθμού ή κειμένου. Χρησιμοποιείται σε συγκρίσεις με τα περιεχόμενα των κελιών.

Μια αναφορά σε κενό κελί ερμηνεύεται ως η αριθμητική τιμή 0.

Μια σύμφωνη έκφραση μπορεί να είναι:

- Ένας αριθμός ή μια λογική τιμή. Ένα αντίστοιχο περιεχόμενο κελιού ισούται με τον αριθμό ή τη λογική τιμή.

- Μια τιμή που ξεκινά με έναν συγκριτικό (<, <=, =, >, >=, <>).

  Για =, εάν η τιμή είναι κενή αντιστοιχεί σε κενά κελιά.

  Για το <>, εάν η τιμή είναι κενή αντιστοιχεί σε μη κενά κελιά.

  Για το <>, εάν η τιμή δεν είναι κενή, αντιστοιχεί σε οποιοδήποτε περιεχόμενο κελιού εκτός από την τιμή, συμπεριλαμβανομένων των κενών κελιών.

  Σημείωση: "=0" δεν συμφωνεί με κενά κελιά.

  Για = και <>, εάν η τιμή δεν είναι κενή και δεν μπορεί να ερμηνευτεί ως τύπος αριθμού ή ένας από τους υποτύπους του και η ιδιότητα Κριτήρια αναζήτησης = και <> πρέπει να ισχύουν για ολόκληρα κελιά έχει επιλεγεί, η σύγκριση γίνεται με ολόκληρο το περιεχόμενο του κελιού. Εάν είναι μη επιλεγμένο, η σύγκριση γίνεται με οποιοδήποτε υποτμήμα του πεδίου που αντιστοιχεί στα κριτήρια. Για = και <>, εάν η τιμή δεν είναι κενή και δεν μπορεί να ερμηνευθεί ως τύπος Αριθμού ή ισχύει ένας από τους υποτύπους του.

- Άλλη τιμή κειμένου. Εάν η ιδιότητα Κριτήρια αναζήτησης = και <> πρέπει να ισχύει για ολόκληρα κελιά είναι αληθής , η σύγκριση γίνεται με το σύνολο των περιεχομένων του κελιού. Εάν είναι ψευδής, η σύγκριση γίνεται με οποιοδήποτε υποτμήμα του πεδίου που αντιστοιχεί στα κριτήρια. Η έκφραση μπορεί να περιέχει κείμενο, αριθμούς, κανονικές εκφράσεις ή χαρακτήρες υποκατάστασης (εάν είναι ενεργοποιημένη στις επιλογές υπολογισμού).

Η αναζήτηση υποστηρίζει χαρακτήρες Υποκατάστασης (μπαλαντέρ) ή κανονικές εκφράσεις. Με ενεργοποιημένες τις κανονικές εκφράσεις, μπορείτε να εισαγάγετε "all.*", για παράδειγμα, για να βρείτε την πρώτη θέση του "all" ακολουθούμενη από οποιουσδήποτε χαρακτήρες. Εάν θέλετε να αναζητήσετε ένα κείμενο που είναι επίσης κανονική έκφραση, πρέπει είτε να προηγηθεί κάθε μεταχαρακτήρα ή τελεστή κανονικής έκφρασης με έναν χαρακτήρα "\" ή να περικλείσετε το κείμενο στο \Q...\E. Μπορείτε να ενεργοποιήσετε και να απενεργοποιήσετε την αυτόματη αξιολόγηση χαρακτήρων υποκατάστασης ή κανονικής έκφρασης στο LibreOffice - Προτιμήσεις Εργαλεία - Επιλογές - LibreOffice Υπολογισμός - Υπολογισμός .

Όταν χρησιμοποιείτε συναρτήσεις όπου ένα ή περισσότερα ορίσματα είναι συμβολοσειρές κριτηρίων αναζήτησης που αντιπροσωπεύουν κανονική έκφραση, η πρώτη προσπάθεια είναι η μετατροπή των κριτηρίων συμβολοσειρών σε αριθμούς. Παραδείγματος χάρη, το ".0" θα μετατραπεί σε 0.0 κ.ο.κ. Εάν είναι πετυχημένο, η συμφωνία δεν θα είναι συμφωνία κανονικής έκφρασης, αλλά αριθμητική συμφωνία. Όμως, όταν αλλάζετε στις τοπικές ρυθμίσεις όπου ο δεκαδικός διαχωριστής δεν είναι η τελεία, η μετατροπή της κανονικής έκφρασης λειτουργεί. Για να εξαναγκάσετε την αξιολόγηση της κανονικής έκφρασης αντί για την αριθμητική έκφραση, χρησιμοποιήστε κάποια έκφραση που δεν μπορεί να παρανοηθεί ως αριθμητική, όπως ".[0]", ή ".\0", ή "(?i).0".

ΠεριοχήΑθροίσματος: Προαιρετικό. Η περιοχή των κελιών από τα οποία αθροίζονται οι τιμές. Εάν δεν δοθεί η ΠεριοχήΑθροίσματος, αθροίζονται οι τιμές στο Περιοχή.

Αυτή η συνάρτηση είναι τμήμα του προτύπου της μορφής Open Document για εφαρμογές γραφείου (OpenDocument) έκδοσης 1.2. (ISO/IEC 26300:2-2015)

### Παραδείγματα

Θεωρήστε τον ακόλουθο πίνακα

| A | B | C
1 | Όνομα προϊόντος | Sales | Revenue
2 | μολύβι | 20 | 65
3 | στυλό | 35 | 85
4 | σημειωματάριο | 20 | 190
5 | βιβλίο | 17 | 180
6 | κασετίνα | όχι | όχι

Σε όλα τα παρακάτω παραδείγματα, οι περιοχές για τον υπολογισμό περιέχουν τη γραμμή #6 που αγνοείται, επειδή περιέχει κείμενο.

#### Απλή χρήση

=SUMIF(C2:C6;">=100")

Αθροίζει μόνο τις τιμές από την περιοχή C2:C6 που είναι >=100. Επιστρέφει 370 επειδή τα κελιά C2:C3 δεν πληρούν το κριτήριο. Οι τιμές από την Περιοχή αθροίζονται επειδή δεν δίνεται η ΠεριοχήΑθροίσματος.

=SUMIF(B2:B5;">=20";C2:C6)

Αθροίζει τιμές από την περιοχή B2:B6 μόνο εάν οι αντίστοιχες τιμές στην περιοχή A1:A5 είναι >=20. Επιστρέφει 340 επειδή η πέμπτη και η έκτη σειρά δεν πληρούν το κριτήριο.

#### Χρήση κανονικών εκφράσεων

=SUMIF(A2:A6;"στυλό";C2:C5)

Αθροίζει τιμές από την περιοχή C2:C6 μόνο εάν η αντίστοιχη περιοχή στο A2:A6 ταιριάζει ακριβώς με τα γράμματα "στυλό". Επιστρέφει 85 επειδή οι σειρές A2 και A4:A6 δεν πληρούν το κριτήριο.

=SUMIF(A2:A6;"στυλό*";C2:C6)

Αθροίζει τις τιμές από την περιοχή C2:C6 μόνο εάν το αντίστοιχο κελί στην περιοχή A2:A6 περιέχει τα γράμματα "στυλό". Επιστρέφει την τιμή 150 επειδή οι σειρές A4:A5 δεν πληρούν το κριτήριο.

=SUMIF(ΌνομαΠροϊόντος;"στυλό*";Έσοδα)

Μια ονομασμένη περιοχή μπορεί να δοθεί ως παράμετρος Περιοχή ή ΠεριοχήΑθροίσματος. Για παράδειγμα, εάν οι στήλες στον παραπάνω πίνακα ονομάζονται αντίστοιχα "ΌνομαΠροϊόντος", "Πωλήσεις" και "Εισόδημα", η συνάρτηση επιστρέφει 150. Αυτή η συνάρτηση θα λειτουργεί όπως περιγράφεται μόνο εάν έχετε ορίσει τα ονόματα των στηλών χρησιμοποιώντας τον διάλογο Ορισμός ονομάτων.

#### Η αναφορά σε ένα κελί ως κριτήριο

Εάν πρέπει να αλλάξετε εύκολα ένα κριτήριο, μπορείτε να το καθορίσετε σε ξεχωριστό κελί και να χρησιμοποιήσετε μια αναφορά σε αυτό το κελί στην συνθήκη της συνάρτησης SUMIF. Για παράδειγμα:

=SUMIF(A2:A6;E2;C2:C6)

Εάν E2 = στυλό, η συνάρτηση επιστρέφει 85 επειδή ο σύνδεσμος προς το κελί έχει αντικατασταθεί με τα περιεχόμενά του.

Σχετικά θέματα

Σελίδα βίκι SUMIF.

SUM, SUMIFS

COUNTIF, COUNTIFS, MINIFS, MAXIFS, AVERAGEIFS

Κατάλογος κανονικών εκφράσεων