Inhalte
Index 🔎︎

# Statistik Teil 4

## MITTELWERTWENN

Ergibt das arithmetische Mittel aller Zellen eines Bereichs, die eine vorgegebene Bedingung erfüllen. Die Funktion MITTELWERTWENN addiert alle Werte, welche die Bedingung erfüllen, und teilt die Summe durch die Anzahl der zutreffenden Zellen.

## MITTELWERTWENNS

Ergibt das arithmetische Mittel aller Zellen eines Bereichs, die vorgegebene Bedingungen erfüllen. Die Funktion MITTELWERTWENNS addiert alle Werte, welche die Bedingungen erfüllen, und teilt die Summe durch die Anzahl der zutreffenden Zellen.

## MAX

Ergibt den größten Wert innerhalb einer Liste mit Argumenten.

Ergibt 0, wenn kein numerischer Wert und kein Fehler im oder in den Zellbereichen gefunden wurde, der oder die als Zellbezüge weitergegeben wurden. Textzellen werden von MIN() und MAX() ignoriert. Die Funktionen MINA() und MAXA() geben 0 zurück, wenn kein Wert (numerisch oder Text) und kein Fehler gefunden wurde. Wenn ein Zeichenkettenargument, beispielsweise MIN("Zeichenkette"), an MIN() oder MAX() weitergegeben wird, führt dies zu einem Fehler.

#### Syntax

MAX(Zahl 1 [; Zahl 2 [; … [; Zahl 255]]])

Zahl 1, Zahl 2, …, Zahl 255 sind Zahlen oder Verweise auf Zellen oder Zellbereiche mit Zahlen.

Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werthervorhebung.

#### Beispiel

=MAX(A1;A2;A3;50;100;200) ergibt den größten Wert der Liste.

=MAX(A1:B100) ergibt den größten Wert der Liste.

## MAXA

Ergibt den größten Wert innerhalb einer Liste mit Argumenten. Im Gegensatz zu MAX können Sie hierbei auch Text einsetzen. Dieser wird als 0 gewertet.

Die Funktionen MINA() und MAXA() geben 0 zurück, wenn kein Wert (numerisch oder Text) und kein Fehler gefunden wurde.

#### Syntax

MAXA(Zahl 1 [; Zahl 2 [; … [; Zahl 255]]])

Zahl 1, Zahl 2, …, Zahl 255 sind Zahlen oder Verweise auf Zellen oder Zellbereiche mit Zahlen.

#### Beispiel

=MAXA(A1;A2;A3;50;100;200;"Text") ergibt den größten Wert der Liste.

=MAXA(A1:B100) ergibt den größten Wert der Liste.

## MEDIAN

Ergibt den Median der angegebenen Zahlen. Das ist bei einer ungeraden Anzahl von Zahlen der Wert, der in der Liste in der Mitte liegt. Bei einer geraden Anzahl von Werten wird der Mittelwert der beiden mittleren Werte ermittelt.

#### Syntax

MEDIAN(Zahl 1 [; Zahl 2 [; … [; Zahl 255]]])

Zahl 1, Zahl 2, …, Zahl 255 sind Zahlen oder Verweise auf Zellen oder Zellbereiche mit Zahlen.

Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werthervorhebung.

#### Beispiel

Für eine ungerade Zahl: =MEDIAN(1;5;9;20;21) ergibt 9 als Medianwert.

Für eine gerade Zahl: =MEDIAN(1;5;9;20) ergibt den Mittelwert der zwei Zentralwerte 5 und 9, also 7.

## MIN

Ergibt die kleinste Zahl einer Liste mit Argumenten.

Ergibt 0, wenn kein numerischer Wert und kein Fehler im oder in den Zellbereichen gefunden wurde, der oder die als Zellbezüge weitergegeben wurden. Textzellen werden von MIN() und MAX() ignoriert. Die Funktionen MINA() und MAXA() geben 0 zurück, wenn kein Wert (numerisch oder Text) und kein Fehler gefunden wurde. Wenn ein Zeichenkettenargument, beispielsweise MIN("Zeichenkette"), an MIN() oder MAX() weitergegeben wird, führt dies zu einem Fehler.

#### Syntax

MIN(Zahl 1 [; Zahl 2 [; … [; Zahl 255]]])

Zahl 1, Zahl 2, …, Zahl 255 sind Zahlen oder Verweise auf Zellen oder Zellbereiche mit Zahlen.

Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werthervorhebung.

#### Beispiel

