Indhold

# REGEX-funktion

Matcher og udtrækker eller erstatter efter tilvalg tekst med regulære udtryk.

### Syntaks

REGEX( tekst ; udtryk [ ; [ erstatning ] [ ; flag|forekomst ] ] )

Tekst En tekst eller henvisning til den celle, hvor det regulære udtryk skal bruges.

Udtryk: En tekst som repræsenterer det regulære udtryk, i formen ICU regulære udtryk. Hvis der ikke er noget match og Erstatning ikke er angivet, returneres #N/A.

Erstatning: valgfri. erstatningsteksten og henvisninger, som skal fange grupper. Hvis der ikke er et match, bliver teksten returneret uændret.

Flag: valgfri. "g" erstatter alle matches med udtryk i teksten uden udtrækning. Hvis der ikke er et match, bliver teksten reurneret uændret.

Forekomst: Valgfri. Tal der angiver hvilken match af Udtryk i Tekst der skal udtrækkes eller erstattes. Hvis der ikke er nogen match og Erstatning ikke er givet, returneres #N/A. Er der ingen match og Erstatning er givet, bliver Tekst returneret uændret. Hvis Forekomst er 0, vil Tekst blive returneret uændret.

### Eksempler

=REGEX("123456ABCDEF";"[:digit:]";"Z") returnerer "Z23456ABCDEF", hvor det første match med et ciffer er erstattet med "Z".

=REGEX("123456ABCDEF";"[:digit:]";"Z";"g") returnerer "ZZZZZZABCDEF", hvor alle cifre blev erstattet med "Z".

=REGEX("123456ABCDEF";"[126]";"";"g") returnerer "345ABCDEF", hvor alle forekomster af "1", "2" eller "6" blev erstattet med den tomme streng og således slettet.

=REGEX("axbxcxd";".x";;2) returnerer "bx", den anden match med ".x".

=REGEX("axbxcxd";"(.)x";"$1y";2) returnerer "axbycxd", den anden match med "(.)x" (dvs. "bx") erstattet med den indfangne gruppe bed en karakter (dvs. "b") fulgt af "y".

#### Tekniske oplysninger

Denne funktion er tilgængelig siden LibreOffice 6.2.

Denne funktion er ikke en del af standarden Open Document Format for kontorprogrammer (OpenDocument) Version 1.3. del 4: Omregnet formel (OpenFormula) -format. Navnerummet er

ORG.LIBREOFFICE.REGEX

Relaterede emner

Wiki-side for funktionen REGEX (samme navn på engelsk).

Liste over regulære udtryk

ICU regulære udtryk