Περιεχόμενα

# Συνάρτηση STYLE

Εφαρμόζει μια τεχνοτροπία στο κελί που περιέχει τον τύπο. Μετά από ένα καθορισμένο χρονικό διάστημα, μπορεί να εφαρμοστεί μια άλλη τεχνοτροπία.

Αυτή η συνάρτηση επιστρέφει πάντα την αριθμητική τιμή 0, η οποία επιτρέπει τη χρήση της προσθέτοντας τη συνάρτηση STYLE σε άλλες συναρτήσεις στο ίδιο κελί χωρίς να αλλάξει η τιμή της.

Η συνάρτηση STYLE δεν πρέπει να χρησιμοποιείται χωρίς επιτακτικό λόγο, σκοπός της είναι η χρήση με ασύγχρονες λειτουργίες πρόσθετου για οπτική ειδοποίηση σχετικά με τη διαθεσιμότητα ενός αποτελέσματος. Σε όλες σχεδόν τις άλλες περιπτώσεις, η χρήση μορφοποίησης υπό όρους είναι καλύτερη επιλογή.

### Σύνταξη

STYLE("Τεχνοτροπία" [; Χρόνος [; "Τεχνοτροπία2"]])

Τεχνοτροπία είναι το όνομα της τεχνοτροπίας κελιού που θα εφαρμοστεί στο κελί. Τα ονόματα τεχνοτροπιών δεν κάνουν διάκριση πεζών-κεφαλαίων και πρέπει να εισάγονται σε εισαγωγικά.

Το Χρόνος είναι ένα προαιρετικό χρονικό εύρος σε δευτερόλεπτα. Αφού παρέλθει αυτός ο χρόνος, εφαρμόζεται η τεχνοτροπία που ορίζεται στο Τεχνοτροπία2 (Style2). Αφήστε αυτήν την παράμετρο κενή εάν δεν θέλετε να αλλάξει την τεχνοτροπία.

Το Τεχνοτροπία2 είναι το προαιρετικό όνομα μιας τεχνοτροπίας κελιού που εκχωρείται στο κελί μετά την πάροδο του χρόνου που καθορίζεται στην παράμετρο Χρόνος. Εάν λείπει αυτή η παράμετρος, εφαρμόζεται η τεχνοτροπία κελιού "Προεπιλογή".

Στις συναρτήσεις του LibreOffice Calc, οι παράμετροι που σημειώνονται ως "προαιρετικές" μπορούν να παραληφθούν μόνο όταν δεν ακολουθεί καμιά παράμετρος. Παραδείγματος χάρη, σε μια συνάρτηση με τέσσερις παραμέτρους, όπου οι δύο τελευταίες παράμετροι είναι σημειωμένες ως "προαιρετικές", μπορείτε να αφήσετε έξω την παράμετρο 4 ή τις παραμέτρους 3 και 4, αλλά δεν μπορείτε να παραλείψετε μόνο την παράμετρο 3.

### Παραδείγματα

=10+STYLE("Καλό",60,"Ουδέτερο")

Εισάγει την τιμή 10 στο κελί και εφαρμόζει την τεχνοτροπία με το όνομα "Καλό". Μετά από 60 δευτερόλεπτα, εφαρμόζεται η τεχνοτροπία "Ουδέτερη".

=A1*A2+STYLE(IF(CURRENT()<100,"Κακό","Καλό"))

Εισάγει το αποτέλεσμα του πολλαπλασιασμού των τιμών στα κελιά A1 και A2 και εφαρμόζει την τεχνοτροπία "Κακό" εάν το αποτέλεσμα είναι μικρότερο από 100, διαφορετικά εφαρμόζεται η τεχνοτροπία "Καλό". Εδώ η συνάρτηση CURRENT() χρησιμοποιείται για να ληφθεί η τρέχουσα αξιολογούμενη τιμή της συνάρτησης στο κελί.

="Συνολικό"&T(STYLE("Αποτέλεσμα"))

Εισάγει το κείμενο "Συνολικό" στο κελί και εφαρμόζει την τεχνοτροπία με το όνομα "Αποτέλεσμα". Σημειώστε ότι αυτό το παράδειγμα ασχολείται με τιμές κειμένου, επομένως η έξοδος της συνάρτησης STYLE πρέπει να προσαρτηθεί στο κείμενο χρησιμοποιώντας τον τελεστή &. Η συνάρτηση T() χρησιμοποιείται για να αποτρέψει την προσάρτηση του αριθμού "0" στο κείμενο που προκύπτει.

#### Τεχνικές πληροφορίες

Αυτή η συνάρτηση δεν αποτελεί μέρος του προτύπου Open Document Format for Office Applications (OpenDocument) Έκδοση 1.3. Μέρος 4: Μορφή επανυπολογισμένου τύπου (OpenFormula). Ο χώρος του ονόματος είναι

ORG.OPENOFFICE.STYLE

Σχετικά θέματα

Σελίδα βίκι STYLE.

Συναρτήσεις υπολογιστικού φύλλου

Εκχώρηση μορφών ανά τύπο

Συνάρτηση CURRENT

Συνάρτηση T