=MIN(A1:B100) ergibt den kleinsten Wert der Liste.

## MINA

Ergibt die kleinste Zahl einer Liste mit Argumenten. Sie können hier auch Text eingeben. Dieser wird als 0 gewertet.

Die Funktionen MINA() und MAXA() geben 0 zurück, wenn kein Wert (numerisch oder Text) und kein Fehler gefunden wurde.

#### Syntax

MINA(Zahl 1 [; Zahl 2 [; … [; Zahl 255]]])

Zahl 1, Zahl 2, …, Zahl 255 sind Zahlen oder Verweise auf Zellen oder Zellbereiche mit Zahlen.

#### Beispiel

=MINA(1;"Text";20) ergibt 0.

=MINA(A1:B100) ergibt den kleinsten Wert der Liste.

## MITTELABW

Ergibt die durchschnittliche absolute Abweichung einer Reihe von Merkmalen von ihrem Mittelwert. Zeigt die Streuung in einer Datengruppe.

#### Syntax

MITTELABW(Zahl 1 [; Zahl 2 [; … [; Zahl 255]]])

Zahl 1, Zahl 2, …, Zahl 255 sind Zahlen oder Verweise auf Zellen oder Zellbereiche mit Zahlen.

Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werthervorhebung.

#### Beispiel

=MITTELABW(A1:A50)

## MITTELWERT

Ergibt den Mittelwert der Argumente.

#### Syntax

MITTELWERT(Zahl 1 [; Zahl 2 [; … [; Zahl 255]]])

Zahl 1, Zahl 2, …, Zahl 255 sind Zahlen oder Verweise auf Zellen oder Zellbereiche mit Zahlen.

Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werthervorhebung.

#### Beispiel

=MITTELWERT(A1:A50)

## MITTELWERTA

Ergibt den Mittelwert der Argumente. Text wird dabei als 0 gewertet.

#### Syntax

MITTELWERTA(Zahl 1 [; Zahl 2 [; … [; Zahl 255]]])

Zahl 1, Zahl 2, …, Zahl 255 sind Zahlen oder Verweise auf Zellen oder Zellbereiche mit Zahlen.

#### Beispiel

=MITTELWERTA(A1:A50)

## MODALWERT

Ergibt den Wert, der innerhalb einer Matrix oder einer Datengruppe am häufigsten vorkommt. Gibt es mehrere Werte gleicher Häufigkeit, ergibt es den kleinsten Wert. Kommt kein Wert zweimal vor, wird ein Fehler gemeldet.

Diese Funktion ist Teil des OpenDocument-Standards (Open Document Format for Office Applications) Version 1.2. (ISO/IEC 26300:2-2015)

#### Syntax

MODALWERT(Zahl 1 [; Zahl 2 [; … [; Zahl 255]]])

Zahl 1, Zahl 2, …, Zahl 255 sind Zahlen oder Verweise auf Zellen oder Zellbereiche mit Zahlen.

Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werthervorhebung.

#### Beispiel

=MODALWERT(A1:A50)

## MODUS.EINF

Ergibt den Wert, der innerhalb einer Matrix oder einer Datengruppe am häufigsten vorkommt. Gibt es mehrere Werte gleicher Häufigkeit, ergibt es den kleinsten Wert. Kommt kein Wert zweimal vor, wird ein Fehler gemeldet.

Diese Funktion ist seit LibreOffice 4.3 verfügbar.

#### Syntax

MODUS.EINF(Zahl 1 [; Zahl 2 [; … [; Zahl 255]]])

Zahl 1, Zahl 2, …, Zahl 255 sind Zahlen oder Verweise auf Zellen oder Zellbereiche mit Zahlen.

Wenn der Datensatz keine doppelten Datenpunkte enthält, gibt MODUS.EINF den Fehlerwert #Wert! zurück.

#### Beispiel

=MODUS.EINF(A1:A50)

## MODUS.VIELF

Ergibt eine vertikale Matrix der statistischen Modi (der am häufigsten vorkommenden Werte) innerhalb einer Liste von eingegebenen Zahlen.

Diese Funktion ist seit LibreOffice 4.3 verfügbar.

#### Syntax

MODUS.VIELF(Zahl 1 [; Zahl 2 [; … [; Zahl 255]]])

Zahl 1, Zahl 2, …, Zahl 255 sind Zahlen oder Verweise auf Zellen oder Zellbereiche mit Zahlen.

