Indhold

# Regnearksfunktioner

Dette afsnit indeholder beskrivelser af Regnearksfunktioner samt et eksempel.

For at tilgå denne kommando...

Indsæt ▸ Funktion ▸ Kategori Regneark

## Funktionen FEJL.TYPE (på engelsk: ERROR.TYPE)

Returnerer et tal, som repræsenterer en specifik fejltype, eller fejlværdien #N/A, hvis der ikke er nogen fejl.

## SLÅ.OP (på engelsk: LOOKUP)

Søger efter et kriterium i en allerede-sorteret matrix, og returnerer et tilhørende resultat. Returnerer indholdet af en celle fra et område, der kan være en enkelt række eller en enkelt kolonne.

## Funktionen TYPOGRAFI (på engelsk: STYLE)

Anvender en typografi på den celle, som indeholder formlen.

## ADDRESSE (på engelsk: ADDRESS)

Returnerer en celleadresse (reference) som tekst, i henhold til de angivne række- og kolonnenumre. Efter eget valg kan du fastslå om adressen fortolkes som en absolut adresse (for eksempel, $A$1), som en relativ adresse (som A1) eller i en blandet form (A$1 eller $A1). Du kan også angive navnet på arket.

Af hensyn til interoperabilitet understøtter funktionerne ADRESSE og INDIREKTE en valgfri parameter til at angive, om R1C1-adresse-notatonen skal bruges i stedet for den sædvanlige A1-notation.

I ADRESSE bliver parameteren indsat som den fjerde parameter, hvilket flytter det valgfri arknavn parameter til den femte placering.

I INDIREKTE er parameteren tilføjet som den anden parameter.

I begge funktioner gælder, at hvis argumentet indsættes med værdien 0, så bruges R1C1-notationen. Hvis argumentet udelades eller har en anden værdi end 0, så bruges A1-notationen.

Ved brug af R1C1-notationen returnerer ADRESSE adresse-strengen med bruge af udråbstegn "!" som arknavn-skilletegn, og INDIREKTE forventer udråbstegn som arknavn-skilletegn. Begge funktioner bruger stadig punktum "." som arknavn-skilletegn med A1-notationen.

Når du åbner dokumenter med ODF 1.0/1.1 formater, hvor ADRESSE-funktionen viser et arknavn som den fjerde parameter, vil arknavnet blive ændret til at blive den femte parameter. En ny fjerde parameter med værdien 1 vil blive indsat.

Når du gemmer et dokument i ODF 1.0/1.1 format, vil den fjerde parameter i ADDRESSE-funktionen blive fjernet.

Undlad at gemme regneark i det ældre ODF 1.0/1.1 format, hvis ADRESSE-funktionens fjerde parameter er brugt med værdien 0.

Funktionen INDIREKTE bliver gemt uden konvertering til formatet ODF 1.0/1.1. Hvis den anden parameter er tilstede, vil ældre versioner af Calc returnere en fejl for den funktion.

#### Syntaks

ADRESSE(Række; Kolonne [; Abs [; A1 [; "Ark"]]])

Række repræsenterer rækkenummeret for cellereferencen

Kolonne repræsenterer kolonnenummeret for cellereferencen (tallet, ikke bogstavet)

Abs bestemmer typen af reference:

1: absolut ($A$1)

2: rækkereferencetype er absolut; kolonnereference er relativ (A$1)

3: række (relativ); kolonne (absolut) ($A1)

4: relativ (A1)

A1 (valgfri) – hvis sat til 0, så bruges R1C1-notation. Hvis denne parameter er udeladt eller sat til en anden værdi end 0, så bruges A1-notation.

Ark repræsenterer navnet på arket. Det skal være placeret i dobbelt citationstegn.

### Eksempel:

=ADRESSE(1; 1; 2; "Ark2") returnerer følgende: Ark2.A$1

Hvis formlen ovenfor findes i celle B2 på det aktive ark, og cellen A1 på ark 2 indeholder værdien -6, kan du henvise indirekte til den til målcellen med en funktion i B2 ved at indtaste =ABS(INDIREKTE(B2)). Resultatet er den numeriske værdi af den cellehenvisning, der er specificeret i B2, hvilket i dette tilfælde giver 6.

## ANTAL.ARK (på engelsk: SHEETS)

Afgør antallet af ark i en henvisning. Hvis du ikke indtaster en parameter, returneres antal ark i det aktuelle dokument.

#### Syntaks

ANTAL.ARK([Reference])

Reference er referencen til et ark eller et område. Denne parameter er valgfri.

#### Eksempel

=ANTAL.ARK(Ark1.A1:Ark3.G12) returnerer 3, hvis Ark1, Ark2 og Ark3 findes i den angivne rækkefølge.

## ARK (på engelsk: SHEET)

Returnerer arknummeret på enten en reference eller en streng, der repræsenterer et arknavn. Hvis du ikke indtaster nogle parametre, er resultatet arknummeret på det regneark, der indeholder formlen.

#### Syntaks

ARK([Reference])

Reference er valgfri og er referencen til en celle, et område eller et arknavn.

#### Eksempel

=ARK( Ark2.A1) returnerer 2, hvis Ark2 er det andet ark i regnearksdiokumentet.ARK

