Indhold

# MAKSHVISER funktion

Returnerer maksimum af værdier i celler i et område, der opfylder flere kriterier i flere områder.

### Syntaks

MAKSHVISER(Funk_Område; Område1; Kriterie[; Område2; Kriterie2][; … ; [Område127; Kriterie127]])

Funktionsområde – påkrævet argument. Et område af celler, navnet på et navngivet område eller en etiket for en kolonne eller række, som indeholder værdier til at beregne maksimum.

Område 1 – obligatorisk argument. Det er et celleområde, et navn på et navngivet område eller en kolonne- eller række-overskrift, som det tilsvarende kriterie skal anvendes på.

Kriterie: Et kriterie er en enkelt celle, henvisning, tal eller tekst. Det bruges i sammenligninger med celleindhold.

En henvisning til en tom celle fortolkes som den numeriske værdi 0.

Et matchende udtryk kan være:

- Et tal eller en logisk værdi. Et matchende celleindhold er lig med tallet eller den logiske værdi.

- En værdi begyndende med en komparator (<, <=, =, >, >=, <>).

  Ved =: hvis værdien er tom, matcher den tomme celler.

  Ved <>: hvis værdien er tom, matcher den ikke-tomme celler.

  Ved <>: hvis værdien ikke er tom, matcher den ethvert celleindhold, undtagen værdien, herunder tomme celler.

  Bemærk: "=0" matcher ikke tomme celle.

  Ved = og <>: hvis værdien ikke er tom og ikke kan fortolkes som typen Tal eller en af dens undertyper og egenskaben Søgekriterier = og <> skal gælde hele celler er markeret, sker sammenligningen med hele celleindholdet, hvis den ikke er markeret, sker sammenligningen med enhver delmængde af feltet, der matcher kriterierne. Ved = og <>: hvis værdien ikke er tom og ikke kan fortolkes som typen Tal eller en en af dens undertyper, gælder ...

- Anden tekstværdi. Hvis egenskaben Søgekriterier = og <> skal gælde hele celler er sand, sker sammenligningen med hele celleindhold, hvis falsk, sker sammenligningen med enhver delmængde af feltet, der matcher kriterierne. Udtrykket kan indeholde tekst, tal, udtryk eller jokere (, hvis aktiveret i indstillingerne Beregning).

Område2 – Valgfri. Område2 og alle de følgende betyder det samme som Område1.

Kriterie2 – Valgfri. Kriterie2 og alle de følgende har samme betydning som Kriterie.

Søgningen understøtter jokertegn eller regulære udtryk. Med regulære udtryk slået til, kan du for eksempel skrive "alle.*" for at finde den første placering af "alle" efterfulgt af vilkårlige tegn. Hvis du ønsker at søge efter en tekst som også er et regulært udtryk, så må du enten skrive tegnet "\" (backslash) før hvert enkelt metategn eller operator fra regulære udtryk, eller du må omkranse teksten med \Q...\E. Du kan slå automatisk evaluering af jokertegn eller regulære udtryk til og fra i LibreOffice ▸ Præferencer Funktioner ▸ Indstillinger ▸ LibreOffice Calc ▸ Beregn.

Når du bruger funktioner, hvor et eller flere argumenter er søgekriterie-strenge, der repræsenterer et regulært udtryk, er det første forsøg at konvertere strengkriterierne til tal. For eksempel vil ".0" konveretres til 0.0 og så videre. Hvis det lykkes, vil matchet ikke være et et regulært udtryk, men et numerisk match. Hvis du imidlertid skifter til lokalisering, hvor decimaltegnet ikke er punktum, kommer konverteringen fungere. For at gennemtvingen evalueringen af det regulære udtryk frem for et numerisk udtryk bruger du et udtryk som ikke kan fejllæses som numerisk, såsom ".[0]", ".\0" eller "(?i).0".

Funktionsområde og Område1, Område2... skal have samme størrelse, ellers returnerer funktionen err:502 - ugyldigt argument.

Den logiske relation mellem kriterier kan defineres som logisk OG (Konjunktion). Med andre ord, hvis og kun hvis alle givne kriterier opfyldes, vil en værdi fra den korresponderende celle af det givne Funktions_område blive taget med i udregningen.

Funktionen kan have op til 255 argumenter, hviket betyder at du kan give 127 kriterieområder og kriterier for dem.

Hvis en celle indeholder SAND, betragtes det som 1, og hvis en celle indeholder FALSK betragtes det som 0 (nul).

#### Eksempel

Betragt den følgende tabel

| A | B | C
1 | Produktnavn | Salg | Indtægter
2 | pensel | 20 | 65
3 | kuglepen | 35 | 85
4 | notesblok | 20 | 190
5 | bog | 17 | 180
6 | penalhus | ikke | ikke

I alle eksempler herunder, indeholder området for beregning af summen række #6, men den ignoreres, fordi den indeholder tekst.

#### Simpelt brug

=MAKSHVISER(B2:B6;B2:B6;"<35")

Beregner maksimum af værdier i området B2:B6, der er større end eller lig med 20. Returner 35, fordi den femte række ikke opfylder kriteriet.

=MAKSHVISER(C2:C6;B2:B6;">=20";C2:C6;"<90")

Beregner maksimum for værdier i området C2:C6, som er mindre end 90 og som korresponderer med celler i området B2:B6 med værdier større end eller lig med 20. Returnerer 85, fordi den fjerde og femte række ikke opfylder mindst et kriterium.

#### Brug af regulære udtryk og indlejrede funktioner

=MAKSHVISER(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAKS(B2:B6))

Beregner maksimum af værdier i området C2:C6, som korresponderer med alle værdier i området B2:B6, med undtagelse af dets minimum og maksimum værdi. Returnerer 190, fordi kun fjerde række opfylder kriterierne.

=MAKSHVISER(C2:C6;A2:A6;"pen.*";B2:B6;"<="&MAKS(B2:B6))

Beregner maksimum af værdier i området C2:C6, som korresponderer med alle værdier i området A2:A6, begyndende med "pen" og til alle celler i B2:B6 området, bortset fra dets maksimum. Returnerer 85, fordi kun tredje række opfylder kriterierne.

#### Reference til en celle som kriterium

Har du brug for en let måde at ændre kriterie på, kan du skrive det i en separat celle, og bruge en reference til denne celle i betingelsen i din MAKSHVISER-funktion. For eksempel kan ovenstående funktion omskrives således:

=MAKSHVISER(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAKS(B2:B6))

Hvis E2 = "pen", returnerer funktionen 65, fordi referencen til cellen erstattes af dennes indhold.

#### Tekniske oplysninger

Denne funktion er tilgængelig siden LibreOffice 5.2.

Denne funktion er ikke en del af standarden Open Document Format for kontorprogrammer (OpenDocument) Version 1.3. del 4: Omregnet formel (OpenFormula) -format. Navnerummet er

COM.MICROSOFT.MAXIFS

Relaterede emner

Wiki-side for funktionen MAKSHVISER (på engelsk: MAXIFS).

MAKS, MAKSV, MIN, MINV,

TÆL.FLERE.HVIS, MINHVISER, MAKSHVISER, MIDDEL.HVIS, SUM.FLERE.HVIS

Liste over regulære udtryk