Die Funktion MUDUS.VIELF ergibt eine Matrix mit Werten und muss deshalb als Matrixformel eingegeben werden. Wird die Funktion nicht als Matrixformel eingegeben, wird nur der erste Modus zurückgegeben, welcher dem Ergebnis der Funktion MODUS.EINF entspricht.

#### Beispiel

=MODUS.VIELF(A1:A50)

## NEGBINOM.VERT

Ergibt die Wahrscheinlichkeit einer negativ binomialverteilten Zufallsvariablen.

Diese Funktion ist seit LibreOffice 4.3 verfügbar.

#### Syntax

NEGBINOM.VERT(X; R; W; Kumulativ)

X ist die Anzahl der Misserfolge in der Versuchsreihe.

R ist die Anzahl der Erfolge in der Versuchsreihe.

W ist die Erfolgswahrscheinlichkeit eines Versuchs.

Kumulativ = 0 berechnet die Dichtefunktion, Kumulativ = 1 berechnet die Verteilung.

#### Beispiel

=NEGBINOM.VERT(1;1;0,5;0) ergibt 0,25.

=NEGBINOM.VERT(1;1;0,5;1) ergibt 0,75.

## NEGBINOMVERT

Ergibt die Wahrscheinlichkeit einer negativ binomialverteilten Zufallsvariablen.

#### Syntax

NEGBINOMVERT(X; R; W)

X ist die Anzahl der Misserfolge in der Versuchsreihe.

R ist die Anzahl der Erfolge in der Versuchsreihe.

W ist die Erfolgswahrscheinlichkeit eines Versuchs.

#### Beispiel

=NEGBINOMVERT(1;1;0,5) ergibt 0,25.

## NORM.INV

Ergibt die Werte der inversen Normalverteilung.

Diese Funktion ist seit LibreOffice 4.3 verfügbar.

#### Syntax

NORM.INV(Zahl; Mittelwert; StAbw)

Zahl ist der Wahrscheinlichkeitswert, zu dem die inverse Normalverteilung berechnet werden soll.

MW ist der Mittelwert der Normalverteilung.

StAbw stellt die Standardabweichung der Normalverteilung dar.

#### Beispiel

=NORM.INV(0,9;63;5) ergibt 69,4077578277. Wenn ein durchschnittliches Ei 63 g wiegt und die Standardabweichung 5 beträgt, besteht eine Wahrscheinlichkeit von 90 %, dass das Ei nicht schwerer als 69,41 g ist.

## NORM.VERT

Ergibt die Dichtefunktion oder die normale Summenverteilung.

Diese Funktion ist seit LibreOffice 4.3 verfügbar.

#### Syntax

NORM.VERT(Zahl; Mittelwert; StAbw; K)

Zahl ist der Wert der Verteilung, zu dem die Normalverteilung berechnet werden soll.

MW ist das arithmetische Mittel der Verteilung.

StAbw ist die Standardabweichung der Verteilung.

K = 0 berechnet die Dichtefunktion, K = 1 die Verteilung.

#### Beispiel

=NORM.VERT(70;63;5;0) ergibt 0,029945493.

=NORM.VERT(70;63;5;1) ergibt 0,9192433408.

## NORMINV

Ergibt die Werte der inversen Normalverteilung.

#### Syntax

NORMINV(Zahl; Mittelwert; StAbw)

Zahl ist der Wahrscheinlichkeitswert, zu dem die inverse Normalverteilung berechnet werden soll.

MW ist der Mittelwert der Normalverteilung.

StAbw stellt die Standardabweichung der Normalverteilung dar.

#### Beispiel

=NORMINV(0,9;63;5) ergibt 69,41. Wenn ein durchschnittliches Ei 63 g wiegt und die Standardabweichung 5 beträgt, besteht eine Wahrscheinlichkeit von 90 %, dass das Ei nicht schwerer als 69,41 g ist.

## NORMVERT

Ergibt die Dichtefunktion oder die normale Summenverteilung.

#### Syntax

NORMVERT(Zahl; Mittelwert; StAbw [; Kumuliert])

Zahl ist der Wert der Verteilung, zu dem die Normalverteilung berechnet werden soll.

MW ist das arithmetische Mittel der Verteilung.

StAbw ist die Standardabweichung der Verteilung.

Kumuliert ist optional. Kumuliert = 0 berechnet die Dichtefunktion, Kumuliert = 1 die Verteilung.

#### Beispiel

=NORMVERT(70;63;5;0) ergibt 0,03.

=NORMVERT(70;63;5;1) ergibt 0,92.

## PEARSON