=ARK( "Ark3") returnerer 3, hvis Ark3 er det tredje ark i regnearksdokumentet.

## DDE (samme navn på engelsk)

Returnerer resultatet af en DDE-baseret kæde. Hvis indholdet af det forbundne område eller den forbundne sektion ændres, vil den returnerede værdi også ændre sig. Du skal indlæse regnearket på ny eller vælge Redigér ▸ Kæder for at se de opdaterede referencer. Referencer på tværs af platforme, for eksempel fra en LibreOffice installation som kører på en Windows-maskine til et dokument oprettet på en Linux-maskine, er ikke tilladt.

#### Syntaks

DDE("Server"; "Emne/fil"; "Element/område" [; Tilstand])

Server er navnet på et serverprogram. LibreOfficeprogrammer har servernavnet "soffice".

Fil er det fuldstændige filnavn, inklusive sti specifikation.

Område er området, som indeholder data, der skal valideres.

Tilstand er en valgfri parameter, der bestemmer den metode, som DDE-serveren bruger til at konvertere sine data til tal.

Tilstand | Effekt
--- | ---
0 eller udeladt | Talformat fra celletypografien "Standard"
1 | Data bliver altid fortolket som standard US engelsk format.
2 | Data bliver hentet som tekst; ingen konvertering til tal.

#### Eksempel

=DDE("soffice"; "c:\Kontor\dokument\data1.ods"; "ark1.A1") læser celleindholdet af celle A1 i ark1 fra LibreOffice Calc-regnearket data1.ods.

=DDE("soffice";"c:\Kontor\dokument\motto.odt";"Dagens Motto") returnerer et motto i den celle, som indeholder denne formel. Først skal du indtaste en linje i motto.odt dokumentet som indeholder mottoets tekst og angive den som den første linje af en sektion med navnet Dagens Motto (i LibreOffice Writer under Indsæt ▸ Sektion). Hvis mottoet bliver ændret (og gemt) i LibreOffice Writer dokumentet, bliver mottoet opdateret i alle LibreOffice Calc celler hvor denne DDE-kæde er defineret.

## FEJLTYPE (på engelsk: ERRORTYPE)

Returnerer tallet svarende til enfejlværdi der optræder i en anden celle. Ved hjælp af dette tal, kan du generere en tekst til fejlmeddelelsen.

Hvis der opstår en fejl, returnerer funktionen en logisk eller numerisk værdi.

Statuslinjen viser den foruddefinerede fejlkode fra LibreOffice hvis du klikker den celle, som indeholder fejlen.

#### Syntaks

FEJLTYPE(Reference)

Reference indeholder adressen på den celle, som fejlen opstår i.

#### Eksempel

Hvis celle A1 viser Err:518, returnerer funktionen =FEJLTYPE(A1) tallet 518.

#### Tekniske oplysninger

Denne funktion er IKKE en del af standarden Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format. Navnerummet er

ORG.OPENOFFICE.ERRORTYPE

## FORSKYDNING (på engelsk: OFFSET)

Returnerer værdien af en celleforskydning for et bestemt antal af rækker og kolonner fra et givet referencepunkt.

Denne funktion genberegnes altid, når som helst der sker en genberegning.

#### Syntaks

FORSKYDNING(Reference; Rækker; Kolonner [; Højde [; Bredde]])

Reference er cellen, hvorfra funktionen leder efter den nye reference.

Rækker er antallet af celler som referencen blev korrigeret opad (negativ værdi) eller nedad.

Rækker er antallet af celler som referencen blev korrigeret opad (negativ værdi) eller nedad.

Højde er den valgfrie lodrette højde for et område, der begynder ved den nye referenceposition.

Bredde (valgfri) er den vandrette bredde for et område, der begynder ved den nye referenceposition.

argumenter Rækker og Kolonner må ikke føre til nul eller en negativ startrække eller -kolonne

argumenter Højde og Bredde må ikke føre til nul eller et negativt antal af rækker eller kolonner.

I LibreOffice Calc-funktioner kan parametre markeret som "valgfri" kun udelades, hvis ingen parameter følger. I en funktion med for eksempel fire parametre, hvor de sidste to parametre er markeret som "valgfri", kan du udelade parameter 4 eller parametrene 3 og 4, men du kan ikke udelade parameter 3 alene.

#### Eksempel

=FORSKYDNING(A1; 2; 2) returnerer værdien i celle C3 (A1 flyttet med to rækker og to kolonner nedad). Hvis C3 indeholder værdien 100 returnerer denne funktion værdien 100.

=OFFSET(B2:C3;1;1) returnerer en reference til B2:C3 flyttet 1 række ned og en kolonne til højre (C3:D4).

=OFFSET(B2:C3;-1;-1) returnerer en reference til B2:C3 flyttet 1 række op og en kolonne til venstre (A1:B2).

=OFFSET(B2:C3;0;0;3;4) returnerer en reference til B2:C3 med størrelsen ændret til 3 rækker og 4 kolonner (B2:E4).

=FORSKYDNING(B2:C3;1;0;3;4) returnerer en reference til B2:C3 flyttet en række ned og med størrelsen ændret til 3 rækker og 4 kolonner (B3:E5).

=SUM(FORSKYDNING(A1;2;2;5;6)) bestemmer summen af det område der starter i celle C3 og har en højde på 5 rækker og en bredde af 6 kolonner (område=C3:H7).

