Inhalte

# Textfunktionen

In diesem Abschnitt werden die Funktionen der Kategorie Text anhand von Beispielen beschrieben.

So greifen Sie auf diesen Befehl zu:

Einfügen – Funktion… – Kategorie: Text

## Doppelte Anführungszeichen in Formeln verwenden

Um eine Textzeichenfolge in eine Formel einzuschließen, setzen Sie die Textzeichenfolge zwischen zwei doppelten Anführungszeichen (") und Calc übernimmt die Zeichen in der Zeichenfolge, ohne zu versuchen, sie auszuwerten. Beispielsweise zeigt die Formel ="Hallo Welt!" die Textzeichenfolge Hallo Welt! in der Zelle ohne umgebenden doppelten Anführungszeichen an.

Die umfangreichere Formel =VERKETTUNG("Das Leben ist wirklich einfach, "; "aber wir bestehen darauf, es kompliziert zu machen "; "(Konfuzius).") verkettet drei einzelne Zeichenfolgen in doppelten Anführungszeichen und ergibt Das Leben ist wirklich einfach, aber wir bestehen darauf, es kompliziert zu machen (Konfuzius).

Um tatsächlich ein doppeltes Anführungszeichen innerhalb einer Zeichenfolge in einer Formel anzuzeigen, können zwei Methoden verwendet werden:

1. Sie können das doppelte Anführungszeichen mit einem zusätzlichen doppelten Anführungszeichen umgehen und Calc behandelt das umgangene doppelte Anführungszeichen als tatsächlichen Wert. Beispielsweise zeigt die Formel ="Mein Name ist ""Max Mustermann"". die Zeichenfolge Mein Name ist "Max Mustermann". an. Ein weiteres Beispiel ist die Formel =UNICODE(""""), welche 34 zurückgibt. Dies ist der Dezimalwert für das Unicode-Zeichen doppeltes Anführungszeichen (U+0022). Das erste und vierte doppelte Anführungszeichen kennzeichnen den Anfang und das Ende der Zeichenfolge und das zweite doppelte Anführungszeichen umgeht das dritte.

2. Sie können die Funktion ZEICHEN oder die Funktion UNIZEICHEN verwenden, um ein doppeltes Anführungszeichen einzufügen. Beispielsweise ergibt die Formel =UNIZEICHEN(34)&"Der Herr der Ringe"&UNIZEICHEN(34)&" ist ein beliebtes Buch von J. R. R. Tolkien." die Zeichenfolge "Der Herr der Ringe" ist ein beliebtes Buch von J. R. R. Tolkien.

Beachten Sie, dass die AutoKorrektur von Calc doppelte Anführungszeichen ändern kann. Die AutoKorrektur sollte die doppelten Anführungszeichen in Zellen mit Formeln nicht ändern, kann jedoch diejenigen ändern, die in Zellen ohne Formeln mit Text verwendet werden. Wenn Sie beispielsweise eine Zeichenfolge kopieren, die von einer anderen Form typografischer doppelter Anführungszeichen umgeben ist, beispielsweise das linke doppelte Anführungszeichen (U+201C) und das rechte doppelte Anführungszeichen (U+201D), und dies in eine Zelle mit Formeln einfügen, kann ein Fehler auftreten. Deaktivieren Sie im Bereich Doppelte Anführungszeichen Öffnen des Dialogs unter Extras – AutoKorrektur-Optionen… – Register: Gebietsschemaabhängige Optionen das Markierfeld Ersetzen, um die Zeichen, die verwendet werden, um die typografischen doppelten Anführungszeichen am Anfang und am Ende automatisch zu korrigieren, auszuschalten.

## ARABISCH

Gibt den numerischen Wert als Text zurück, der einer römischen Zahl entspricht.

## ASC

Wandelt Double-Byte-Zeichen (volle Breite) in Single-Byte-ASCII- und Katakana-Zeichen (halbe Breite) um.

## JIS

Konvertiert Single-Byte (halbe Breite) ASCII- oder Katakana-Zeichen in Double-Byte (volle Breite) Zeichen.

## Funktion REGAUS

Findet und extrahiert oder optional ersetzt Text mittels regulärer Ausdrücke.

## RÖMISCH

Wandelt eine Zahl in eine römische Zahl um. Der Wertebereich muss zwischen 0 und 3999 liegen. Ein Vereinfachungsmodus kann im Bereich von 0 bis 4 festgelegt werden.

## WERT

Wandelt die Darstellung einer Zeichenfolge einer Zahl in numerische Form um. Wenn es sich bei der angegebenen Zeichenfolge um ein gültiges Datum, eine gültige Uhrzeit oder um beides handelt, wird die entsprechende fortlaufende Nummer des Datums oder/und der Uhrzeit zurückgegeben.

### WEBDIENST

Liefert den Webinhalt zu einer URL.

### XMLFILTERN

Wendet einen XPath-Ausdruck für ein XML-Dokument an.

### URLCODIEREN

Gibt eine URL-codierte Zeichendolge zurück.

## BAHTTEXT

Wandelt eine Zahl in Thai-Text um, auch die Thai-Währungsnamen.

#### Syntax

BAHTTEXT(Zahl)

Zahl ist eine beliebige Zahl. "Baht" wird an den Bestandteil der Zahl angehängt und "Satang" wird an die Nachkommastelle der Zahl angehängt.

#### Beispiel

=BAHTTEXT(12,65) gibt eine Thai-Zeichenfolge mit der Bedeutung "Zwölf Baht und 65 Satang" zurück.

#### Technische Information

Diese Funktion ist nicht Bestandteil des Standards Open Document Format für Office-Anwendungen (OpenDocument) Version 1.3. Teil 4: Format für neu berechnete Formeln (OpenFormula). Der Namensraum ist

COM.MICROSOFT.BAHTTEXT

## BASIS

Wandelt eine positive ganze Zahl in einen Text aus dem Zahlensystem der angegebenen Basis um. Dabei werden die Ziffern 0-9 und die Buchstaben A-Z verwendet.

#### Syntax

BASIS(Zahl; Zahlenbasis [; Mindestlänge])

Zahl ist die positive ganze Zahl, die umgewandelt werden soll.

Zahlenbasis gibt die Basis des Zahlensystems an. Es kann jede positive ganze Zahl zwischen 2 und 36 sein.

Mindestlänge (optional) bestimmt die Mindestlänge der erstellten Zeichenfolge. Wenn der Text kürzer als die angegebene Mindestlänge ist, werden links neben der Zeichenfolge Nullen hinzugefügt.

#### Beispiel

=BASIS(17;10;4) ergibt 0017 im Dezimalsystem.

=BASIS(17;2) ergibt 10001 im Binärsystem.

=BASIS(255;16;4) ergibt 00FF im Hexadezimalsystem.

#### Siehe auch

DEZIMAL

## CODE

Ergibt den numerischen Code des ersten Zeichens eines Textes beziehungsweise einer Zeichenfolgen.

#### Syntax

CODE("Text")

Text ist der Text, für dessen erstes Zeichen der Code gefunden werden soll.

Codes größer als 127 hängen von ihrer eingestellten System-Zeichencodierung ab (beispielsweise iso-8859-1, iso-8859-2, Windows-1262, Windows-1250) und sind daher nicht portabel.

#### Beispiel

=CODE("Hieronymus") ergibt 72, =CODE("hieroglyphisch") ergibt 104.

Bei dem verwendeten Code handelt es sich nicht um den ASCII-Code, sondern um den Code der aktuellen Code-Tabelle.

## DEZIMAL

Konvertiert Text, der eine Zahl in einem Zahlensystem mit der angegebenen Zahlenbasis darstellt, in eine positive ganze Zahl. Die Basis muss im Bereich von 2 bis 36 liegen. Leerzeichen und Tabulatoren werden ignoriert. Beim Feld Text wird die Groß-/Kleinschreibung nicht beachtet.

Wenn die Basis 16 ist, werden ein vorangestelltes "x" oder "X" beziehungsweise "0x" oder "0X" und ein angehängtes "h" oder "H" nicht berücksichtigt. Wenn die Basis 2 ist, wird ein angehängtes "b" oder "B" ignoriert. Andere Zeichen, die nicht zum Zahlensystem gehören, erzeugen einen Fehler.

#### Syntax

DEZIMAL("Text"; Zahlenbasis)

Text ist der zu konvertierende Text.

Zahlenbasis gibt die Basis des Zahlensystems an. Es kann jede positive ganze Zahl zwischen 2 und 36 sein.

#### Beispiel

=DEZIMAL("17";10) ergibt 17.

=DEZIMAL("FACE";16) ergibt 64206.

=DEZIMAL("0101";2) ergibt 5.

#### Siehe auch

BASIS

## ERSETZEN

Um einen bestimmten Teil einer Zeichenfolge durch eine andere Zeichenfolge auszuwechseln, können Sie den auszuwechselnden Text, die Position, die Länge und den Textersatz festlegen. Es können sowohl Zeichen als auch Zahlen (die automatisch in Text gewandelt werden) mit dieser Funktion ausgetauscht werden. Das Ergebnis der Funktion ist immer ein Text. Um mit einer ersetzten Zahl weiterzurechnen, müssen Sie das Ergebnis mit der Funktion WERT in eine Zahl zurückwandeln.

Text, der Zahlen enthält, ist in Anführungszeichen zu setzen. Anderenfalls wird er als Zahl interpretiert und automatisch in Text konvertiert.

#### Syntax

ERSETZEN("Text"; Position; Länge; "NeuerText")

Text ist ein Text, aus dem ein Teil ersetzt wird.

Position bezieht sich auf die Position innerhalb des Textes, wo die Ersetzung beginnt.

Länge ist die Anzahl von Zeichen im Text, der ersetzt werden soll.

NeuerText bezieht sich auf Text, der Text ersetzt.

#### Beispiel

=ERSETZEN("1234567";1;1;"444") ergibt "444234567". Ein Zeichen an Position 1 wird durch den vollständigen neuen Text (Parameter NeuerText) ersetzt.

## EUR

Konvertiert eine Zahl in eine Zeichenfolge, die den Betrag im Währungsformat darstellt, gerundet auf eine bestimmte Dezimalstelle, wobei das Dezimaltrennzeichen verwendet wird, das der aktuellen Gebietsschemaeinstellung entspricht. Geben Sie im Feld Wert die umzuwandelnde Zahl ein. Optional können Sie im Feld Dezimalstellen die Anzahl der Nachkommastellen eingeben. Wenn kein Wert angegeben ist, werden alle Zahlen im Währungsformat mit zwei Dezimalstellen angezeigt.

Das Währungsformat legen Sie in den Systemeinstellungen fest.

#### Syntax

EUR(Wert [; Dezimalstellen])

Wert ist ein Zahl, ein Bezug auf ein Zelle, in der eine Zahl enthalten ist, oder eine Formel, die eine Zahl ergibt.

Dezimalstellen ist die optionale Anzahl von Dezimalstellen.

#### Beispiel

=EUR(255) ergibt $255,00 für das englische (USA) Gebietsschema und die Währung USD (Dollar); ￥255,00 für das japanische Gebietsschema und die Währung JPY (Yen); oder 255,00 € für das deutsche (Deutschland) Gebietsschema und die Währung EUR (Euro).

=EUR(367,456;2) ergibt 367,46 €.

## FEST

Gibt eine Zahl als Text mit einer angegebenen Anzahl von Dezimalstellen und optional Tausendertrennzeichen zurück.

#### Syntax

FEST(Zahl; [Dezimalstellen = 2 [; Keine Tausendertrennzeichen = FALSCH]])

Zahl wird auf die Anzahl von Dezimalstellen nach dem Dezimaltrennzeichen gerundet und das Ergebnis wird als Text ausgegeben. Es werden die aktuellen lokalen Einstellungen verwendet.

Dezimalstellen (optional) ist die Anzahl an Dezimalstellen, die angezeigt werden sollen. Wenn Dezimalstellen negativ ist, wird Zahl mit der Anzahl von (Dezimalstellen) links vom Dezimaltrennzeichen auf die ganze Zahl gerundet. Wenn Dezimalstellen eine Dezimalzahl ist, wird nur die ganze Zahl verwendet.

Keine Tausendertrennzeichen (optional) bestimmt, ob das Tausendertrennzeichen verwendet wird. Wenn der Parameter WAHR oder ungleich 0 ist, wird das Tausendertrennzeichen nicht angezeigt. Wenn der Parameter FALSCH, gleich 0 oder nicht vorhanden ist, werden die Tausendertrennzeichen entsprechend Ihren aktuellen lokalen Einstellungen angezeigt.

#### Beispiel

=FEST(1234567,89;3) ergibt 1.234.567,890 als Zeichenfolge.

=FEST(123456,789;;WAHR) ergibt 123456,79 als Zeichenfolge.

=FEST(12345,6789;-2) gibt 12.300 als Zeichenfolge zurück.

=FEST(12134567,89;-3;1) gibt 12135000 als Zeichenfolge zurück.

=FEST(12345,789;3/4) gibt 12.346 als Zeichenfolge.

=FEST(12345,789;8/5) gibt 12.345,8 als Zeichenfolge.

## FINDEN

Gibt die Position einer Textzeichenfolge in einer anderen Zeichenfolge zurück. Sie können auch festlegen, wo die Suche beginnen soll. Bei dem Suchbegriff kann es sich um eine Zahl oder eine beliebige Zeichenfolge handeln. Die Groß- und Kleinschreibung ist dabei zu beachten.

#### Syntax

FINDEN("TextFinden"; "Text" [; Position])

TextFinden bezieht sich auf Text, der gefunden werden soll.

Text ist der Text, wo die Suche stattfindet.

Position (optional) ist die Position im Text, wo die Suche beginnt.

#### Beispiel

=FINDEN(76;998877665544) ergibt 6.

## GLÄTTEN

Entfernt Leerstellen aus einer Zeichenfolge und lässt nur einzelne Leerzeichen zwischen Worten stehen.

#### Syntax

GLÄTTEN("Text")

Text bezieht sich auf den Text, in dem Leerstellen entfernt werden sollen.

#### Beispiel

=GLÄTTEN(" Hallo Welt ") ergibt Hallo Welt ohne führende und abschließende Leerzeichen und mit nur einem Leerzeichen zwischen den Wörtern.

## GROSS

Die im Textfeld Text eingegebene Buchstabenfolge wird komplett in Großbuchstaben umgewandelt.

#### Syntax

GROSS("Text")

Text bezieht sich auf in Großbuchstaben umzuwandelnde Kleinbuchstaben.

#### Beispiel

=GROSS("Guten Morgen") ergibt GUTEN MORGEN.

## GROSS2

Wandelt alle Wortanfänge einer Textzeichenfolge in Großbuchstaben um.

#### Syntax

GROSS2("Text")

Text bezieht sich auf Text, der umgewandelt werden soll.

#### Beispiel

=GROSS2("the document foundation") gibt The Document Foundation zurück.

## IDENTISCH

Vergleicht zwei Textzeichenfolgen und ergibt WAHR, wenn sie identisch sind. Diese Funktion berücksichtigt die Groß- und Kleinschreibung.

#### Syntax

IDENTISCH("Text1"; "Text2")

Text1 bezieht sich auf den ersten Text, der verglichen werden soll.

Text2 ist der zweite Text, der verglichen werden soll.

#### Beispiel

=IDENTISCH("microsystems";"Microsystems") ergibt FALSCH.

## KLEIN

Die im Textfeld „Text“ eingegebene Buchstabenfolge wird komplett in Kleinbuchstaben umgewandelt.

#### Syntax

KLEIN("Text")

Text bezieht sich auf Text, der umgewandelt werden soll.

#### Beispiel

=KLEIN("Sonne") ergibt sonne.

## LINKS

Ergibt das erste Zeichen beziehungsweise die ersten Zeichen eines Textes.

#### Syntax

LINKS("Text" [; Zahl])

Text ist der Text, dessen am Anfang stehende Wortsegmente bestimmt werden sollen.

Anzahl (optional) legt die Anzahl der Zeichen für den Anfangstext fest. Ist dieser Parameter nicht definiert, dann wird ein Zeichen zurückgegeben.

#### Beispiel

=LINKS("Ausgabe";3) ergibt „Aus“.

## LINKSB

Ergibt das erste Zeichen eines DBCS-Textes.

Diese Funktion ist seit LibreOffice 4.2 verfügbar.

#### Syntax

LINKSB("Text" [; Anzahl_Bytes])

Text ist der Text, dessen am Anfang stehendes Wortsegment bestimmt werden soll.

Anzahl_Bytes (optional) legt die Anzahl an Zeichen fest, die LINKSB zurückgeben soll. Ist dieser Parameter nicht definiert, wird ein Zeichen zurückgegeben.

#### Beispiel

=LINKSB("中国";1) ergibt " " (1 Byte ist nur ein halbes DBCS-Zeichen, deshalb wird ersatzweise ein Leerzeichen zurückgegeben).

=LINKSB("中国";2) ergibt "中" (2 Bytes bilden ein vollständiges DBCS-Zeichen).

=LINKSB("中国";3) ergibt "中 " (3 Bytes bilden eineinhalb DBCS-Zeichen; als zweites Zeichen wird deshalb ersatzweise ein Leerzeichen zurückgegeben).

=LINKSB("中国";4) ergibt "中国" (4 Bytes bilden zwei vollständige DBCS-Zeichen).

=LINKSB("Büro";3) ergibt "Bür" (3 Nicht-DBCS-Zeichen, jedes mit der Länge von 1 Byte).

## LÄNGE

Gibt die Länge einer Zeichenfolge zurück. Leerzeichen werden mitgezählt.

#### Syntax

LÄNGE("Text")

Text ist der Text, dessen Länge bestimmt werden soll.

#### Beispiel

=LÄNGE("Guten Tag") ergibt 9.

=LÄNGE(12345,67) ergibt 8.

## LÄNGEB

Gibt die Anzahl der Bytes für Double-Byte-Zeichensatz-Sprachen (DBCS) zurück, die zur Darstellung der Zeichen in einer Zeichenfolge verwendet werden.

Diese Funktion ist seit LibreOffice 4.2 verfügbar.

#### Syntax

LÄNGEB("Text")

Text ist der Text, dessen Länge bestimmt werden soll.

#### Beispiel

LÄNGEB("中") ergibt 2 (1 DBCS-Zeichen, bestehend aus 2 Bytes).

LÄNGEB("中国") ergibt 4 (2 DBCS-Zeichen, bestehend aus je 2 Bytes).

LÄNGEB("Office") ergibt 6 (6 Nicht-DBCS-Zeichen, bestehend aus je 1 Byte).

=LÄNGEB("Guten Tag") ergibt 9.

=LÄNGEB(12345,67) ergibt 8.

## RECHTS

Ergibt das letzte Zeichen beziehungsweise die letzten Zeichen eines Textes.

#### Syntax

RECHTS("Text" [; Zahl])

Text ist der Text, dessen rechter Teil bestimmt werden soll.

Zahl (optional) gibt die Anzahl von Zeichen im rechten Teil des Textes an. Ist diese Parameter leer, wird ein Zeichen zurückgegeben.

#### Beispiel

=RECHTS("Sonne";2) ergibt ne.

## RECHTSB

Ergibt das letzte oder die letzten Zeichen eines Textes mit Double-Bytes-Zeichensätzen (DBCS).

Diese Funktion ist seit LibreOffice 4.2 verfügbar.

#### Syntax

RECHTSB("Text" [; Anzahl_Bytes])

Text ist der Text, dessen rechter Teil bestimmt werden soll.

Anzahl_Bytes (optional) legt die Anzahl der auf Bytes basierenden Zeichen fest, die Sie mit RECHTSB abfragen möchten. Ist diese Parameter leer, wird ein Byte zurückgegeben.

#### Beispiel

RECHTSB("中国";1) ergibt " " (1 Byte ist nur ein halbes DBCS-Zeichen, deshalb wird ersatzweise ein Leerzeichen zurückgegeben).

RECHTSB("中国";2) ergibt "国" (2 Bytes bilden ein komplettes DBCS-Zeichen).

RECHTSB("中国";3) ergibt " 国" (3 Bytes bilden eineinhalb DBCS-Zeichen; ein Leerzeichen wird ersatzweise für das erste halbe Zeichen zurückgegeben).

RECHTSB("中国";4) ergibt "中国" (4 Bytes bilden zwei komplette DBCS-Zeichen).

RECHTSB("Büro";3) ergibt "üro" (3 Nicht-DBCS-Zeichen, jedes mit der Länge 1 Byte).

## SUCHEN

Gibt die Position eines Textsegments innerhalb einer Zeichenfolge zurück. Sie können optional auch den Anfang für die Suche festlegen. Bei dem Suchbegriff kann es sich um eine Zahl oder eine beliebige Zeichenfolge handeln. Die Groß-/Kleinschreibung spielt keine Rolle. Wenn der Text nicht gefunden wird, wird der Fehler 519 (#WERT) zurückgegeben.

Die Suche unterstützt Platzhalter oder reguläre Ausdrücke. Wenn reguläre Ausdrücke aktiviert sind, können Sie "all.*" eingeben, um beispielsweise das erste Vorkommen von "all", gefolgt von beliebigen Zeichen, zu finden. Wenn Sie nach einem Text suchen möchten, der auch ein regulärer Ausdruck ist, müssen Sie entweder jedem Metazeichen oder Operator eines regulären Ausdrucks ein "\" voranstellen oder den Text in \Q…\E einschließen. Die automatische Auswertung von Platzhaltern oder regulären Ausdrücken können Sie unter LibreOffice – Einstellungen Extras – Optionen… – LibreOffice Calc – Berechnen umschalten.

Wenn Sie Funktionen verwenden, bei denen ein oder mehrere Argumente Suchkriterien-Zeichenfolgen sind, die einen regulären Ausdruck darstellen, besteht der erste Versuch darin, die Zeichenfolgen-Kriterien in Zahlen umzuwandeln. Zum Beispiel wird in bestimmten Gebietsschemen ".0" in "0.0" konvertiert und so weiter. Bei Erfolg handelt es sich bei der Übereinstimmung nicht um eine Übereinstimmung mit regulären Ausdrücken, sondern um eine numerische Übereinstimmung. Wenn Sie jedoch zu einem Gebietsschema wechseln, in dem das Dezimaltrennzeichen nicht der Punkt ist, funktioniert die Konvertierung regulärer Ausdrücke. Um die Auswertung des regulären Ausdrucks anstelle eines numerischen Ausdrucks zu erzwingen, verwenden Sie einen Ausdruck, der nicht als numerisch falsch verstanden werden kann, beispielsweise ".[0]" oder ".\0" oder "(?i).0".

#### Syntax

SUCHEN("TextFinden"; "Text" [; Position])

TextFinden ist der Text, nach dem gesucht werden soll.

Text ist der Text, wo die Suche stattfindet.

Position (optional) ist die Position im Text, wo die Suche beginnen soll.

#### Beispiel

=SUCHEN(54;998877665544) ergibt 10.

## SÄUBERN

Aus der Zeichenfolge werden alle nicht druckbaren Zeichen entfernt.

#### Syntax

SÄUBERN("Text")

Text bezieht sich auf Text, aus dem alle nicht druckbaren Zeichen entfernt werden sollen.

#### Beispiel

=LÄNGE(SÄUBERN(ZEICHEN(7)&"LibreOffice Calc"&Zeichen(8))) gibt 16 zurück, was zeigt, dass die Funktion SÄUBERN die nicht druckbaren Unicode-Zeichen U+0007 ("BEL") und U+0008 ("BS") am Anfang und Ende des Zeichenfolgenarguments entfernt. SÄUBERN entfernt keine Leerzeichen.

## T

Diese Funktion ergibt den Zieltext oder eine leere Zeichenfolge, wenn das Ziel kein Text ist.

#### Syntax

T(Wert)

Wenn Wert eine Zeichenfolge ist oder sich auf eine Zeichenfolge bezieht, ergibt T die Zeichenfolge; anderenfalls ergibt T eine leere Zeichenfolge.

#### Beispiel

=T(12345) gibt eine leere Zeichenfolge zurück.

=T("12345") gibt die Zeichenfolge 12345 zurück.

## TEIL

Gibt eine Zeichenfolge des Textes zurück. Die Parameter legen die Ausgangsposition und die Zeichenanzahl fest.

#### Syntax

TEIL("Text"; Start; Zahl)

Text ist der Text, der Zeichen enthält, die extrahiert werden sollen.

Anfang ist die Position des ersten Zeichens im Text, der extrahiert werden soll.

Zahl legt die Anzahl von Zeichen im betreffenden Teil des Textes fest.

#### Beispiel

=TEIL("office";2;2) ergibt ff.

## TEILB

Gibt eine Zeichenfolge des DBCS-Textes zurück. Die Parameter legen die Ausgangsposition und die Zeichenanzahl fest.

Diese Funktion ist seit LibreOffice 4.2 verfügbar.

#### Syntax

TEILB("Text"; Start; Zahl_Bytes)

Text ist der Text, der Zeichen enthält, die extrahiert werden sollen.

Start ist die Position des ersten Zeichens im Text, der extrahiert werden soll.

Anzahl_Bytes legt die Anzahl der Zeichen in Bytes fest, die TEILB vom Text in Bytes zurückgeben soll.

#### Beispiel

=TEILB("中国";1;0) ergibt "" (0 Bytes entsprechen immer einer leeren Zeichenfolge).

=TEILB("中国";1;1) ergibt " " (1 Byte ist lediglich ein halbes DBCS-Zeichen, deshalb wird ersatzweise ein Leerzeichen zurückgegeben).

=TEILB("中国";1;2) ergibt "中" 2 Bytes bilden ein vollständiges DBCS-Zeichen).

=TEILB("中国";1;3) ergibt "中 " (3 Bytes bilden eineinhalb DBCS-Zeichen; als zweites Zeichen wird deshalb ersatzweise ein Leerzeichen zurückgegeben).

=TEILB("中国";1;4) ergibt "中国" (4 Bytes bilden zwei vollständige DBCS-Zeichen).

=TEILB("中国";2;1) ergibt " " (Die 2. Byteposition ist nicht am Anfang eines Zeichens einer DBCS-Zeichenfolge; deshalb wird ersatzweise ein Leerzeichen zurückgegeben).

=TEILB("中国";2;2) ergibt " " (Die 2. Byteposition ist nicht am Anfang eines Zeichens einer DBCS-Zeichenfolge; die 2 Bytes, die zurückgegeben werden sollen, bilden stattdessen die zweite Hälfte des ersten Zeichens und die erste Hälfte des zweiten Zeichens in der Zeichenfolge; deshalb werden ersatzweise zwei Leerzeichen zurückgegeben).

=TEILB("中国";2;3) ergibt " 国" (Die 2. Byteposition ist nicht am Anfang eines Zeichens einer DBCS-Zeichenfolge; deshalb wird ersatzweise ein Leerzeichen für die 2. Byteposition zurückgegeben).

=TEILB("中国";3;1) ergibt " " (Die 3. Byteposition am Anfang eines Zeichens einer DBCS-Zeichenfolge, aber 1 Byte ist lediglich ein halbes DBCS-Zeichen, deshalb wird ersatzweise ein Leerzeichen zurückgegeben).

=TEILB("中国";3;2) ergibt "国" (Die 3. Byteposition ist am Anfang eines Zeichens einer DBCS-Zeichenfolge und 2 Bytes bilden ein DBCS-Zeichen).

=TEILB("Büro";2;3) ergibt "üro" (Die 2. Byteposition ist am Anfang eines Zeichens einer Nicht-DBCS-Zeichenfolge und 3 Bytes einer Nicht-DBCS-Zeichenfolge bilden 3 Zeichen).

## TEXT

Konvertiert einen Wert gemäß einem bestimmten Format in Text.

#### Syntax

TEXT(Wert; Format)

Wert ist der Wert (Zahl oder Text), der konvertiert werden soll.

Format ist der Text, der das Format beschreibt. Verwenden Sie die für die im Zellenformat festgelegte Sprache üblichen Dezimal- und Tausenderseparatoren.

#### Beispiel

=TEXT(12,34567;"###,##") ergibt den Text 12,35

=TEXT(12,34567;"000,00") ergibt den Text 012,35

=TEXT("xyz";"=== @ ===") gibt den Text === xyz === zurück.

Siehe auch Zahlenformat-Codes: Vom Anwender definierte Benutzerdefinierte Formatcodes.

## UNICODE

Gibt den Code des ersten Unicode-Zeichens einer Zeichenfolge zurück.

#### Syntax

UNICODE("Text")

#### Beispiel

=UNICODE("©") ergibt die Unicodezahl 169 für das Copyrightzeichen.

Vergleichen Sie auch die Funktion UNIZEICHEN().

## UNIZEICHEN

Wandelt eine Codenummer in ein Unicode-Zeichen oder -Buchstaben um.

#### Syntax

UNIZEICHEN(Zahl)

#### Beispiel

=UNIZEICHEN(169) ergibt das Copyrightzeichen ©.

Vergleichen Sie auch die Funktion UNICODE().

## VERKETTEN

Verbindet mehrere Textzeichenfolgen zu einer Zeichenfolge.

#### Syntax

VERKETTEN(Zeichenfolge 1 [; Zeichenfolge 2 [; … [; Zeichenfolge 255]]])

Zeichenfolge 1 [; Zeichenfolge 2 [; … [; Zeichenfolge 255]]] sind Zeichenfolgen oder Verweise auf Zellen, die Zeichenfolgen enthalten.

#### Beispiel

=VERKETTEN("Guten ";"Morgen ";"Frau ";"Müller") ergibt "Guten Morgen Frau Müller".

## WECHSELN

Tauscht in einer Zeichenfolge einen alten gegen einen neuen Text aus.

#### Syntax

WECHSELN("Text"; "Suchtext"; "NeuerText" [; GefundeneTextstelle])

Text ist der Text, in dem Textsegmente ausgetauscht werden sollen.

Suchtext ist das Textsegment, das ersetzt werden soll (mehrere Male).

NeuerText ist der Text, der das Textsegment ersetzen soll.

GefundeneTextstelle (optional) zeigt an, welche gefundene Textstelle des Suchtextes ersetzt werden soll. Wenn dieser Parameter nicht vorhanden ist, wird der Suchtext durchgängig ersetzt.

#### Beispiel

=WECHSELN("123123123";"3";"abc") ergibt 12abc12abc12abc.

=WECHSELN("123123123";"3";"abc";2) ergibt 12312abc123.

## WIEDERHOLEN

Wiederholt eine Zeichenfolge so oft, wie mit Anzahl angegeben.

#### Syntax

WIEDERHOLEN("Text"; Zahl)

Text ist der Text, der wiederholt werden soll.

Zahl ist die Anzahl von Wiederholungen.

#### Beispiel

=WIEDERHOLEN("Guten Morgen";2) ergibt Guten MorgenGuten Morgen.

Lesen Sie für weitere Details über diese Funktion die Wikipedia-Seite WIEDERHOLEN.

## ZEICHEN

Konvertiert eine Zahl gemäß der aktuellen Codetabelle in einen Buchstaben oder ein Zeichen. Bei der Zahl kann es sich um eine zwei- oder dreistellige ganze Zahl handeln.

Codes größer als 127 hängen von ihrer eingestellten System-Zeichencodierung ab (beispielsweise iso-8859-1, iso-8859-2, Windows-1262, Windows-1250) und sind daher nicht portabel.

#### Syntax

ZEICHEN(Zahl)

Zahl ist eine Zahl zwischen 1 und 255, die den Codewert für das Zeichen darstellt.

#### Beispiel

=ZEICHEN(100) ergibt das Zeichen d.

="abc" &ZEICHEN(10) & "def" fügt einen Zeilenumbruch in den Text ein.

Verwandte Themen

Funktionen nach Kategorie