Ergibt den Pearsonschen Produktmoment-Korrelationskoeffizient r.

#### Syntax

PEARSON(Daten1; Daten2)

Daten1 stellt die Matrix der ersten Datenmenge dar.

Daten2 stellt die Matrix der zweiten Datenmenge dar.

#### Beispiel

=PEARSON(A1:A30;B1:B30) ergibt den Pearsonschen Korrelationskoeffizienten von beiden Datenmengen.

## PHI

Gibt den Wert der Wahrscheinlichkeitsdichtefunktion für einen gegebenen Wert unter Berücksichtigung der Standardnormalverteilung zurück.

#### Syntax

PHI(Zahl)

Zahl ist der Wert, für den die Wahrscheinlichkeitsdichtefunktion berechnet wird.

#### Beispiel

=PHI(2,25) ergibt 0,0317.

=PHI(-2,25) ergibt ebenfalls 0,0317, weil die Normalverteilung symmetrisch ist.

=PHI(0) ergibt 0,3989.

Der Aufruf von PHI(Zahl) entspricht dem Aufruf von NORMVERT(Zahl,0,1,FALSCH()) oder NORM.S.VERT(Zahl;FALSCH()), also unter Verwendung der Standardnormalverteilung mit Mittelwert gleich 0 und Standardabweichung gleich 1, wobei das Argument Kumuliert auf Falsch gesetzt ist.

## POISSON

Ergibt die Wahrscheinlichkeit einer Poisson-verteilten Zufallsvariablen.

#### Syntax

POISSON(Zahl; Mittelwert [; Kumuliert])

Zahl ist der Wert, zu dem eine Poisson-Verteilung berechnet werden soll.

Mittelwert ist der Mittelwert der Poisson-Verteilung.

Kumuliert (optional) = 0 oder FALSCH berechnet die Dichtefunktion; Kumuliert = 1 oder WAHR berechnet die Verteilung. Wenn der Parameter fehlt, wird der Defaultwert WAHR angenommen, wenn Sie das Dokument speichern. Das gewährleistet die beste Kompatibilität mit anderen Programmen und älteren Versionen von LibreOffice.

#### Beispiel

=POISSON(60;50;1) ergibt 0,93.

## POISSON.VERT

Ergibt die Wahrscheinlichkeit einer Poisson-verteilten Zufallsvariablen.

Diese Funktion ist seit LibreOffice 4.2 verfügbar.

#### Syntax

POISSON.DIST(Zahl; Mittelwert ; Kumulativ)

Zahl ist der Wert, zu dem eine Poisson-Verteilung berechnet werden soll.

Mittelwert ist der Mittelwert der Poisson-Verteilung.

Kumulativ = 0 oder Falsch, um die Wahrscheinlichkeitsmassenfunktion zu berechnen; Kumulativ = 1, Wahr oder ein anderer Wert ungleich Null, um die kumulative Verteilungsfunktion zu berechnen.

#### Beispiel

=POISSON.VERT(60;50;1) ergibt 0,9278398202.

## QUANTIL

Ergibt den Alpha-Prozentsatz des Datenwerts in einer Matrix. Ein Prozentsatz ergibt einen Skalenwert für eine Datenreihe, die vom kleinsten (Alpha = 0) bis zum größten Wert (Alpha = 1) der Datenreihe reicht. Bei Alpha = 25 % entspricht dem ersten Quartil; Alpha = 50 % ist der MEDIAN.

#### Syntax

QUANTIL(Daten; Alpha)

Daten ist die Matrix der Daten.

Alpha legt den Prozentsatz des Quantils fest, der zwischen 0 und 1 liegt.

Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werthervorhebung.

#### Beispiel

=QUANTIL(A1:A50;0,1) stellt den Wert in der Datenmenge dar, der 10 % der Gesamtdatenskala in A1:A50 entspricht.

## QUANTIL.EXKL

Ergibt das Alpha-te Quantil eines übergebenen Bereichs von Werten für einen übergebenen Wert Alpha im Bereich von 0 bis 1 (exklusiv). Ein Quantil ergibt den Skalenwert für eine Datenreihe, die vom kleinsten Wert (Alpha=0) bis zum größten Wert (Alpha = 1) eines Datenbereichs reicht. Alpha = 25 % entspricht dem ersten Quartil; Alpha = 50 % ist der MEDIAN.