Hvis Bredde eller Højde er givet, returnerer funktionen FORSKYDNING en celleområde-reference . Hvis Reference er en enkeltcelle-reference og både Bredde og Højde er udeladt, returneres en enkeltcelle-reference .

## GETPIVOTDATA (samme navn på engelsk)

Funktionen GETPIVOTDATA returnerer en resultatværdi fra en pivottabel. Værdien adresseres ved hjælp at felt- og elementnavnene, således at de forbliver valide såfremt pivottabellens opbygning senere ændres.

#### Syntaks

To forskellige syntaksdefinitioner kan bruges:

GETPIVOTDATA(Datafelt; Pivottabel [; Felt 1; Element 1 [; ... [Felt 126; Element 126]]])

eller

GETPIVOTDATA(pivottabel; Begrænsninger)

Syntaks nr. 2 antages at være brugt hvis netop to parametre er givet, hvor den første parameter er en reference til en celle eller et celleområde. Den første syntaks antages at være brugt i alle andre tilfælde. Funktionsguiden viser den første syntaks.

### Første syntaks

Målfelt er en tekststreng som vælger et af pivottabellens datafelter. Tekststrengen kan være navnet på kildekolonnen eller navn på datafeltet som vises i tabellen ("Sum - Salg").

pivottabel er en reference til en celle eller et celleområde som er placeret inden i en pivottabel eller som indeholder en pivottabel. Hvis celleområdet består af flere pivottabeller, vil den senest brugte pivottabel blive anvendt.

Hvis intet Felt n / Element n par er opgivet, returneres totalen. Ellers tilføjer hvert par en begrænsning som resultatet skal leve op til. Felt n er navnet på et felt fra pivottabellen. Element n er navnet på et element fra selvsamme felt.

Hvis pivottabellen kun består af et en enkelt resultatværdi som lever op til afgrænsningerne, eller en delsammentælling som summerer alle matchende værdier, vil denne værdi blive returneret. Hvis der ikke er matchende resultater, eller der er flere resultater uden delsammentælling, returneres en fejl. Disse betingelser knytter sig til resultater fra pivottabellen.

Hvis kildedata indeholder bestanddele som er skjult som følge af indstillinger for pivottabellen, ignoreres de. Rækkefølgen af felter og elementer er ikke vigtig. Felter og elementnavne er ikke afhængige af at være præcise med hensyn til STORE og små bogstaver.

Hvis der ikke er givet begrænsninger for et filter, bruges feltets valgte værdi implicit. Hver der er givet en begrænsning for et filter, skal den matche feltets valgte værdi, ellers returneres der en fejl. Filtre er felterne øverst, til venstre i en pivottabel, der udfyldes ved hjælp af området "Filtre" i pivottabellens layout-dialog, Fra hvert filter kan der vælges et element (en værdi), hvilket betyder, at kun det element tages med i beregningen.

Værdier for delsammentælling fra pivottabellen bruges kun, hvis de benytter funktionen "auto" (bortset fra specificerede begrænsninger, se Anden syntaks herunder).

### Anden syntaks

pivottabel har samme betydning som ved første syntaks.

Begrænsninger er en mellemrumssepareret liste. Elementer kan være i citationstegn (enkelte citationstegn). Hele tekststrengen skal være omkranset af citationstegn (dobbelte citationstegn), med mindre du refererer til tekststrengen fra en anden celle.

En af indtastningerne kan være datafeltnavnet. Datafeltnavnet kan undlades, hvis pivottabellen alene består af et datafelt, ellers skal det være tilstede.

Hver af de øvrige indtastninger angiver en begrænsning på formen Felt[Element] (med de konkrete tegn [ og ]), eller blot Element hvis elementnavnet er unikt i alle felter som er brugt i pivottabellen.

Et funktionsnavn kan tilføjes på formen felt[element;funktion], hvilket betyder at kriterierne kun passer på delsammentællings-værdier som bruger denne funktion. De mulige funktionsnavne er Sum, Tæl, Middel, Maks, Min, Produkt, Tæl (kun tal), Stdafv, Stdafvp, Varians, og Variansp. Der skelnes ikke mellem store og små bogstaver.

## HYPERLINK (samme navn på engelsk)

Når du klikker på en celle, som indeholder HYPERLINK-funktionen, åbner hyperlinket.

Hvis du bruger den valgfri parameter Celleværdi, finder formlen URL'en og viser derefter teksten eller tallet.

For at åbne en hyperlinket celle med tastaturet, skal du vælge cellen, trykke F2 for at komme i redigeringstilstand, flytte markøren foran hyperlinket, trykke Skift+F10, og så vælge Åbn hyperlink.

#### Syntaks

HYPERLINK("URL" [; Celleværdi])

URLangiver linkets mål. Den valgfrie parameter CellValue er den tekst eller et tal, der vises i cellen og bliver returneret som resultat. Hvis parameteren CellValue ikke er specificeret, vises URLen i celleteksten og returneres som resultat.

Tallet 0 returneres for tomme celler og matrixelementer.

#### Eksempel

=HYPERLINK("http://www.example.org") viser teksten "http://www.example.org" og udfører hyperlinket http://www.example.org, når der bliver klikket på det.

