Περιεχόμενα

# Λήψη πληροφοριών συνόδου

Η επεξεργασία κατατομής (προφίλ) χρήστη του LibreOffice και οι κοινόχρηστες διαδρομές αρχείων συστήματος αρθρωμάτων μπορούν να εκτελεστούν με τις γλώσσες Python ή Basic. Οι θέσεις δεσμών ενεργειών JavaScript και Python μπορεί να παραχθούν από αυτές τις πληροφορίες.

## Παραδείγματα:

Με κέλυφος Python.

>>> from <the_module> import Session

>>> print(Session.SharedPythonScripts()) # στατική μέθοδος

>>> print(Session().UserName) # object property

>>> input(Session().UserProfile) # object property

### Από μενού Εργαλεία – Μακροεντολές - Εκτέλεση μακροεντολής....

            from <the_module> import Session

            def demo_session():
                import screen_io as ui
                ui.MsgBox(Session.Share(),title='Installation Share')  # στατική μέθοδος
                ui.Print(Session.SharedPythonScripts())  # στατική μέθοδος
                s = Session()  # δημιουργία στιγμιοτύπου
                ui.MsgBox(s.UserName,title='Hello')  # ιδιότητα αντικειμένου
                ui.Print(s.UserPythonScripts)  # ιδιότητα αντικειμένου

            g_exportedScripts = (demo_session,)  # δημόσιες μακροεντολές

### Με LibreOffice Basic.

            Sub Session_example()
                Dim s As New Session ' instance of Session class
                Print "Shared scripts location:", s.SharedScripts
                MsgBox s.UserName,,"Hello"
                Print s.UserScripts, Chr(13), s.UserPythonScripts
            End Sub ' Session_example

### Με χρήση γλώσσας COM/OLE και Visual Basic Scripting

            ' Η διαχειριστική υπηρεσία είναι πάντα στο σημείο εισόδου
            ' Εάν δεν υπάρχει εκτελούμενο office, τότε ξεκινά το office
            Set sm = WScript.CreateObject("com.sun.star.ServiceManager")
            ' Η υπηρεσία PathSubstitution εμφανίζει πληροφορίες για συμπέρασμα
            ' θέσεις από <UserProfile|Share>/Scripts/python
            Set obj = sm.createInstance("com.sun.star.util.PathSubstitution")

            MsgBox CreateObject("WScript.Network").UserName,, "Hello"
            user = obj.getSubstituteVariableValue("$(user)")
            MsgBox user & "/Scripts",, "User scripts location"
            libO = Replace(obj.getSubstituteVariableValue("$(inst)"), "program/..", "Share")
            MsgBox libO & "/Scripts",, "Shared scripts location"

## Κλάση συνόδου Python:

            import getpass, os, os.path, uno

            class Session():
                @staticmethod
                def substitute(var_name):
                    ctx = uno.getComponentContext()
                    ps = ctx.getServiceManager().createInstanceWithContext(
                        'com.sun.star.util.PathSubstitution', ctx)
                    return ps.getSubstituteVariableValue(var_name)
                @staticmethod
                def Share():
                    inst = uno.fileUrlToSystemPath(Session.substitute("$(prog)"))
                    return os.path.normpath(inst.replace('program', "Share"))
                @staticmethod
                def SharedScripts():
                    return ''.join([Session.Share(), os.sep, "Scripts"])
                @staticmethod
                def SharedPythonScripts():
                    return ''.join([Session.SharedScripts(), os.sep, 'python'])
                @property  # εναλλακτική στη μεταβλητή '$(username)'
                def UserName(self): return getpass.getuser()
                @property
                def UserProfile(self):
                    return uno.fileUrlToSystemPath(Session.substitute("$(user)"))
                @property
                def UserScripts(self):
                    return ''.join([self.UserProfile, os.sep, 'Scripts'])
                @property
                def UserPythonScripts(self):
                    return ''.join([self.UserScripts, os.sep, "python"])

Αντίθετα με τη Basic, η κανονικοποίηση ονόματος διαδρομής εκτελείται με την Python μέσα σε κλάση συνόδου.

## Η κλάση συνόδου της Basic LibreOffice

            Option Explicit
            Option Compatible
            Option ClassModule

            Private _ps As Object ' ιδιωτικό μέλος

            Private Sub Class_Initialize()
                GlobalScope.BasicLibraries.LoadLibrary("Tools")
                Set _ps = CreateUnoService("com.sun.star.util.PathSubstitution")
            End Sub ' κατασκευή

            Private Sub Class_Terminate()
                _ps = Nothing
            End Sub ' Καταστροφέας

            Public Property Get SharedScripts() As String
                Dim inst As String, shr As String
                inst = ConvertFromURL(_ps.getSubstituteVariableValue("$(prog)"))
                shr = Tools.Strings.ReplaceString(inst,"Share","program")
                SharedScripts = shr & GetPathSeparator() &"Scripts"
            End Property ' Session.sharedScripts

            Public Property Get SharedPythonScripts() As String
                sharedPythonScripts = sharedScripts() & GetPathSeparator() &"python"
            End Property ' Session.sharedPythonScripts

            Public Property Get UserName() As String ' Όνομα λογαριασμού χρήστη
                userName = _ps.getSubstituteVariableValue("$(username)")
            End Property ' Session.userName

            Public Property Get UserProfile() As String ' Διαδρομή συστήματος κατατομών (προφίλ) χρήστη
                userProfile = ConvertFromURL(_ps.getSubstituteVariableValue("$(user)"))
            End Property ' Session.userProfile

            Public Property Get UserScripts() As String ' Διαδρομή συστήματος δεσμών ενεργειών χρήστη
                userScripts = userProfile() & GetPathSeparator() &"Scripts"
            End Property ' Session.userScripts

            Public Property Get UserPythonScripts() As String ' Διαδρομή συστήματος δεσμών ενεργειών Python χρήστη
                userPythonScripts = userScripts() & GetPathSeparator() &"python"
            End Property ' Session.userPythonScripts

Σχετικά θέματα

Οργάνωση και θέση σεναρίων Python

Εισαγωγή αρθρωμάτων Python

Είσοδος/Έξοδος στην οθόνη

παραδείγματα προγραμματισμού Python