Wenn Alpha nicht ein Vielfaches von 1/(n+1) ist (wobei n die Anzahl der Werte in der eingegebenen Matrix ist), interpoliert die Funktion zwischen den Werten im eingegebenen Feld, um den Prozentwert zu berechnen. Jedoch ist die Funktion, wenn Alpha kleiner als 1/(n+1) oder Alpha größer als n/(n+1) ist, nicht in der Lage zu interpolieren und ergibt eine Fehlermeldung.

Der Unterschied zwischen QUANTIL.INKL und QUANTIL.EXKL ist, dass bei QUANTIL.INKL der Wert für Alpha im Bereich 0 bis 1 inklusiv ist und bei QUANTIL.EXKL der Wert im Bereich 0 bis 1 exklusiv ist.

Diese Funktion ist seit LibreOffice 4.3 verfügbar.

#### Syntax

QUANTIL.EXKL(Daten; Alpha)

Daten ist die Matrix der Daten.

Alpha legt den Prozentsatz des Quantils fest, der zwischen 0 und 1 liegt.

#### Beispiel

=QUANTIL.EXKL(A1:A50;10%) stellt den Wert der Datenmenge dar, der 10 % der Gesamtdatenskala in A1:A50 entspricht.

## QUANTIL.INKL

Ergibt den Alpha-Prozentsatz des Datenwerts in einer Matrix. Ein Prozentsatz ergibt einen Skalenwert für eine Datenreihe, die vom kleinsten (Alpha = 0) bis zum größten Wert (Alpha = 1) der Datenreihe reicht. Bei Alpha = 25 % entspricht dem ersten Viertel; Alpha = 50 % ist der MEDIAN.

Der Unterschied zwischen QUANTIL.INKL und QUANTIL.EXKL ist, dass bei QUANTIL.INKL der Wert für Alpha im Bereich 0 bis 1 inklusiv ist und bei QUANTIL.EXKL der Wert im Bereich 0 bis 1 exklusiv ist.

Diese Funktion ist seit LibreOffice 4.3 verfügbar.

#### Syntax

QUANTIL.INKL(Daten; Alpha)

Daten ist die Matrix der Daten.

Alpha legt den Prozentsatz des Quantils fest, der zwischen 0 und 1 liegt.

#### Beispiel

=QUANTIL.INKL(A1:A50;0,1) stellt den Wert in der Datenmenge dar, der 10 % der Gesamtdatenskala in A1:A50 entspricht.

## QUANTILSRANG

Ergibt den prozentualen Rang (Alpha) eines Wertes in einer Stichprobe.

#### Syntax

QUANTILSRANG(Daten; Wert [; Signifikanz])

Daten ist die Matrix der Daten in der Stichprobe.

Wert ist der Wert, dessen prozentualer Rang bestimmt werden soll.

Signifikanz ist ein optionales Argument, das die Anzahl der gültigen Stellen festlegt, auf die der zurückgegebene Prozentwert gerundet werden soll. Falls fehlend, wird der Wert 3 verwendet.

Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werthervorhebung.

#### Beispiel

=QUANTILSRANG(A1:A50;50) ergibt den prozentualen Rang des Werts 50 aus dem Gesamtbereich aller Werte, die in A1:A50 gefunden werden. Wenn 50 außerhalb des Gesamtbereichs liegt, wird eine Fehlermeldung angezeigt.

## QUANTILSRANG.EXKL

Ergibt die relative Position, einen Wert zwischen 0 und 1 (exklusiv), eines angegebenen Wertes innerhalb eines übergebenen Bereichs.

Der Unterschied zwischen QUANTIL.INKL und QUANTIL.EXKL ist, dass bei QUANTIL.INKL der Wert für Alpha im Bereich 0 bis 1 inklusiv ist und bei QUANTIL.EXKL der Wert im Bereich 0 bis 1 exklusiv ist.

Diese Funktion ist seit LibreOffice 4.3 verfügbar.

#### Syntax

QUANTILSRANG.EXKL(Daten; Wert [; Signifikanz])

Daten ist die Matrix der Daten in der Stichprobe.

Wert ist der Wert, dessen prozentualer Rang bestimmt werden soll.

Signifikanz ist ein optionales Argument, das die Anzahl der gültigen Stellen festlegt, auf die der zurückgegebene Prozentwert gerundet werden soll.

#### Beispiel

=QUANTILSRANG.EXKL(A1:A50;50) ergibt den prozentualen Rang des Werts 50 aus dem Gesamtbereich aller Werte, die in A1:A50 gefunden werden. Wenn 50 außerhalb des Gesamtbereichs liegt, wird eine Fehlermeldung angezeigt.