=HYPERLINK("http://www.example.org";"Klik her") viser teksten "Klik her" i cellen og udfører hyperlinket http://www.example.org, når der klikkes på det.

=HYPERLINK("http://www.example.org";12345) viser tallet 12345 og udfører hyperlinket http://www.example.org, når der bliver klikket på det.

=HYPERLINK($B4), hvor cellen B4 indeholder http://www.example.org. Funktionen tilføjer http://www.example.org til URLen og returnerer den samme tekst, som bruges formelresultat.

=HYPERLINK("http://www.";"Klik ") og "example.org" viser teksten Klik på exemple.org i cellen og udfører hyperlinket http://www.example.org, når der bliver klikket på det.

=HYPERLINK("#Ark1.A1";"Gå til toppen") viser teksten Gå til toppen og hopper til cellen Ark1.A1 i dette dokument.

=HYPERLINK("file:///C:/writer.odt#Specification";"Gå til Writer-bogmærke") viser teksten "Gå til Writer-bogmærke", henter det angivne tekstdokument og hopper til bogmærket "Specifikation".

=HYPERLINK("file:///C:/Documents/";"Åbn Dokumentmappen") viser teksten "Åbn Dokumentmappen" og viser mappens indhold ved hjælp af dit operativsystems standard filhåndtering.

Funktionen forsøger at slå bro over systemspecifikke forskelle. For eksempel vil "c:\sti til\fil.ext" under Windows korrekt blive fortolket som "file:///c:/sti%20til/fil.ext", eller ".." vil lede til dokumentets overordnede katalog.

## INDEKS (på engelsk: INDEX)

INDEKS returnerer en reference, en værdi eller en matrix af værdier fra et referenceområde, angivet med indekstal for række og kolonne eller med en matrix af indekstal for rækker og kolonner, samt et valgfrit områdeindeks.

INDEKS() returnerer en reference hvis argumentet er én eller flere referencer. Når funktionen bruges i formen =INDEKS(), bliver referencen løst og værdierne vist. Når INDEKS() bruges i argumenter til andre funktioner, =FUNKTION(INDEKS()...), modtager funktionen den reference som blev returneret af INDEKS(). At returnere en reference er forskelligt fra at returnere en matrix med værdier for funktioner som håndterer dem anderledes.

#### Syntaks

INDEKS(Reference [; [Række] [; [Kolonne] [; Område]]])

Reference er en reference, enten skrevet direkte eller ved at angive en områdenavn. Hvis reference består af flere områder, skal du skrive listen af referencer eller områdenavne i parenteser, eller bruge område-sammensætningsoperatoren tilde (~), eller definere et navngivet område som indeholder flere områder.

Række (valgfri) repræsenterer den række eller den matrix af rækkeindekser i referenceområdet, som der skal returneres en værdi for. Ved nul eller udeladt (ingen specifik række) bliver alle refererede rækker returneret.

Kolonne (valgfri) repræsenterer den kolonne eller den matrix af kolonneindekser i referenceområdet, som der skal returneres en værdi for. Ved nul eller udeladt (ingen specifik kolonne) bliver alle refererede kolonner returneret.

Hvis Række eller Kolonne eller begge er udeladt eller defineret som matricer af indekser, skal INDEKS-funktionen skrives som en matrixfunktion.

Område (valgfri) repræsenterer indekset for underområdet hvis der refereres til et multipelt område. Standard er 1.

#### Eksempel

{=INDEKS({1.3.5;7.9.10};{2;1};1)} returnerer en 2-rækkers matrix med 7 og 1. Rækkeindekset {2;1} udvælger række 2 og så række 1. Kolonneindekset 1 udvælger den første kolonne.

{=INDEKS(D3:G12;{1;2;3;4};{3.1})} returnerer en matrix med 4 række og 2 kolonner. Rækkeindeksmatricen {1;2;3;4} udvælger række 3 til 6, og {3;1} udvælger den tredje kolonne (F) og den første kolonne (D). Kolonne 1 og 3 fra kildereferencen er derfor byttet om i den resulterende matrix.

=INDEKS(Priser;4;1) returnerer værdien fra række 4 og kolonne 1 af databaseområdet defineret i Data ▸ Definér som Priser.

=INDEKS(SumX; 4; 1) returnerer værdien fra området SumX i række 4 og kolonne 1 som defineret i Ark ▸ Navngivne områder og udtryk ▸ Definér.

{=INDEKS(A1:B6;1)} returnerer værdierne fra den første række af A1:B6. Skriv formlen ind som en matrixformel.

{=INDEKS(A1:B6;0;1)} returnerer værdierne fra den første kolonne af A1:B6. Skriv formlen ind som en matrixformel.

=INDEKS(A1:B6;1;1) angiver værdien i det øverste venstre hjørne af området A1:B6.

{=INDEKS((A1:B6;C1:D6);0;0;2)} returnerer værdierne af det andet område C1:D6 fra det multiple område. Skriv formlen ind som en matrixformel.

Relaterede emner

Wiki-side for funktionen INDEKS (på engelsk: INDEX).

## INDIREKTE (på engelsk: INDIRECT)

Returnerer Henvisning angivet ved en tekststreng. Denne funktion kan også bruges til at returnere området af en tilsvarende streng.

Denne funktion genberegnes altid, når som helst der sker en genberegning.

Af hensyn til interoperabilitet understøtter funktionerne ADRESSE og INDIREKTE en valgfri parameter til at angive, om R1C1-adresse-notatonen skal bruges i stedet for den sædvanlige A1-notation.

I ADRESSE bliver parameteren indsat som den fjerde parameter, hvilket flytter det valgfri arknavn parameter til den femte placering.

I INDIREKTE er parameteren tilføjet som den anden parameter.

I begge funktioner gælder, at hvis argumentet indsættes med værdien 0, så bruges R1C1-notationen. Hvis argumentet udelades eller har en anden værdi end 0, så bruges A1-notationen.

Ved brug af R1C1-notationen returnerer ADRESSE adresse-strengen med bruge af udråbstegn "!" som arknavn-skilletegn, og INDIREKTE forventer udråbstegn som arknavn-skilletegn. Begge funktioner bruger stadig punktum "." som arknavn-skilletegn med A1-notationen.

Når du åbner dokumenter med ODF 1.0/1.1 formater, hvor ADRESSE-funktionen viser et arknavn som den fjerde parameter, vil arknavnet blive ændret til at blive den femte parameter. En ny fjerde parameter med værdien 1 vil blive indsat.

Når du gemmer et dokument i ODF 1.0/1.1 format, vil den fjerde parameter i ADDRESSE-funktionen blive fjernet.

Undlad at gemme regneark i det ældre ODF 1.0/1.1 format, hvis ADRESSE-funktionens fjerde parameter er brugt med værdien 0.

Funktionen INDIREKTE bliver gemt uden konvertering til formatet ODF 1.0/1.1. Hvis den anden parameter er tilstede, vil ældre versioner af Calc returnere en fejl for den funktion.

#### Syntaks

INDIREKTE(Reference [; A1])

Reference repræsenterer en reference til en celle eller et område (i tekst form) hvorfra der skal returneres en værdi.

A1 (valgfri) – hvis sat til 0, så bruges R1C1-notation. Hvis denne parameter er udeladt eller sat til en anden værdi end 0, så bruges A1-notation.

Hvis du åbner et Excel regneark, som benytter inddirekte adresser beregnet fra strengfunktioner, vil arkadresserne ikke blive konverteret automatisk. For eksempel vil Exceladressen i INDIREKTE("[filnavn]!arknavn"&B1) ikke blive konverteret til Calc-adressen INDIREKTE("filnavn!arknavn"&B1)

#### Eksempel

=INDIREKTE(A1) er lig med 100, hvis A1 indeholder C108 som en reference, og celle C108 indeholder en værdi på 100.

=SUM(INDIREKTE("A1:" & ADRESSE(1;3))) sammentæller cellerne i området fra A1 op til cellen, hvis adresse er defineret ved række 1 og kolonne 3. Det betyder, at området A1:C1 bliver sammentalt.

Relaterede emner

Wiki-side for funktionen INDIREKTE (på engelsk: INDIRECT).

## KOLONNE (på engelsk: COLUMN)

Returnerer kolonnenummeret i en cellereference. Hvis referencen er en celle, returneres cellens kolonnenummer; hvis parameteren er en celleområde, returneres de tilsvarende kolonnenumre i en enkelt rækkes matrix, hvis formlen er indtastet som en matrixformel. Hvis funktionen KOLONNE med et område som referenceparameter ikke er brugt til en matrixformel, bestemmes kun kolonnetallet på den første celle i området.

#### Syntaks

KOLONNE([Reference])

Reference en reference til en celle eller celleområde hvis første kolonnenummer skal findes.

Hvis ingen reference indtastes, bliver kolonnenummeret for cellen hvori formlen er indtastet fundet.LibreOffice Calc sætter automatisk henvisningen til den aktuelle celle.

#### Eksempel

=KOLONNE(A1) er lig med 1. Kolonne A er den første kolonne i tabellen.

=KOLONNE(C3:E3) er lig med 3. Kolonne C er den tredje kolonne i tabellen.

=KOLONNE(D3:G10) returnerer 4, fordi kolonne D er den fjerde kolonne i tabellen, og KOLONNE-funktionen ikke er brugt som en matrixformel. (I dette tilfælde bruges den første værdi i et område altid som resultat.)

{=KOLONNE(B2:B7)} og =KOLONNE(B2:B7) returnerer hver især 2 fordi referencen kun indeholder kolonne B som den anden kolonne i tabellen. Fordi enkelt-kolonne områder kun har et kolonnenummer, gør det ingen forskel om formlen bliver brugt som en matrixformel.

==KOLONNE() returnerer 3 hvis formlen blev indtastet i kolonne C.

{=KOLONNE(Kanin)} returnerer enkeltrækkematricen (3; 4) hvis "Kanin" er det navngivne område (C1:D3).

## KOLONNER (på engelsk: COLUMNS)

Returnerer antallet af kolonner i den givne reference.

#### Syntaks

KOLONNER(Matrix)

Matrix er referencen til et celleområde hvis totale antal kolonner skal findes. Argumentet kan også være en enkelt celle.

#### Eksempel

=Kolonner(B5) returnerer 1, fordi en celle kun indeholder en kolonne.