## QUANTILSRANG.INKL

Ergibt die relative Position, einen Wert zwischen 0 und 1 (inklusiv), eines angegebenen Wertes innerhalb eines übergebenen Bereichs.

Der Unterschied zwischen QUANTILSRANG.INKL und QUANTILSRANG.EXKL ist, dass bei QUANTILSRANG.INKL der Wert für Alpha ist im Bereich 0 bis 1 inklusive und bei QUANTILSRANG.EXKL der Wert ist im Bereich 0 bis 1 exklusive.

Diese Funktion ist seit LibreOffice 4.3 verfügbar.

#### Syntax

QUANTIL.INKL(Daten; Wert [; Signifikanz])

Daten ist die Matrix der Daten in der Stichprobe.

Wert ist der Wert, dessen prozentualer Rang bestimmt werden soll.

Signifikanz ist ein optionales Argument, das die Anzahl der gültigen Stellen festlegt, auf die der zurückgegebene Prozentwert gerundet werden soll.

#### Beispiel

=QUANTILSRANG.INKL(A1:A50;50) ergibt den prozentualen Rang des Werts 50 aus dem Gesamtbereich aller Werte, die in A1:A50 gefunden werden. Wenn 50 außerhalb des Gesamtbereichs liegt, wird eine Fehlermeldung angezeigt.

## QUARTILE

Ergibt die Quartile einer Datengruppe.

#### Syntax

QUARTILE(Daten; Typ)

Daten ist die Matrix der Daten in der Stichprobe.

Typ ist der Typ des Quartils. (0 = MIN, 1 = 25 %, 2 = 50 % (MEDIAN) ,3 = 75 % und 4 = MAX.)

Diese Funktion ignoriert jeden Text oder jede leere Zelle innerhalb eines Datenbereichs. Wenn Sie falsche Ergebnisse dieser Funktion vermuten, suchen Sie nach Text in den Datenbereichen. Um Textinhalte in einem Datenbereich hervorzuheben, verwenden Sie die Funktion Werthervorhebung.

#### Beispiel

=QUARTILE(A1:A50;2) ergibt den Wert, von dem 50 % der Skala den Werten (niedrigster bis höchster Wert) im Bereich A1:A50 entsprechen.

## QUARTILE.EXKL

Ergibt das angegebene Quartil im Bereich von 0 bis 1 (exklusiv) eines übergebenen Datenbereichs.

Der Unterschied zwischen QUARTILE.INKL und QUARTILE.EXKL ist, dass die Funktion QUARTILE.INKL sich bei der Berechnung auf einen Bereich von 0 bis 1 (inklusiv) und die Funktion QUARTILE.EXKL sich auf einen Bereich von 0 bis 1 (exklusiv) bezieht.

Diese Funktion ist seit LibreOffice 4.3 verfügbar.

#### Syntax

QUARTILE.EXKL(Daten; Typ)

Daten legt den Bereich mit Datenwerten fest, für die Sie das festgelegte Quartil berechnen möchten.

Typ ist eine ganze Zahl zwischen 1 und 3, die das erforderliche Quartil angibt. (falls Typ = 1 oder 3 ist, muss das eingegebene Feld mehr als 2 Werte enthalten)

#### Beispiel

=QUARTILE.EXKL(A1:A50;2) ergibt den Wert, von dem 50 % der Skala den Werten (niedrigster bis höchster Wert) im Bereich A1:A50 entsprechen.

## QUARTILE.INKL

Ergibt die Quartile einer Datengruppe.

Der Unterschied zwischen QUARTILE.INKL und QUARTILE.EXKL ist, dass bei QUARTILE.INKL die Berechnung des Prozentwerts im Bereich 0 bis 1 inklusiv liegt und bei QUARTILE.EXKL im Bereich 0 bis 1 exklusiv liegt.

Diese Funktion ist seit LibreOffice 4.3 verfügbar.

#### Syntax

QUARTILE.INKL(Daten; Typ)

Daten ist die Matrix der Daten in der Stichprobe.

Typ legt die Art des Quartils fest. (0 = MIN, 1 = 25 %, 2 = 50 % (MEDIAN), 3 = 75 % und 4 = MAX.)

#### Beispiel

=QUARTILE.INKL(A1:A50;2) ergibt den Wert, von dem 50 % der Skala den Werten (niedrigster bis höchster Wert) im Bereich A1:A50 entsprechen.

Verwandte Themen

Funktionen nach Kategorie