=KOLONNER(A1:C5) er lig med 3. Henvisningen indbefatter tre Kolonner.

=KOLONNER(Kanin) returnerer 2 hvisKanin er det navngivne område (C1:D3).

## LOPSLAG (på engelsk: VLOOKUP)

Lodret søgning med reference til tilstødende celler til højre. Denne funktion tjekker om en bestemt værdi er indeholdt i den første kolonne af matricen. Funktionen returnerer så værdi i den samme række fra kolonnen angivet af Indeks. Hvis parameteren SorteretOmrådeOpslag er udeladt eller sat til SAND eller 1, så antages det at data er sorterede i stigende orden. I dette tilfælde, hvis det eksakte Opslag ikke bliver fundet, så returneres den sidste værdi, som er lavere end kriteriet. Hvis SorteretOmrådeOpslag er sat til FALSK eller 0, så skal der findes et præcist match, ellers returneres fejlen Fejl: Værdi er ikke tilgængelig som resultatet. Med værdien FALSK eller nul behøver data altså ikke at være sorterede.

Søgningen understøtter jokertegn eller regulære udtryk. Med regulære udtryk slået til, kan du for eksempel skrive "alle.*" for at finde den første placering af "alle" efterfulgt af vilkårlige tegn. Hvis du ønsker at søge efter en tekst som også er et regulært udtryk, så må du enten skrive tegnet "\" (backslash) før hvert enkelt metategn eller operator fra regulære udtryk, eller du må omkranse teksten med \Q...\E. Du kan slå automatisk evaluering af jokertegn eller regulære udtryk til og fra i LibreOffice ▸ Indstillinger Funktioner ▸ Indstillinger ▸ LibreOffice Calc ▸ Beregn.

Når du bruger funktioner, hvor et eller flere argumenter er søgekriterie-strenge, der repræsenterer et regulært udtryk, er det første forsøg at konvertere strengkriterierne til tal. For eksempel vil ".0" konverteres til 0.0 og så videre. Hvis det lykkes, vil matchet ikke være et et regulært udtryk, men et numerisk match. Hvis du imidlertid skifter til et sprog, hvor decimaltegnet ikke er punktum, vil konverteringen fungere. For at gennemtvinge evalueringen af det regulære udtryk frem for et numerisk udtryk, bruger du et udtryk som ikke kan fejllæses som numerisk, såsom ".[0]", ".\0" eller "(?i).0".

#### Syntaks

=LOPSLAG(Opslag; Matrix; Indeks [; SorteretOmrådeOpslag])

Opslag er værdien af enhver type, der slås op i matricens første kolonne.

Matrix er den henvisning, som skal omfatte mindst så mange kolonner som det tal, der blev angivet i Indeks-argumentet.

Indeks er kolonnenummeret i området som indeholder værdien som skal returneres. Den første kolonne har tallet 1.

SorteretOmrådeOpslag er en valgfri parameter, der viser, om den første kolonne i matrixen indeholder områdegrænser i stedet for almindelige værdier. I denne tilstand returnerer opslaget værdien i rækken med den første kolonne, der har en værdi, der er lig med eller mindre end Opslag. Den kan fx indeholde dato, hvor nogle skattetekster er ændret, og på den måde repræsenterer værdierne begyndelsesdatoer for en periode, hvor en bestemt skattetakst var gældende. Således vil søgning efter en dato, der mangler i den første kolonne i matrixen, men falder imellem nogle eksisterende grænsedatoer, ville give den laveste af dem og finde ud af, hvilke data, der var gyldige på den den søgte dato. Indtast den Boolske værdi FALSE (falsk) eller nul, hvis den første kolonne ikke en liste over områdegrænser. Når denne parameter er TRUE (sand) eller ikke angivet, skal den første kolonne sorteres i stigende rækkefølge. Sorterede kolonner kan gennemsøges meget hurtigere og funktionen returnerer altid en værdi, også selv om søgeværdien ikke blev præcist matchet, hvis den er større end den laveste værdi i den sorterede liste. I usorterede lister skal søgeværdien matches præcist. Ellers returnerer funktionen #N/A med beskeden: Fejl: Værdi ikke tilgængelig.

Håndtering af tomme celler

#### Eksempel

Du vil indtaste varenummeret i menuen i celle A1, og navnet på retten skal med det samme fremkomme i den tilstødende celle (B1). Værdien til konvertering fra nummer til navn findes i området D1:E100. D1 indeholder 100, E1 indeholder navnet Grøntsagssuppe og så videre op til 100 menupunkter. Tallene i kolonne D er sorteret i stigende orden; derfor er den valgfri parameter Sorteret ikke nødvendig.

Indtast følgende formel i B1:

=LOPSLAG(A1;D1:E100;2)

Så snart du indtaster et tal i A1 vil B1 vise den tilsvarende tekst indeholdt i den anden kolonne af referencen D1:E100. Indtastning af et ikke eksisterende tal viser teksten med næste tal i rækken. For at forhindre dette, indtastes FALSK som sidste parameter i formlen så en fejlmeddelelse genereres når et ikke eksisterende tal er indtastet.

## OMRÅDER (på engelsk: AREAS)

Returnerer antallet af individuelle områder som tilhører et multiområde. Et område kan bestå af sammenhængende celler eller en enkelt celle.

Funktionen forventer et enkelt argument. Hvis du angiver flere områder, skal du omgive dem i yderligere parenteser. Flere områder kan indtastes ved at bruge semikolon (;) som deler, men disse ændres automatisk til en tilde (~). Tilde bruges til at samle områder.

#### Syntaks

OMRÅDER(Reference)

Reference repræsenterer referencen til en celle eller et celleområde.

#### Eksempel

=OMRÅDER(A1:B3;F2;G1) returnerer 3, fordi det er en reference til tre celler og/eller celleområder. Efter indtastning konverteres det til = OMRÅDER((A1:B3~F2~G1)).

=OMRÅDER(Alt) returnerer 1, hvis du har defineret et område ved navn Alt under Data ▸ Definér område.

## RÆKKE (på engelsk: ROW)

Returnerer rækkenummeret på en cellereference. Hvis referencen er en celle, returnerer den cellens rækkenummer. Hvis referencen er et celleområde, returnerer det de tilsvarende rækkenumre i en en rækkes matrix, hvis formlen er indtastet som en matrixformel. Hvis funktionen RÆKKE med en områdereference ikke er brugt i matrixformlen, returneres kun rækkenummeret for den første områdecelle.

#### Syntaks

RÆKKE([Reference])

Reference er en celle, et område eller navnet på et område.

Hvis du ikke angiver en reference, vil rækkenummeret for cellen, hvor formlen er indtastet, blive fundet.LibreOffice Calc sætter automatisk referencen til den aktuelle celle.

#### Eksempel

RÆKKE(B3) returnerer 3, fordi referencen henviser til den tredje række i tabellen.

{=RÆKKE(D5:D8)} returnerer den enkeltkolonnede matrix (5, 6, 7, 8), fordi den specificerede reference indeholder rækkerne 5 til 8.

=RÆKKE(D5:D8) returnerer 5, fordi RÆKKE-funktionen ikke bliver brugt som matrixformel og kun nummeret på første række i referencen returneres.

{=RÆKKE(A1:E1)} og =RÆKKE(A1:E1) returnerer begge 1, fordi referencen kun indeholder række 1 som den første række i tabellen. (Fordi enkeltrækkede områder kun har en enkelt række tal, gør det ingen forskel, om formlen er brugt som en matrixformel.)

=RÆKKE() returnerer 3 hvis formlen blev indtastet i række 3.

{=RÆKKE(Kanin)} returnerer den enkeltkolonnede matrix (1, 2, 3), hvis "Kanin" er det navngivne område (C1:D3).

## RÆKKER (på engelsk: ROWS)

Returnerer antal rækker i en reference eller en matrix.

#### Syntaks

RÆKKER(Matrix)

Matrix er referencen eller det navngivne område, hvis totale antal rækker skal findes.

#### Eksempel

=Rækker(B5) returnerer 1, fordi en celle indeholder kun en enkelt række.

=RÆKKER(A10:B12) returnerer 3.

=RÆKKER(Kanin) returnerer 3, hvis "Kanin" er det navngivne område (C1:D3).

## SAMMENLIGN (på engelsk: MATCH)

Returnerer den relative position for et element i en matrix, som svarer til en angivet værdi. Funktionen returnerer positionen af værdien fundet i opslagsmatricen som et tal.

#### Syntaks

SAMMENLIGN(Opslagsværdi; Opslagsområde [; Type])

Søgning er den værdi, der skal søges efter i en enkelt række- eller enkeltrække matrix.

Opslagsmatrix er referencen, der skal søges i. Et opslagsområde kan være en enkelt række eller kolonne eller en del af en enkelt række eller kolonne.

Type kan have værdierne 1, 0 eller -1. Hvis Type = 1 eller hvis denne valgfri parameter mangler, antages det, at den første kolonne i opslagsområdet er sorteret i stigende orden. Hvis Type = -1 antages det, at kolonnen er sorteret i faldende orden. Dette svarer til samme funktion i Microsoft Excel.

Hvis Type = 1, eller hvis den tredje parameter mangler, så returneres indeksværdien for den sidste værdi, som er mindre end eller lig med søgekriteriet. For Type = -1 returneres indekset af den sidste værdi, som er større end eller lig med søgekriteriet.

Der kan forventes uforudsigelige resultater, hvis Type har værdi -1 eller +1, men LookupArray ikke er sorteret.

Hvis Type = 0, findes kun eksakte sammenfald. If søgekriteriet er fundet mere end en gang, returnerer funktionen indekset til den overenstemmelse. Kun hvis Type = 0 kan du søge efter regulære udtryk (hvis det er aktiveret i beregningsindstillingerne) eller jokere (hvis det er aktiveret i beregningsindstillingerne).

Søgningen understøtter jokertegn eller regulære udtryk. Med regulære udtryk slået til, kan du for eksempel skrive "alle.*" for at finde den første placering af "alle" efterfulgt af vilkårlige tegn. Hvis du ønsker at søge efter en tekst som også er et regulært udtryk, så må du enten skrive tegnet "\" (backslash) før hvert enkelt metategn eller operator fra regulære udtryk, eller du må omkranse teksten med \Q...\E. Du kan slå automatisk evaluering af jokertegn eller regulære udtryk til og fra i LibreOffice ▸ Indstillinger Funktioner ▸ Indstillinger ▸ LibreOffice Calc ▸ Beregn.

Når du bruger funktioner, hvor et eller flere argumenter er søgekriterie-strenge, der repræsenterer et regulært udtryk, er det første forsøg at konvertere strengkriterierne til tal. For eksempel vil ".0" konverteres til 0.0 og så videre. Hvis det lykkes, vil matchet ikke være et et regulært udtryk, men et numerisk match. Hvis du imidlertid skifter til et sprog, hvor decimaltegnet ikke er punktum, vil konverteringen fungere. For at gennemtvinge evalueringen af det regulære udtryk frem for et numerisk udtryk, bruger du et udtryk som ikke kan fejllæses som numerisk, såsom ".[0]", ".\0" eller "(?i).0".

#### Eksempel

=SAMMENLIGN(200;D1:D100) søger i området D1:D100, som er sorteret efter kolonne D, efter værdien 200. Så snart denne værdi er nået, returneres rækkenummeret hvor den blev fundet. Hvis en højere værdi er fundet undervejs i søgningen i kolonnen, returneres rækkenummeret for den foregående række.

## VOPSLAG (på engelsk: HLOOKUP)

Søger efter en værdi og reference til cellerne nedenfor det valgte område. Denne funktion verificerer at den første række af et område indeholder en bestemt værdi. Funktionen returnerer så værdien i en række af området, navngivet i Indeks, i samme kolonne.

Søgningen understøtter jokertegn eller regulære udtryk. Med regulære udtryk slået til, kan du for eksempel skrive "alle.*" for at finde den første placering af "alle" efterfulgt af vilkårlige tegn. Hvis du ønsker at søge efter en tekst som også er et regulært udtryk, så må du enten skrive tegnet "\" (backslash) før hvert enkelt metategn eller operator fra regulære udtryk, eller du må omkranse teksten med \Q...\E. Du kan slå automatisk evaluering af jokertegn eller regulære udtryk til og fra i LibreOffice ▸ Indstillinger Funktioner ▸ Indstillinger ▸ LibreOffice Calc ▸ Beregn.

Når du bruger funktioner, hvor et eller flere argumenter er søgekriterie-strenge, der repræsenterer et regulært udtryk, er det første forsøg at konvertere strengkriterierne til tal. For eksempel vil ".0" konverteres til 0.0 og så videre. Hvis det lykkes, vil matchet ikke være et et regulært udtryk, men et numerisk match. Hvis du imidlertid skifter til et sprog, hvor decimaltegnet ikke er punktum, vil konverteringen fungere. For at gennemtvinge evalueringen af det regulære udtryk frem for et numerisk udtryk, bruger du et udtryk som ikke kan fejllæses som numerisk, såsom ".[0]", ".\0" eller "(?i).0".

#### Syntaks

VOPSLAG(Søgekriterie; Matrix; Indeks [Sorteret områdeopslag])

En forklaring af parametrene finder du under LOPSLAG (kolonner og rækker er byttet om)

Håndtering af tomme celler

#### Eksempel

Antag, at vi har opbygget en lille datavasetabel, der fylder celleområdet A1:DO4 og indeholder grundoplysningerr om 118 kemiske elementer. Den første kolonne indeholder rækkeoverskrifterne "Element", "Symbol", "Atomnummer" og "Relativ Atommasse". De følgende kolonner indeholder de relevante oplysninger for hvert element, ordnet fra venstre mod højre efter atomnummer. for eksempel indeholder cellerne B1:B4 "Brint (Hydrogen)", "H", "1" og "1,008", mens cellerne DO1:DO4 indeholder "Oganesson", "Og", "118" og "294".

| A | B | C | D | ... | DO
--- | --- | --- | --- | --- | --- | ---
1 | Grundstof | Brint (Hydrogen) | Helium | Lithium | ... | Oganesson
2 | Symbol | H | He | Li | ... | Og
3 | Atomnummer | 1 | 2 | 3 | ... | 118
4 | Relativ Atommasse | 1.008 | 4.0026 | 6.94 | ... | 294

=VOPSLAG("Bly"; $A$1:$DO$4; 2; 0) returnerer “Pb”, symbolet for bly.

=HLOOKUP("Gold"; $A$1:$DO$4; 3; 0) returnerer 79: gulds atomnummer.

=VOPSLAG("Kul"; $A$1:$DO$4; 4; 0) returnerer 12,011: kuls relative atommasse.

## VÆLG (på engelsk: CHOOSE)

Bruger et indeks til at returnere en værdi fra en liste af op til 30 værdier.

#### Syntaks

VÆLG( Indeks; Værdi 1 [; Værdi 2 [; ... [; Værdi 30]]])

Indeks er en reference eller et tal mellem 1 og 30, som indikerer, hvilke værdier der skal tages fra listen.

Værdi 1, Værdi 2, ..., Værdi 30 er listen over værdier, indtastet som en reference til en celle eller som individuelle værdier.

#### Eksempel

=VÆLG(A1; B1; B2; B3; "I dag"; "I går"; "I morgen"), returnerer for eksempel indholdet af celle B2 til A1 = 2; til A1 = 4. Funktionen returnerer teksten "I dag".

Relaterede emner

Funktioner efter kategori

Støt os venligst!